[gentoo-commits] repo/gentoo:master commit in: dev-libs/gecode/

[gentoo-commits] repo/gentoo:master commit in: dev-libs/gecode/

[Michael Orlitzky]

commit:     395d5ea72bceca3087e602683b43e279f5ca0b71
Author:     Michael Orlitzky <mjo <AT> gentoo <DOT> org>
AuthorDate: Mon Aug  1 12:48:17 2016 +0000
Commit:     Michael Orlitzky <mjo <AT> gentoo <DOT> org>
CommitDate: Mon Aug  1 12:48:17 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=395d5ea7

dev-libs/gecode: remove old version 3.7.3 to fix QA warnings.

Package-Manager: portage-2.2.28

 dev-libs/gecode/Manifest            |  1 -
 dev-libs/gecode/gecode-3.7.3.ebuild | 52 -------------------------------------
 2 files changed, 53 deletions(-)

diff --git a/dev-libs/gecode/Manifest b/dev-libs/gecode/Manifest
index 1c0230c..bf4b19e 100644
--- a/dev-libs/gecode/Manifest
+++ b/dev-libs/gecode/Manifest
@@ -1,2 +1 @@
-DIST gecode-3.7.3.tar.gz 1643336 SHA256 e7cc8bcc18b49195fef0544061bdd2e484a1240923e4e85fa39e8d6bb492854c SHA512 292bafeaca3911b8af40d7c0f425cf0263f4408afad47f4f229a821ce89d06dc69ad1feeeef72531a1e711d797d249581b67c2d9cfdc9e544240012c838d2a5b WHIRLPOOL 5aad39285c73e2d918fca98b694b33e00b11fcc21d542a37e23424acc381696f20826d6c28a33a5cde8fbfdfd4254d05791f2db903903306887e4c4fdecb7104
 DIST gecode-4.4.0.tar.gz 2889186 SHA256 b45783cc8d0d5dbbd3385a263a2199e6ad7f9a286e92607de81aa0c1105769cb SHA512 5189a3c5f9f34371a0bc94528e8ca65efb0a3078ec158887f47a816d6fe3c879a7e908ee421414bc317754333ecb73806c8fc46b0b6b7d8419cdf6f13a4f8aef WHIRLPOOL a01541d86883eadfcbb45eb7df486ac8d9fa4f656dede937625b00c8f47d1898e42d1fc6004b073392a179b895bc5181585b71693d47e88317a658eb3ecf3252

diff --git a/dev-libs/gecode/gecode-3.7.3.ebuild b/dev-libs/gecode/gecode-3.7.3.ebuild
deleted file mode 100644
index 74c4418..0000000
--- a/dev-libs/gecode/gecode-3.7.3.ebuild
+++ /dev/null
@@ -1,52 +0,0 @@
-# Copyright 1999-2013 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Id$
-
-EAPI="4"
-
-DESCRIPTION="Gecode is an environment for developing constraint-based systems and applications"
-SRC_URI="http://www.gecode.org/download/${P}.tar.gz"
-HOMEPAGE="http://www.gecode.org/"
-
-SLOT="0"
-LICENSE="MIT"
-KEYWORDS="~amd64 ~x86"
-IUSE="doc examples gist"
-
-DEPEND="gist? (
-	dev-qt/qtcore:4
-	dev-qt/qtgui:4
-	media-libs/freetype
-	media-libs/libpng
-	>=dev-libs/glib-2
-)"
-RDEPEND="${DEPEND}"
-
-src_configure() {
-	econf \
-		--disable-examples \
-		$(use_enable gist qt) \
-		$(use_enable gist)
-}
-
-src_compile() {
-	default
-	use doc && emake doc
-}
-
-src_install() {
-	default
-
-	if use doc; then
-		dohtml -r doc/html/
-		einfo "HTML documentation has been installed into " \
-			"/usr/share/doc/${PF}/html"
-	fi
-
-	if use examples; then
-		docinto examples
-		doins examples/*.cpp
-		einfo "Example C++ programs have been installed into " \
-			"/usr/share/doc/${PF}/examples"
-	fi
-}

[gentoo-commits] repo/gentoo:master commit in: dev-libs/gecode/

[Michael Orlitzky]

commit:     eac999d93c087c4e5981a7edb82d1a167772fdad
Author:     Michael Orlitzky <mjo <AT> gentoo <DOT> org>
AuthorDate: Sun Jul 31 23:05:12 2016 +0000
Commit:     Michael Orlitzky <mjo <AT> gentoo <DOT> org>
CommitDate: Mon Aug  1 12:45:53 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=eac999d9

dev-libs/gecode: new version 4.4.0.

This version bump fixes at least two open bugs. The first simply asked
for a version bump, and the second reported a failure when /bin/sh is
dash (now fixed).

Along with the new version, some ebuild cleanup was done. The ebuild
is now EAPI=6, and the "gmp" USE flag was added to control building
with float constraints. Three superfluous runtime dependencies
(transitive through Qt) were removed, and two new build dependencies
needed to generate the documentation were added.

The src_test() phase has been re-enabled with an LD_LIBRARY hack to
make sure that the test suite is run against the just-build libraries.

Gentoo-Bug: 377091
Gentoo-bug: 527526
Gentoo-Bug: 567208

Package-Manager: portage-2.2.28

 dev-libs/gecode/Manifest            |  1 +
 dev-libs/gecode/gecode-4.4.0.ebuild | 70 +++++++++++++++++++++++++++++++++++++
 dev-libs/gecode/metadata.xml        |  6 ++++
 3 files changed, 77 insertions(+)

diff --git a/dev-libs/gecode/Manifest b/dev-libs/gecode/Manifest
index a9908f7..1c0230c 100644
--- a/dev-libs/gecode/Manifest
+++ b/dev-libs/gecode/Manifest
@@ -1 +1,2 @@
 DIST gecode-3.7.3.tar.gz 1643336 SHA256 e7cc8bcc18b49195fef0544061bdd2e484a1240923e4e85fa39e8d6bb492854c SHA512 292bafeaca3911b8af40d7c0f425cf0263f4408afad47f4f229a821ce89d06dc69ad1feeeef72531a1e711d797d249581b67c2d9cfdc9e544240012c838d2a5b WHIRLPOOL 5aad39285c73e2d918fca98b694b33e00b11fcc21d542a37e23424acc381696f20826d6c28a33a5cde8fbfdfd4254d05791f2db903903306887e4c4fdecb7104
+DIST gecode-4.4.0.tar.gz 2889186 SHA256 b45783cc8d0d5dbbd3385a263a2199e6ad7f9a286e92607de81aa0c1105769cb SHA512 5189a3c5f9f34371a0bc94528e8ca65efb0a3078ec158887f47a816d6fe3c879a7e908ee421414bc317754333ecb73806c8fc46b0b6b7d8419cdf6f13a4f8aef WHIRLPOOL a01541d86883eadfcbb45eb7df486ac8d9fa4f656dede937625b00c8f47d1898e42d1fc6004b073392a179b895bc5181585b71693d47e88317a658eb3ecf3252

diff --git a/dev-libs/gecode/gecode-4.4.0.ebuild b/dev-libs/gecode/gecode-4.4.0.ebuild
new file mode 100644
index 0000000..68b54f7
--- /dev/null
+++ b/dev-libs/gecode/gecode-4.4.0.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+DESCRIPTION="An environment for developing constraint-based applications"
+SRC_URI="http://www.gecode.org/download/${P}.tar.gz"
+HOMEPAGE="http://www.gecode.org/"
+
+SLOT="0"
+LICENSE="MIT"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc examples gist gmp test"
+
+RDEPEND="
+	gist? (
+		|| (
+			( dev-qt/qtcore:4 dev-qt/qtgui:4 )
+			( dev-qt/qtcore:5 dev-qt/qtgui:5 )
+		)
+	)
+	gmp? (
+		|| ( dev-libs/gmp:0 sci-libs/mpir )
+		dev-libs/mpfr:0
+	)"
+DEPEND="${RDEPEND}
+	doc? (
+		app-doc/doxygen
+		media-gfx/graphviz
+	)"
+
+src_configure() {
+	 # --disable-examples prevents COMPILING the examples.
+	econf \
+		--docdir="/usr/share/doc/${PF}" \
+		--htmldir="/usr/share/doc/${PF}/html" \
+		--disable-examples \
+		$(use_enable doc doc-dot) \
+		$(use_enable doc doc-tagfile) \
+		$(use_enable gist qt) \
+		$(use_enable gist) \
+		$(use_enable gmp mpfr)
+}
+
+src_compile() {
+	default
+	use doc && emake doc
+}
+
+src_install() {
+	default
+
+	# The --docdir and --htmldir that we pass to configure don't seem to
+	# be respected...
+	use doc && dodoc -r doc/html
+
+	if use examples; then
+		# The build system supports "examples", but we want to install
+		# their source code, not the resulting binaries.
+		rm -f examples/CMakeLists.txt \
+			|| die 'failed to remove examples/CMakeLists.txt'
+		dodoc -r examples
+	fi
+}
+
+src_test() {
+	LD_LIBRARY_PATH="${S}" emake test
+	LD_LIBRARY_PATH="${S}" ./test/test || die "test suite failed"
+}

diff --git a/dev-libs/gecode/metadata.xml b/dev-libs/gecode/metadata.xml
index 06c0664..8d55768 100644
--- a/dev-libs/gecode/metadata.xml
+++ b/dev-libs/gecode/metadata.xml
@@ -7,4 +7,10 @@
 			Enable Gist, the Gecode Interactive Search Tool
 		</flag>
 	</use>
+	<use>
+		<flag name="gmp">
+			Enable trigonometric and transcendental float
+			constraints
+		</flag>
+	</use>
 </pkgmetadata>

[gentoo-commits] repo/gentoo:master commit in: dev-libs/gecode/

[Michael Orlitzky]

commit:     53ef549d34ff365c05660062933a5f5981aa41d3
Author:     Michael Orlitzky <mjo <AT> gentoo <DOT> org>
AuthorDate: Mon Aug  1 13:03:06 2016 +0000
Commit:     Michael Orlitzky <mjo <AT> gentoo <DOT> org>
CommitDate: Mon Aug  1 13:03:06 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=53ef549d

Revert "dev-libs/gecode: remove old version 3.7.3 to fix QA warnings."

This reverts commit 395d5ea72bceca3087e602683b43e279f5ca0b71. The
dev-ruby/dep_selector package has a dependency on >=gecode3.5.0, but
at the moment it can only be satisfied by gecode-3.x, so we need to
leave v3.7.3 in the tree. There is an upstream pull request (#44) to
support gecode 4.x.

 dev-libs/gecode/Manifest            |  1 +
 dev-libs/gecode/gecode-3.7.3.ebuild | 52 +++++++++++++++++++++++++++++++++++++
 2 files changed, 53 insertions(+)

diff --git a/dev-libs/gecode/Manifest b/dev-libs/gecode/Manifest
index bf4b19e..1c0230c 100644
--- a/dev-libs/gecode/Manifest
+++ b/dev-libs/gecode/Manifest
@@ -1 +1,2 @@
+DIST gecode-3.7.3.tar.gz 1643336 SHA256 e7cc8bcc18b49195fef0544061bdd2e484a1240923e4e85fa39e8d6bb492854c SHA512 292bafeaca3911b8af40d7c0f425cf0263f4408afad47f4f229a821ce89d06dc69ad1feeeef72531a1e711d797d249581b67c2d9cfdc9e544240012c838d2a5b WHIRLPOOL 5aad39285c73e2d918fca98b694b33e00b11fcc21d542a37e23424acc381696f20826d6c28a33a5cde8fbfdfd4254d05791f2db903903306887e4c4fdecb7104
 DIST gecode-4.4.0.tar.gz 2889186 SHA256 b45783cc8d0d5dbbd3385a263a2199e6ad7f9a286e92607de81aa0c1105769cb SHA512 5189a3c5f9f34371a0bc94528e8ca65efb0a3078ec158887f47a816d6fe3c879a7e908ee421414bc317754333ecb73806c8fc46b0b6b7d8419cdf6f13a4f8aef WHIRLPOOL a01541d86883eadfcbb45eb7df486ac8d9fa4f656dede937625b00c8f47d1898e42d1fc6004b073392a179b895bc5181585b71693d47e88317a658eb3ecf3252

diff --git a/dev-libs/gecode/gecode-3.7.3.ebuild b/dev-libs/gecode/gecode-3.7.3.ebuild
new file mode 100644
index 0000000..74c4418
--- /dev/null
+++ b/dev-libs/gecode/gecode-3.7.3.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="4"
+
+DESCRIPTION="Gecode is an environment for developing constraint-based systems and applications"
+SRC_URI="http://www.gecode.org/download/${P}.tar.gz"
+HOMEPAGE="http://www.gecode.org/"
+
+SLOT="0"
+LICENSE="MIT"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc examples gist"
+
+DEPEND="gist? (
+	dev-qt/qtcore:4
+	dev-qt/qtgui:4
+	media-libs/freetype
+	media-libs/libpng
+	>=dev-libs/glib-2
+)"
+RDEPEND="${DEPEND}"
+
+src_configure() {
+	econf \
+		--disable-examples \
+		$(use_enable gist qt) \
+		$(use_enable gist)
+}
+
+src_compile() {
+	default
+	use doc && emake doc
+}
+
+src_install() {
+	default
+
+	if use doc; then
+		dohtml -r doc/html/
+		einfo "HTML documentation has been installed into " \
+			"/usr/share/doc/${PF}/html"
+	fi
+
+	if use examples; then
+		docinto examples
+		doins examples/*.cpp
+		einfo "Example C++ programs have been installed into " \
+			"/usr/share/doc/${PF}/examples"
+	fi
+}

[gentoo-commits] repo/gentoo:master commit in: dev-libs/gecode/

[Michael Orlitzky]

commit:     a4c6aa1c4d788baf43d1b0f689d8f363dc56de04
Author:     Michael Orlitzky <mjo <AT> gentoo <DOT> org>
AuthorDate: Mon Aug  1 13:14:36 2016 +0000
Commit:     Michael Orlitzky <mjo <AT> gentoo <DOT> org>
CommitDate: Mon Aug  1 13:14:36 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=a4c6aa1c

dev-libs/gecode: fix metadata.xml schema.

In my recent addition of gecode-4.4.0, I made a copy/paste error and
duplicated the <use> element in metadata.xml. Michał's Travis CI
instance caught the error (thanks).

Package-Manager: portage-2.2.28

 dev-libs/gecode/metadata.xml | 2 --
 1 file changed, 2 deletions(-)

diff --git a/dev-libs/gecode/metadata.xml b/dev-libs/gecode/metadata.xml
index 8d55768..234da92 100644
--- a/dev-libs/gecode/metadata.xml
+++ b/dev-libs/gecode/metadata.xml
@@ -6,8 +6,6 @@
 		<flag name="gist">
 			Enable Gist, the Gecode Interactive Search Tool
 		</flag>
-	</use>
-	<use>
 		<flag name="gmp">
 			Enable trigonometric and transcendental float
 			constraints

[gentoo-commits] repo/gentoo:master commit in: dev-libs/gecode/

[Michael Palimaka]

commit:     15fcaf22dbdbd343e557b3768e7dbd4a93e78342
Author:     Michael Palimaka <kensington <AT> gentoo <DOT> org>
AuthorDate: Thu Sep 29 17:26:42 2016 +0000
Commit:     Michael Palimaka <kensington <AT> gentoo <DOT> org>
CommitDate: Thu Sep 29 17:27:03 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=15fcaf22

dev-libs/gecode: remove econf options that are automatically added in EAPI 6

Package-Manager: portage-2.3.1

 dev-libs/gecode/gecode-4.4.0-r1.ebuild | 2 --
 1 file changed, 2 deletions(-)

diff --git a/dev-libs/gecode/gecode-4.4.0-r1.ebuild b/dev-libs/gecode/gecode-4.4.0-r1.ebuild
index f43e46b..c9f4000 100644
--- a/dev-libs/gecode/gecode-4.4.0-r1.ebuild
+++ b/dev-libs/gecode/gecode-4.4.0-r1.ebuild
@@ -49,8 +49,6 @@ src_prepare() {
 src_configure() {
 	 # --disable-examples prevents COMPILING the examples.
 	econf \
-		--docdir="/usr/share/doc/${PF}" \
-		--htmldir="/usr/share/doc/${PF}" \
 		--disable-examples \
 		$(use_enable doc doc-dot) \
 		$(use_enable doc doc-tagfile) \

[gentoo-commits] repo/gentoo:master commit in: dev-libs/gecode/

[David Seifert]

commit:     0574885098d75610ed3c0db63daf39f16190db5b
Author:     Harri Nieminen <moikkis <AT> gmail <DOT> com>
AuthorDate: Sat May  6 17:14:28 2017 +0000
Commit:     David Seifert <soap <AT> gentoo <DOT> org>
CommitDate: Sat May  6 22:18:34 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=05748850

dev-libs/gecode: Fix toolong DESCRIPTION

Package-Manager: Portage-2.3.5, Repoman-2.3.2
Closes: https://github.com/gentoo/gentoo/pull/4517

 dev-libs/gecode/gecode-3.7.3.ebuild | 4 ++--
 1 file changed, 2 insertions(+), 2 deletions(-)

diff --git a/dev-libs/gecode/gecode-3.7.3.ebuild b/dev-libs/gecode/gecode-3.7.3.ebuild
index 4e341d57562..463a840f970 100644
--- a/dev-libs/gecode/gecode-3.7.3.ebuild
+++ b/dev-libs/gecode/gecode-3.7.3.ebuild
@@ -1,9 +1,9 @@
-# Copyright 1999-2013 Gentoo Foundation
+# Copyright 1999-2017 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI="4"
 
-DESCRIPTION="Gecode is an environment for developing constraint-based systems and applications"
+DESCRIPTION="An environment for developing constraint-based applications"
 SRC_URI="http://www.gecode.org/download/${P}.tar.gz"
 HOMEPAGE="http://www.gecode.org/"
 

[gentoo-commits] repo/gentoo:master commit in: dev-libs/gecode/

[Michael Orlitzky]

commit:     a91f44dc7772adfd3f3db6adfd37aedee19659c8
Author:     Michael Orlitzky <mjo <AT> gentoo <DOT> org>
AuthorDate: Sat Aug  5 13:31:41 2017 +0000
Commit:     Michael Orlitzky <mjo <AT> gentoo <DOT> org>
CommitDate: Sat Aug  5 13:33:52 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=a91f44dc

dev-libs/gecode: new revision 3.7.3-r1 to fix "doins" -> "dodoc" typo.

Gentoo-Bug: 588944

Package-Manager: Portage-2.3.6, Repoman-2.3.1

 dev-libs/gecode/{gecode-3.7.3.ebuild => gecode-3.7.3-r1.ebuild} | 5 +----
 1 file changed, 1 insertion(+), 4 deletions(-)

diff --git a/dev-libs/gecode/gecode-3.7.3.ebuild b/dev-libs/gecode/gecode-3.7.3-r1.ebuild
similarity index 85%
rename from dev-libs/gecode/gecode-3.7.3.ebuild
rename to dev-libs/gecode/gecode-3.7.3-r1.ebuild
index 463a840f970..644e93c9e26 100644
--- a/dev-libs/gecode/gecode-3.7.3.ebuild
+++ b/dev-libs/gecode/gecode-3.7.3-r1.ebuild
@@ -43,9 +43,6 @@ src_install() {
 	fi
 
 	if use examples; then
-		docinto examples
-		doins examples/*.cpp
-		einfo "Example C++ programs have been installed into " \
-			"/usr/share/doc/${PF}/examples"
+		dodoc -r examples
 	fi
 }

[gentoo-commits] repo/gentoo:master commit in: dev-libs/gecode/

[Michael Orlitzky]

commit:     725fc1fbf99c0607fcd7532b38b31d421485ddb6
Author:     Michael Orlitzky <mjo <AT> gentoo <DOT> org>
AuthorDate: Sat Aug  5 13:30:13 2017 +0000
Commit:     Michael Orlitzky <mjo <AT> gentoo <DOT> org>
CommitDate: Sat Aug  5 13:30:13 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=725fc1fb

dev-libs/gecode: remove unused version 4.4.0.

Package-Manager: Portage-2.3.6, Repoman-2.3.1

 dev-libs/gecode/gecode-4.4.0.ebuild | 69 -------------------------------------
 1 file changed, 69 deletions(-)

diff --git a/dev-libs/gecode/gecode-4.4.0.ebuild b/dev-libs/gecode/gecode-4.4.0.ebuild
deleted file mode 100644
index e4641dd83f3..00000000000
--- a/dev-libs/gecode/gecode-4.4.0.ebuild
+++ /dev/null
@@ -1,69 +0,0 @@
-# Copyright 1999-2016 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-
-DESCRIPTION="An environment for developing constraint-based applications"
-SRC_URI="http://www.gecode.org/download/${P}.tar.gz"
-HOMEPAGE="http://www.gecode.org/"
-
-SLOT="0"
-LICENSE="MIT"
-KEYWORDS="~amd64 ~x86"
-IUSE="doc examples gist gmp test"
-
-RDEPEND="
-	gist? (
-		|| (
-			( dev-qt/qtcore:4 dev-qt/qtgui:4 )
-			( dev-qt/qtcore:5 dev-qt/qtgui:5 )
-		)
-	)
-	gmp? (
-		|| ( dev-libs/gmp:0 sci-libs/mpir )
-		dev-libs/mpfr:0
-	)"
-DEPEND="${RDEPEND}
-	doc? (
-		app-doc/doxygen
-		media-gfx/graphviz
-	)"
-
-src_configure() {
-	 # --disable-examples prevents COMPILING the examples.
-	econf \
-		--docdir="/usr/share/doc/${PF}" \
-		--htmldir="/usr/share/doc/${PF}/html" \
-		--disable-examples \
-		$(use_enable doc doc-dot) \
-		$(use_enable doc doc-tagfile) \
-		$(use_enable gist qt) \
-		$(use_enable gist) \
-		$(use_enable gmp mpfr)
-}
-
-src_compile() {
-	default
-	use doc && emake doc
-}
-
-src_install() {
-	default
-
-	# The --docdir and --htmldir that we pass to configure don't seem to
-	# be respected...
-	use doc && dodoc -r doc/html
-
-	if use examples; then
-		# The build system supports "examples", but we want to install
-		# their source code, not the resulting binaries.
-		rm -f examples/CMakeLists.txt \
-			|| die 'failed to remove examples/CMakeLists.txt'
-		dodoc -r examples
-	fi
-}
-
-src_test() {
-	LD_LIBRARY_PATH="${S}" emake test
-	LD_LIBRARY_PATH="${S}" ./test/test || die "test suite failed"
-}

[gentoo-commits] repo/gentoo:master commit in: dev-libs/gecode/

[Andreas Sturmlechner]

commit:     9b37b6d845e340a83deee1decf0e04b43fc23def
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Fri Jan 12 22:48:39 2018 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Fri Jan 12 22:48:39 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9b37b6d8

dev-libs/gecode: Switch to Qt5

Package-Manager: Portage-2.3.19, Repoman-2.3.6

 dev-libs/gecode/gecode-4.4.0-r2.ebuild | 81 ++++++++++++++++++++++++++++++++++
 1 file changed, 81 insertions(+)

diff --git a/dev-libs/gecode/gecode-4.4.0-r2.ebuild b/dev-libs/gecode/gecode-4.4.0-r2.ebuild
new file mode 100644
index 00000000000..4642b6d3496
--- /dev/null
+++ b/dev-libs/gecode/gecode-4.4.0-r2.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit autotools qmake-utils
+
+DESCRIPTION="An environment for developing constraint-based applications"
+HOMEPAGE="http://www.gecode.org/"
+SRC_URI="http://www.gecode.org/download/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc examples gist gmp"
+
+RDEPEND="
+	gist? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtprintsupport:5
+		dev-qt/qtwidgets:5
+	)
+	gmp? (
+		dev-libs/gmp:0
+		dev-libs/mpfr:0
+	)"
+DEPEND="${RDEPEND}
+	sys-devel/bison
+	sys-devel/flex
+	doc? (
+		app-doc/doxygen
+		media-gfx/graphviz
+	)"
+
+PATCHES=( "${FILESDIR}/${PN}-4.4.0-no-examples.patch" )
+
+src_prepare() {
+	default
+
+	sed -i gecode.m4 \
+		-e "s/-ggdb//" -e "s/-O3//" -e "s/-pipe//" \
+		-e "/AC_CHECK_PROGS(QMAKE/a AC_SUBST(QMAKE,$(qt5_get_bindir)/qmake)" \
+		-e "/AC_CHECK_PROGS(MOC/a AC_SUBST(MOC,$(qt5_get_bindir)/moc)" \
+		|| die
+
+	eautoreconf
+}
+
+src_configure() {
+	 # --disable-examples prevents COMPILING the examples.
+	econf \
+		--disable-examples \
+		$(use_enable doc doc-dot) \
+		$(use_enable doc doc-tagfile) \
+		$(use_enable gist qt) \
+		$(use_enable gist) \
+		$(use_enable gmp mpfr)
+}
+
+src_compile() {
+	default
+	use doc && emake doc
+}
+
+src_test() {
+	LD_LIBRARY_PATH="${S}" emake test
+	LD_LIBRARY_PATH="${S}" ./test/test || die "test suite failed"
+}
+
+src_install() {
+	default
+
+	# The --docdir and --htmldir that we pass to configure don't seem to
+	# be respected...
+	use doc && dodoc -r doc/html/
+
+	if use examples; then
+		dodoc -r examples
+	fi
+}

[gentoo-commits] repo/gentoo:master commit in: dev-libs/gecode/

[Andreas Sturmlechner]

commit:     5d3f68c74a28e36b18a530301721ad1bd75ec428
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Fri Jan 12 22:49:00 2018 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Fri Jan 12 22:49:00 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=5d3f68c7

dev-libs/gecode: Drop old

Package-Manager: Portage-2.3.19, Repoman-2.3.6

 dev-libs/gecode/Manifest               |  1 -
 dev-libs/gecode/gecode-3.7.3-r1.ebuild | 48 ---------------------
 dev-libs/gecode/gecode-4.4.0-r1.ebuild | 79 ----------------------------------
 3 files changed, 128 deletions(-)

diff --git a/dev-libs/gecode/Manifest b/dev-libs/gecode/Manifest
index 9ec9a8c1bcd..144685e2954 100644
--- a/dev-libs/gecode/Manifest
+++ b/dev-libs/gecode/Manifest
@@ -1,2 +1 @@
-DIST gecode-3.7.3.tar.gz 1643336 BLAKE2B bf36fec6ee7f9f76be578de084f6d5c60afb9c01e6d66dcb6e7f35e0105fbf3be9017f8377f09a00502bcd4bc02f97083d23ceb42de16f5361c388fa332f9dba SHA512 292bafeaca3911b8af40d7c0f425cf0263f4408afad47f4f229a821ce89d06dc69ad1feeeef72531a1e711d797d249581b67c2d9cfdc9e544240012c838d2a5b
 DIST gecode-4.4.0.tar.gz 2889186 BLAKE2B b98692f841f8af292371b222c5dd8fda771eee48664e415daa84fd34c6430276fbc96c127491c8eb0fb86c1744f4137ecd1556420ddddc72af70ff0712999bd7 SHA512 5189a3c5f9f34371a0bc94528e8ca65efb0a3078ec158887f47a816d6fe3c879a7e908ee421414bc317754333ecb73806c8fc46b0b6b7d8419cdf6f13a4f8aef

diff --git a/dev-libs/gecode/gecode-3.7.3-r1.ebuild b/dev-libs/gecode/gecode-3.7.3-r1.ebuild
deleted file mode 100644
index 644e93c9e26..00000000000
--- a/dev-libs/gecode/gecode-3.7.3-r1.ebuild
+++ /dev/null
@@ -1,48 +0,0 @@
-# Copyright 1999-2017 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI="4"
-
-DESCRIPTION="An environment for developing constraint-based applications"
-SRC_URI="http://www.gecode.org/download/${P}.tar.gz"
-HOMEPAGE="http://www.gecode.org/"
-
-SLOT="0"
-LICENSE="MIT"
-KEYWORDS="~amd64 ~x86"
-IUSE="doc examples gist"
-
-DEPEND="gist? (
-	dev-qt/qtcore:4
-	dev-qt/qtgui:4
-	media-libs/freetype
-	media-libs/libpng
-	>=dev-libs/glib-2
-)"
-RDEPEND="${DEPEND}"
-
-src_configure() {
-	econf \
-		--disable-examples \
-		$(use_enable gist qt) \
-		$(use_enable gist)
-}
-
-src_compile() {
-	default
-	use doc && emake doc
-}
-
-src_install() {
-	default
-
-	if use doc; then
-		dohtml -r doc/html/
-		einfo "HTML documentation has been installed into " \
-			"/usr/share/doc/${PF}/html"
-	fi
-
-	if use examples; then
-		dodoc -r examples
-	fi
-}

diff --git a/dev-libs/gecode/gecode-4.4.0-r1.ebuild b/dev-libs/gecode/gecode-4.4.0-r1.ebuild
deleted file mode 100644
index 3a38dc91e03..00000000000
--- a/dev-libs/gecode/gecode-4.4.0-r1.ebuild
+++ /dev/null
@@ -1,79 +0,0 @@
-# Copyright 1999-2016 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-
-inherit autotools qmake-utils
-
-DESCRIPTION="An environment for developing constraint-based applications"
-HOMEPAGE="http://www.gecode.org/"
-SRC_URI="http://www.gecode.org/download/${P}.tar.gz"
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE="doc examples gist gmp"
-
-RDEPEND="
-	gist? (
-		dev-qt/qtcore:4
-		dev-qt/qtgui:4
-	)
-	gmp? (
-		dev-libs/gmp:0
-		dev-libs/mpfr:0
-	)"
-DEPEND="${RDEPEND}
-	sys-devel/bison
-	sys-devel/flex
-	doc? (
-		app-doc/doxygen
-		media-gfx/graphviz
-	)"
-
-PATCHES=( "${FILESDIR}/${PN}-4.4.0-no-examples.patch" )
-
-src_prepare() {
-	default
-
-	sed -i gecode.m4 \
-		-e "s/-ggdb//" -e "s/-O3//" -e "s/-pipe//" \
-		-e "/AC_CHECK_PROGS(QMAKE/a AC_SUBST(QMAKE,$(qt4_get_bindir)/qmake)" \
-		-e "/AC_CHECK_PROGS(MOC/a AC_SUBST(MOC,$(qt4_get_bindir)/moc)" \
-		|| die
-
-	eautoreconf
-}
-
-src_configure() {
-	 # --disable-examples prevents COMPILING the examples.
-	econf \
-		--disable-examples \
-		$(use_enable doc doc-dot) \
-		$(use_enable doc doc-tagfile) \
-		$(use_enable gist qt) \
-		$(use_enable gist) \
-		$(use_enable gmp mpfr)
-}
-
-src_compile() {
-	default
-	use doc && emake doc
-}
-
-src_test() {
-	LD_LIBRARY_PATH="${S}" emake test
-	LD_LIBRARY_PATH="${S}" ./test/test || die "test suite failed"
-}
-
-src_install() {
-	default
-
-	# The --docdir and --htmldir that we pass to configure don't seem to
-	# be respected...
-	use doc && dodoc -r doc/html/
-
-	if use examples; then
-		dodoc -r examples
-	fi
-}

[gentoo-commits] repo/gentoo:master commit in: dev-libs/gecode/

[Andreas Sturmlechner]

commit:     6749e2e3338dc68e22ef18158b595077a8da6334
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Fri Jan 12 23:27:21 2018 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Fri Jan 12 23:31:09 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=6749e2e3

dev-libs/gecode: Re-add 3.7.3-r1 w/o USE=gist

Package-Manager: Portage-2.3.19, Repoman-2.3.6

 dev-libs/gecode/Manifest               |  1 +
 dev-libs/gecode/gecode-3.7.3-r1.ebuild | 42 ++++++++++++++++++++++++++++++++++
 2 files changed, 43 insertions(+)

diff --git a/dev-libs/gecode/Manifest b/dev-libs/gecode/Manifest
index 144685e2954..9ec9a8c1bcd 100644
--- a/dev-libs/gecode/Manifest
+++ b/dev-libs/gecode/Manifest
@@ -1 +1,2 @@
+DIST gecode-3.7.3.tar.gz 1643336 BLAKE2B bf36fec6ee7f9f76be578de084f6d5c60afb9c01e6d66dcb6e7f35e0105fbf3be9017f8377f09a00502bcd4bc02f97083d23ceb42de16f5361c388fa332f9dba SHA512 292bafeaca3911b8af40d7c0f425cf0263f4408afad47f4f229a821ce89d06dc69ad1feeeef72531a1e711d797d249581b67c2d9cfdc9e544240012c838d2a5b
 DIST gecode-4.4.0.tar.gz 2889186 BLAKE2B b98692f841f8af292371b222c5dd8fda771eee48664e415daa84fd34c6430276fbc96c127491c8eb0fb86c1744f4137ecd1556420ddddc72af70ff0712999bd7 SHA512 5189a3c5f9f34371a0bc94528e8ca65efb0a3078ec158887f47a816d6fe3c879a7e908ee421414bc317754333ecb73806c8fc46b0b6b7d8419cdf6f13a4f8aef

diff --git a/dev-libs/gecode/gecode-3.7.3-r1.ebuild b/dev-libs/gecode/gecode-3.7.3-r1.ebuild
new file mode 100644
index 00000000000..f586564191f
--- /dev/null
+++ b/dev-libs/gecode/gecode-3.7.3-r1.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="4"
+
+DESCRIPTION="An environment for developing constraint-based applications"
+SRC_URI="http://www.gecode.org/download/${P}.tar.gz"
+HOMEPAGE="http://www.gecode.org/"
+
+SLOT="0"
+LICENSE="MIT"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc examples"
+
+DEPEND=""
+RDEPEND="${DEPEND}"
+
+src_configure() {
+	econf \
+		--disable-examples \
+		--disable-gist \
+		--disable-qt
+}
+
+src_compile() {
+	default
+	use doc && emake doc
+}
+
+src_install() {
+	default
+
+	if use doc; then
+		dohtml -r doc/html/
+		einfo "HTML documentation has been installed into " \
+			"/usr/share/doc/${PF}/html"
+	fi
+
+	if use examples; then
+		dodoc -r examples
+	fi
+}