[gentoo-commits] repo/gentoo:master commit in: media-libs/gegl/, media-libs/gegl/files/

["Sebastian Pipping" <sping@gentoo.org>]

commit:     64c8f56ec6b193ccab99d03de658684e5eb7e599
Author:     Sebastian Pipping <sping <AT> gentoo <DOT> org>
AuthorDate: Wed Jan 10 22:03:12 2018 +0000
Commit:     Sebastian Pipping <sping <AT> gentoo <DOT> org>
CommitDate: Wed Jan 10 22:08:13 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=64c8f56e

media-libs/gegl: Remove ghost dependency on media-gfx/exiv2

Configure option --without-exiv2 was used already but broken
in a way where it would still do auto-detection for exiv2 and
end up linking a non-inst programm against it.
Ebuilds for 0.3.20+ do not need patching as its fixed upstream
for a while now.

Closes: https://bugs.gentoo.org/641872

Package-Manager: Portage-2.3.19, Repoman-2.3.6

 .../gegl/files/gegl-0.2.0-fix-without-exiv2.patch  |  30 ++++
 media-libs/gegl/gegl-0.2.0-r4.ebuild               |   3 +-
 .../{gegl-0.2.0-r4.ebuild => gegl-0.3.0-r1.ebuild} | 123 ++++++++------
 media-libs/gegl/gegl-0.3.8-r1.ebuild               | 180 +++++++++++++++++++++
 4 files changed, 285 insertions(+), 51 deletions(-)

diff --git a/media-libs/gegl/files/gegl-0.2.0-fix-without-exiv2.patch b/media-libs/gegl/files/gegl-0.2.0-fix-without-exiv2.patch
new file mode 100644
index 00000000000..96a4188926d
--- /dev/null
+++ b/media-libs/gegl/files/gegl-0.2.0-fix-without-exiv2.patch
@@ -0,0 +1,30 @@
+From c0b4da18e199d1043738c034269f5dd6a4aa7d99 Mon Sep 17 00:00:00 2001
+From: Sebastian Pipping <sebastian@pipping.org>
+Date: Wed, 10 Jan 2018 22:39:05 +0100
+Subject: [PATCH] Fix ./configure --without-exiv2
+
+Variable names were in error
+
+Bug: https://bugs.gentoo.org/641872
+---
+ configure.ac | 4 ++--
+ 1 file changed, 2 insertions(+), 2 deletions(-)
+
+diff --git a/configure.ac b/configure.ac
+index 30d306e..146b271 100644
+--- a/configure.ac
++++ b/configure.ac
+@@ -977,8 +977,8 @@ AC_SUBST(LIBSPIRO)
+ 
+ AC_ARG_WITH(exiv2, [  --without-exiv2         build without libexiv2 support])
+ 
+-have_libexiv2="no"
+-if test "x$with_libexiv2" != "xno"; then
++have_exiv2="no"
++if test "x$with_exiv2" != "xno"; then
+   PKG_CHECK_MODULES(EXIV2, exiv2,
+     have_exiv2="yes",
+     have_exiv2="no  (exiv2 library not found)")
+-- 
+2.16.0.rc0
+

diff --git a/media-libs/gegl/gegl-0.2.0-r4.ebuild b/media-libs/gegl/gegl-0.2.0-r4.ebuild
index 2d8d8728da8..f1b427ba45a 100644
--- a/media-libs/gegl/gegl-0.2.0-r4.ebuild
+++ b/media-libs/gegl/gegl-0.2.0-r4.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2017 Gentoo Foundation
+# Copyright 1999-2018 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=6
@@ -76,6 +76,7 @@ src_prepare() {
 	# https://bugs.gentoo.org/show_bug.cgi?id=617430
 	epatch "${FILESDIR}"/${P}-underlinking.patch
 	epatch "${FILESDIR}"/${P}-libopenraw-0.1.patch  # bug 639834
+	epatch "${FILESDIR}"/${P}-fix-without-exiv2.patch  # bug 641872
 
 	eapply_user
 	eautoreconf

diff --git a/media-libs/gegl/gegl-0.2.0-r4.ebuild b/media-libs/gegl/gegl-0.3.0-r1.ebuild
similarity index 54%
copy from media-libs/gegl/gegl-0.2.0-r4.ebuild
copy to media-libs/gegl/gegl-0.3.0-r1.ebuild
index 2d8d8728da8..5e6d76c9487 100644
--- a/media-libs/gegl/gegl-0.2.0-r4.ebuild
+++ b/media-libs/gegl/gegl-0.3.0-r1.ebuild
@@ -1,68 +1,78 @@
-# Copyright 1999-2017 Gentoo Foundation
+# Copyright 1999-2018 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=6
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 )
 
-WANT_AUTOMAKE=1.11  # see bug 471990, comment 3
 # vala and introspection support is broken, bug #468208
-#VALA_MIN_API_VERSION=0.14
-#VALA_USE_DEPEND=vapigen
+VALA_MIN_API_VERSION=0.20
+VALA_USE_DEPEND=vapigen
+
+inherit versionator gnome2-utils eutils autotools python-any-r1 vala
 
-inherit versionator gnome2-utils eutils autotools #vala
+if [[ ${PV} == *9999* ]]; then
+	inherit autotools git-r3
+	EGIT_REPO_URI="git://git.gnome.org/gegl"
+	SRC_URI=""
+else
+	SRC_URI="http://download.gimp.org/pub/${PN}/${PV:0:3}/${P}.tar.bz2"
+	KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x64-solaris ~x86-solaris"
+fi
 
 DESCRIPTION="A graph based image processing framework"
 HOMEPAGE="http://www.gegl.org/"
-SRC_URI="ftp://ftp.gimp.org/pub/${PN}/${PV:0:3}/${P}.tar.bz2"
 
 LICENSE="|| ( GPL-3 LGPL-3 )"
-SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x64-solaris ~x86-solaris"
+SLOT="0.3"
 
-IUSE="cairo debug ffmpeg jpeg jpeg2k lensfun libav cpu_flags_x86_mmx openexr png raw sdl cpu_flags_x86_sse svg umfpack" # +introspection vala
+IUSE="cairo cpu_flags_x86_mmx cpu_flags_x86_sse debug ffmpeg +introspection jpeg jpeg2k lcms lensfun libav openexr png raw sdl svg test umfpack vala v4l webp"
+REQUIRED_USE="vala? ( introspection )"
 
 RDEPEND="
-	>=media-libs/babl-0.1.10
-	>=dev-libs/glib-2.28:2
+	>=dev-libs/glib-2.36:2
+	dev-libs/json-glib
+	>=media-libs/babl-0.1.12
+	sys-libs/zlib
 	>=x11-libs/gdk-pixbuf-2.18:2
 	x11-libs/pango
-	sys-libs/zlib
+
 	cairo? ( x11-libs/cairo )
 	ffmpeg? (
 		libav? ( media-video/libav:0= )
 		!libav? ( media-video/ffmpeg:0= )
 	)
-	jpeg? ( virtual/jpeg:0 )
+	introspection? ( >=dev-libs/gobject-introspection-1.32 )
+	jpeg? ( virtual/jpeg:0= )
 	jpeg2k? ( >=media-libs/jasper-1.900.1:= )
+	lcms? ( >=media-libs/lcms-2.2:2 )
+	lensfun? ( >=media-libs/lensfun-0.2.5 )
 	openexr? ( media-libs/openexr )
 	png? ( media-libs/libpng:0= )
-	raw? ( >=media-libs/libopenraw-0.1:0= )
+	raw? ( =media-libs/libopenraw-0.0.9 )
 	sdl? ( media-libs/libsdl )
 	svg? ( >=gnome-base/librsvg-2.14:2 )
 	umfpack? ( sci-libs/umfpack )
-	lensfun? ( >=media-libs/lensfun-0.2.5 )
+	v4l? ( >=media-libs/libv4l-1.0.1 )
+	webp? ( media-libs/libwebp )
 "
-#	>=media-libs/babl-0.1.10[introspection?]
-#	introspection? ( >=dev-libs/gobject-introspection-0.10
-#			>=dev-python/pygobject-2.26:2 )
 DEPEND="${RDEPEND}
+	>=dev-util/gtk-doc-am-1
 	>=dev-util/intltool-0.40.1
 	dev-lang/perl
 	virtual/pkgconfig
 	>=sys-devel/libtool-2.2
+	test? ( introspection? (
+		$(python_gen_any_dep '>=dev-python/pygobject-3.2[${PYTHON_USEDEP}]') ) )
+	vala? ( $(vala_depend) )
 "
-#	vala? ( $(vala_depend) )"
 
-DOCS=( ChangeLog INSTALL README NEWS )
+pkg_setup() {
+	use test && use introspection && python-any-r1_pkg_setup
+}
 
 src_prepare() {
-	# https://bugs.gentoo.org/show_bug.cgi?id=442016
-	epatch "${FILESDIR}/${P}-cve-2012-4433-1e92e523.patch"
-	epatch "${FILESDIR}/${P}-cve-2012-4433-4757cdf7.patch"
-
-	# https://bugs.gentoo.org/show_bug.cgi?id=416587
-	epatch "${FILESDIR}/${P}-introspection-version.patch"
-
-	epatch "${FILESDIR}/${P}-ffmpeg-0.11.diff"
+	# FIXME: the following should be proper patch sent to upstream
 	# fix OSX loadable module filename extension
 	sed -i -e 's/\.dylib/.bundle/' configure.ac || die
 	# don't require Apple's OpenCL on versions of OSX that don't have it
@@ -70,21 +80,28 @@ src_prepare() {
 		sed -i -e 's/#ifdef __APPLE__/#if 0/' gegl/opencl/* || die
 	fi
 
-	epatch "${FILESDIR}"/${P}-g_log_domain.patch
+	#epatch "${FILESDIR}"/${P}-g_log_domain.patch
 
-	# https://bugs.gentoo.org/show_bug.cgi?id=605216
-	# https://bugs.gentoo.org/show_bug.cgi?id=617430
-	epatch "${FILESDIR}"/${P}-underlinking.patch
-	epatch "${FILESDIR}"/${P}-libopenraw-0.1.patch  # bug 639834
+	# commit 7c78497b : tests that use gegl.png are broken on non-amd64
+	sed -e '/clones.xml/d' \
+		-e '/composite-transform.xml/d' \
+		-i tests/compositions/Makefile.am || die
 
-	eapply_user
-	eautoreconf
+	# commit 11a283ab : test-image-compare needs >=babl-0.1.13 (not released yet)
+	# for the new CIE conversions
+	sed -e '/test-image-compare/d' \
+		-i tests/simple/Makefile.am || die
+
+	# Skip broken test with >=dev-python/pygobject-3.14
+	sed -e '/test_buffer/ i\    @unittest.skip("broken")\' \
+		-i tests/python/test-gegl-format.py || die
 
-	# https://bugs.gentoo.org/show_bug.cgi?id=468248
-	local deps_file="${PN}/${PN}-$(get_version_component_range 1-2).deps"
-	[[ -f "${deps_file}" ]] || touch "${deps_file}"
+	epatch "${FILESDIR}"/${PN}-0.2.0-fix-without-exiv2.patch  # bug 641872
 
-#	use vala && vala_src_prepare
+	epatch_user
+	eautoreconf
+
+	use vala && vala_src_prepare
 }
 
 src_configure() {
@@ -114,11 +131,14 @@ src_configure() {
 	# https://bugs.gentoo.org/show_bug.cgi?id=451136
 	#
 	econf \
-		--disable-silent-rules \
+		--disable-docs \
 		--disable-profile \
+		--disable-silent-rules \
+		--disable-workshop \
+		--program-suffix=-${SLOT} \
+		--with-gdk-pixbuf \
+		--with-pango \
 		--without-libspiro \
-		--disable-docs --disable-workshop \
-		--with-pango --with-gdk-pixbuf \
 		$(use_enable cpu_flags_x86_mmx mmx) \
 		$(use_enable cpu_flags_x86_sse sse) \
 		$(use_enable debug) \
@@ -129,6 +149,8 @@ src_configure() {
 		--without-graphviz \
 		$(use_with jpeg libjpeg) \
 		$(use_with jpeg2k jasper) \
+		$(use_with lcms) \
+		$(use_with lensfun) \
 		--without-lua \
 		$(use_with openexr) \
 		$(use_with png libpng) \
@@ -136,12 +158,11 @@ src_configure() {
 		$(use_with sdl) \
 		$(use_with svg librsvg) \
 		$(use_with umfpack) \
-		--without-libv4l \
-		$(use_with lensfun) \
-		--disable-introspection \
-		--without-vala
-#		$(use_enable introspection) \
-#		$(use_with vala)
+		$(use_with v4l libv4l) \
+		$(use_with v4l libv4l2) \
+		$(use_enable introspection) \
+		$(use_with vala) \
+		$(use_with webp)
 }
 
 src_test() {
@@ -152,9 +173,11 @@ src_test() {
 src_compile() {
 	gnome2_environment_reset  # sandbox issues (bug #396687)
 	default
+
+	[[ ${PV} == *9999* ]] && emake ./ChangeLog  # "./" prevents "Circular ChangeLog <- ChangeLog dependency dropped."
 }
 
 src_install() {
 	default
-	find "${ED}" -name '*.la' -delete
+	prune_libtool_files --all
 }

diff --git a/media-libs/gegl/gegl-0.3.8-r1.ebuild b/media-libs/gegl/gegl-0.3.8-r1.ebuild
new file mode 100644
index 00000000000..63e40fdf726
--- /dev/null
+++ b/media-libs/gegl/gegl-0.3.8-r1.ebuild
@@ -0,0 +1,180 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 )
+
+# vala and introspection support is broken, bug #468208
+VALA_USE_DEPEND=vapigen
+
+inherit versionator gnome2-utils eutils autotools python-any-r1 vala
+
+if [[ ${PV} == *9999* ]]; then
+	inherit autotools git-r3
+	EGIT_REPO_URI="git://git.gnome.org/gegl"
+	SRC_URI=""
+else
+	SRC_URI="http://download.gimp.org/pub/${PN}/${PV:0:3}/${P}.tar.bz2"
+	KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x64-solaris ~x86-solaris"
+fi
+
+DESCRIPTION="A graph based image processing framework"
+HOMEPAGE="http://www.gegl.org/"
+
+LICENSE="|| ( GPL-3 LGPL-3 )"
+SLOT="0.3"
+
+IUSE="cairo cpu_flags_x86_mmx cpu_flags_x86_sse debug ffmpeg +introspection jpeg2k lcms lensfun openexr raw sdl svg test tiff umfpack vala v4l webp"
+REQUIRED_USE="
+	svg? ( cairo )
+	vala? ( introspection )
+"
+
+# NOTE: Even current libav 11.4 does not have AV_CODEC_CAP_VARIABLE_FRAME_SIZE
+#       so there is no chance to support libav right now (Gentoo bug #567638)
+#       If it returns, please check prior GEGL ebuilds for how libav was integrated.  Thanks!
+RDEPEND="
+	>=dev-libs/glib-2.36:2
+	dev-libs/json-glib
+	>=media-libs/babl-0.1.14
+	sys-libs/zlib
+	>=x11-libs/gdk-pixbuf-2.18:2
+	x11-libs/pango
+
+	cairo? ( x11-libs/cairo )
+	ffmpeg? (
+		>=media-video/ffmpeg-2.8:0=
+	)
+	introspection? ( >=dev-libs/gobject-introspection-1.32:= )
+	virtual/jpeg:0=
+	jpeg2k? ( >=media-libs/jasper-1.900.1:= )
+	lcms? ( >=media-libs/lcms-2.2:2 )
+	lensfun? ( >=media-libs/lensfun-0.2.5 )
+	openexr? ( media-libs/openexr:= )
+	media-libs/libpng:0=
+	raw? ( >=media-libs/libraw-0.15.4 )
+	sdl? ( media-libs/libsdl )
+	svg? ( >=gnome-base/librsvg-2.14:2 )
+	tiff? ( >=media-libs/tiff-4:0 )
+	umfpack? ( sci-libs/umfpack )
+	v4l? ( >=media-libs/libv4l-1.0.1 )
+	webp? ( media-libs/libwebp )
+"
+DEPEND="${RDEPEND}
+	>=dev-util/gtk-doc-am-1
+	>=dev-util/intltool-0.40.1
+	dev-lang/perl
+	virtual/pkgconfig
+	>=sys-devel/libtool-2.2
+	test? ( introspection? (
+		$(python_gen_any_dep '>=dev-python/pygobject-3.2[${PYTHON_USEDEP}]') ) )
+	vala? ( $(vala_depend) )
+"
+
+pkg_setup() {
+	use test && use introspection && python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+
+	# FIXME: the following should be proper patch sent to upstream
+	# fix OSX loadable module filename extension
+	sed -i -e 's/\.dylib/.bundle/' configure.ac || die
+	# don't require Apple's OpenCL on versions of OSX that don't have it
+	if [[ ${CHOST} == *-darwin* && ${CHOST#*-darwin} -le 9 ]] ; then
+		sed -i -e 's/#ifdef __APPLE__/#if 0/' gegl/opencl/* || die
+	fi
+
+	#epatch "${FILESDIR}"/${P}-g_log_domain.patch
+
+	# commit 7c78497b : tests that use gegl.png are broken on non-amd64
+	sed -e '/clones.xml/d' \
+		-e '/composite-transform.xml/d' \
+		-i tests/compositions/Makefile.am || die
+
+	epatch "${FILESDIR}"/${PN}-0.3.12-failing-tests.patch
+	epatch "${FILESDIR}"/${PN}-0.2.0-fix-without-exiv2.patch  # bug 641872
+
+	eautoreconf
+
+	gnome2_environment_reset
+
+	use vala && vala_src_prepare
+}
+
+src_configure() {
+	# never enable altering of CFLAGS via profile option
+	# libspiro: not in portage main tree
+	# disable documentation as the generating is bit automagic
+	#    if anyone wants to work on it just create bug with patch
+
+	# Also please note that:
+	#
+	#  - Some auto-detections are not patched away since the docs are
+	#    not built (--disable-docs, lack of --enable-gtk-doc) and these
+	#    tools affect re-generation of docs, only
+	#    (e.g. ruby, asciidoc, dot (of graphviz), enscript)
+	#
+	#  - Parameter --with-exiv2 compiles a noinst-app only, no use
+	#
+	#  - Parameter --disable-workshop disables any use of Lua, effectivly
+	#
+	#  - v4l support does not work with our media-libs/libv4l-0.8.9,
+	#    upstream bug at https://bugzilla.gnome.org/show_bug.cgi?id=654675
+	#
+	#  - There are two checks for dot, one controllable by --with(out)-graphviz
+	#    which toggles HAVE_GRAPHVIZ that is not used anywhere.  Yes.
+	#
+	#  - mrg is not in tree and gexiv2 support only has effect when mrg support
+	#    is enabled
+	#
+	# So that's why USE="exif graphviz lua v4l" got resolved.  More at:
+	# https://bugs.gentoo.org/show_bug.cgi?id=451136
+	#
+	econf \
+		--disable-docs \
+		--disable-profile \
+		--disable-silent-rules \
+		--disable-workshop \
+		--program-suffix=-${SLOT} \
+		--with-gdk-pixbuf \
+		--with-pango \
+		--without-libspiro \
+		$(use_enable cpu_flags_x86_mmx mmx) \
+		$(use_enable cpu_flags_x86_sse sse) \
+		$(use_enable debug) \
+		$(use_with cairo) \
+		$(use_with cairo pangocairo) \
+		--without-exiv2 \
+		$(use_with ffmpeg libavformat) \
+		--without-gexiv2 \
+		--without-graphviz \
+		$(use_with jpeg2k jasper) \
+		$(use_with lcms) \
+		$(use_with lensfun) \
+		--without-lua \
+		--without-mrg \
+		$(use_with openexr) \
+		$(use_with raw libraw) \
+		$(use_with sdl) \
+		$(use_with svg librsvg) \
+		$(use_with tiff libtiff) \
+		$(use_with umfpack) \
+		$(use_with v4l libv4l) \
+		$(use_with v4l libv4l2) \
+		$(use_enable introspection) \
+		$(use_with vala) \
+		$(use_with webp)
+}
+
+src_compile() {
+	default
+
+	[[ ${PV} == *9999* ]] && emake ./ChangeLog  # "./" prevents "Circular ChangeLog <- ChangeLog dependency dropped."
+}
+
+src_install() {
+	default
+	prune_libtool_files --all
+}