[gentoo-commits] repo/gentoo:master commit in: net-news/liferea/

["Patrice Clement" <monsieurp@gentoo.org>]

commit:     3ccec78b8334a664d31c2c19e7868c964d7dc4cc
Author:     Yuri Konotopov <ykonotopov <AT> gnome <DOT> org>
AuthorDate: Tue Jan 16 16:21:22 2018 +0000
Commit:     Patrice Clement <monsieurp <AT> gentoo <DOT> org>
CommitDate: Thu Jan 25 22:51:55 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=3ccec78b

net-news/liferea: version bump.

Closes: https://bugs.gentoo.org/644436
Closes: https://github.com/gentoo/gentoo/pull/6878

 net-news/liferea/Manifest              |  1 +
 net-news/liferea/liferea-1.12.1.ebuild | 70 ++++++++++++++++++++++++++++++++++
 2 files changed, 71 insertions(+)

diff --git a/net-news/liferea/Manifest b/net-news/liferea/Manifest
index 5ebd13370da..18e1b960a05 100644
--- a/net-news/liferea/Manifest
+++ b/net-news/liferea/Manifest
@@ -1 +1,2 @@
 DIST liferea-1.12-rc3.tar.bz2 1474948 BLAKE2B 2eff01f0494024d40f2a530ba52a29778ea3a90b2ad786c76658451140509e99c81d08a54e50a4688588e79a0638de72aed09fd6c8e856941094760d6498b07e SHA512 cc3b84444ec95c158311d5d2df7bec0c18f83fd4a7a6a38fdc67a613283288a90076892d0e632447b0523674c8182e70723f2fb865f479cd6fe7a22d4d29d8bb
+DIST liferea-1.12.1.tar.bz2 1490079 BLAKE2B 56963749537bfe7c1f57e95725756b6da43637c2f6a872482033bafbbbb04539d59f942dbb6e35ceda9426a7311b9ba70d37d0a91fb575287dbfe4f5bbc5b136 SHA512 d3e53127f62e91b23aa042ae6dc655eb174f2823320cc01c4cb2b9074f6547ae9a34f6daeb0c1dfb37dfb9f85890ab67223a863f2679ad15a5c7c7f3840d711a

diff --git a/net-news/liferea/liferea-1.12.1.ebuild b/net-news/liferea/liferea-1.12.1.ebuild
new file mode 100644
index 00000000000..daae977aa59
--- /dev/null
+++ b/net-news/liferea/liferea-1.12.1.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python3_{4,5,6} )
+
+inherit autotools gnome2 pax-utils python-single-r1
+
+MY_P=${P/_/-}
+MY_PV=${PV/_/-}
+
+S=${WORKDIR}/${MY_P}
+
+DESCRIPTION="News Aggregator for RDF/RSS/CDF/Atom/Echo feeds"
+HOMEPAGE="https://lzone.de/liferea/"
+SRC_URI="https://github.com/lwindolf/${PN}/releases/download/v${MY_PV}/${MY_P}.tar.bz2"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~x86"
+IUSE=""
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}
+	>=dev-db/sqlite-3.7.0:3
+	>=dev-libs/glib-2.28.0:2
+	dev-libs/gobject-introspection
+	dev-libs/json-glib
+	>=dev-libs/libpeas-1.0.0[gtk,python,${PYTHON_USEDEP}]
+	>=dev-libs/libxml2-2.6.27:2
+	>=dev-libs/libxslt-1.1.19
+	gnome-base/gsettings-desktop-schemas
+	>=net-libs/libsoup-2.42:2.4
+	net-libs/webkit-gtk:4
+	x11-libs/gtk+:3
+	>=x11-libs/pango-1.4.0"
+DEPEND="${RDEPEND}
+	dev-util/intltool
+	virtual/pkgconfig"
+
+S="${WORKDIR}"/${MY_P}
+
+src_prepare() {
+	gnome2_src_prepare
+
+	# gnome2_src_prepare calls elibtoolize
+	if [ -f "${S}"/.elibtoolized ]; then
+		local AT_NOELIBTOOLIZE="yes"
+	fi
+	eautoreconf
+}
+
+src_configure() {
+	gnome2_src_configure --disable-schemas-compile
+}
+
+src_install() {
+	gnome2_src_install
+
+	# bug #338213
+	# Uses webkit's JIT. Needs mmap('rwx') to generate code in runtime.
+	# MPROTECT policy violation. Will sit here until webkit will
+	# get optional JIT.
+	pax-mark m "${D%/}"/usr/bin/liferea
+
+	einfo "If you want to enhance the functionality of this package,"
+	einfo "you should consider installing:"
+	einfo "    net-misc/networkmanager"
+}