From mboxrd@z Thu Jan  1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-994839-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
	(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
	(No client certificate requested)
	by finch.gentoo.org (Postfix) with ESMTPS id 3F2FB138206
	for <garchives@archives.gentoo.org>; Wed,  3 Jan 2018 22:22:32 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
	by pigeon.gentoo.org (Postfix) with SMTP id 464D2E0932;
	Wed,  3 Jan 2018 22:21:55 +0000 (UTC)
Received: from smtp.gentoo.org (mail.gentoo.org [IPv6:2001:470:ea4a:1:5054:ff:fec7:86e4])
	(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
	(No client certificate requested)
	by pigeon.gentoo.org (Postfix) with ESMTPS id 16340E0932
	for <gentoo-commits@lists.gentoo.org>; Wed,  3 Jan 2018 22:21:55 +0000 (UTC)
Received: from oystercatcher.gentoo.org (oystercatcher.gentoo.org [148.251.78.52])
	(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
	(No client certificate requested)
	by smtp.gentoo.org (Postfix) with ESMTPS id E3E2F335C3C
	for <gentoo-commits@lists.gentoo.org>; Wed,  3 Jan 2018 22:21:53 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
	by oystercatcher.gentoo.org (Postfix) with ESMTP id 1A2991AB
	for <gentoo-commits@lists.gentoo.org>; Wed,  3 Jan 2018 22:21:51 +0000 (UTC)
From: "Michał Górny" <mgorny@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Michał Górny" <mgorny@gentoo.org>
Message-ID: <1515018099.1742e5f90c62e76898802dcb1710ed683ab77ae0.mgorny@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: dev-util/lldb/
X-VCS-Repository: repo/gentoo
X-VCS-Files: dev-util/lldb/lldb-6.0.9999.ebuild
X-VCS-Directories: dev-util/lldb/
X-VCS-Committer: mgorny
X-VCS-Committer-Name: Michał Górny
X-VCS-Revision: 1742e5f90c62e76898802dcb1710ed683ab77ae0
X-VCS-Branch: master
Date: Wed,  3 Jan 2018 22:21:51 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Archives-Salt: 284de90e-3de2-47e5-8526-8e680bc4247f
X-Archives-Hash: 70a06aa4c0e51cc4aab6ac0a83bc3e3a

commit:     1742e5f90c62e76898802dcb1710ed683ab77ae0
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Wed Jan  3 21:23:48 2018 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Wed Jan  3 22:21:39 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1742e5f9

dev-util/lldb: Add a live ebuild for 6.0 branch

 dev-util/lldb/lldb-6.0.9999.ebuild | 122 +++++++++++++++++++++++++++++++++++++
 1 file changed, 122 insertions(+)

diff --git a/dev-util/lldb/lldb-6.0.9999.ebuild b/dev-util/lldb/lldb-6.0.9999.ebuild
new file mode 100644
index 00000000000..002f1571b63
--- /dev/null
+++ b/dev-util/lldb/lldb-6.0.9999.ebuild
@@ -0,0 +1,122 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+: ${CMAKE_MAKEFILE_GENERATOR:=ninja}
+# (needed due to CMAKE_BUILD_TYPE != Gentoo)
+CMAKE_MIN_VERSION=3.7.0-r1
+PYTHON_COMPAT=( python2_7 )
+
+inherit cmake-utils git-r3 llvm python-single-r1 toolchain-funcs
+
+DESCRIPTION="The LLVM debugger"
+HOMEPAGE="https://llvm.org/"
+SRC_URI=""
+EGIT_REPO_URI="https://git.llvm.org/git/lldb.git
+	https://github.com/llvm-mirror/lldb.git"
+EGIT_BRANCH="release_60"
+
+LICENSE="UoI-NCSA"
+SLOT="0"
+KEYWORDS=""
+IUSE="libedit ncurses python test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	libedit? ( dev-libs/libedit:0= )
+	ncurses? ( >=sys-libs/ncurses-5.9-r3:0= )
+	python? ( dev-python/six[${PYTHON_USEDEP}]
+		${PYTHON_DEPS} )
+	~sys-devel/clang-${PV}[xml]
+	~sys-devel/llvm-${PV}
+	!<sys-devel/llvm-4.0"
+# swig-3.0.9+ generates invalid wrappers, #598708
+# upstream: https://github.com/swig/swig/issues/769
+DEPEND="${RDEPEND}
+	python? ( <dev-lang/swig-3.0.9 )
+	test? ( ~dev-python/lit-${PV}[${PYTHON_USEDEP}] )
+	${PYTHON_DEPS}"
+
+REQUIRED_USE=${PYTHON_REQUIRED_USE}
+
+# least intrusive of all
+CMAKE_BUILD_TYPE=RelWithDebInfo
+
+pkg_setup() {
+	llvm_pkg_setup
+	python-single-r1_pkg_setup
+}
+
+src_unpack() {
+	if use test; then
+		# needed for patched gtest
+		git-r3_fetch "https://git.llvm.org/git/llvm.git
+			https://github.com/llvm-mirror/llvm.git"
+	fi
+	git-r3_fetch
+
+	if use test; then
+		git-r3_checkout https://llvm.org/git/llvm.git \
+			"${WORKDIR}"/llvm '' lib/Testing/Support utils/unittest
+	fi
+	git-r3_checkout
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DLLDB_DISABLE_CURSES=$(usex !ncurses)
+		-DLLDB_DISABLE_LIBEDIT=$(usex !libedit)
+		-DLLDB_DISABLE_PYTHON=$(usex !python)
+		-DLLVM_ENABLE_TERMINFO=$(usex ncurses)
+
+		-DLLDB_INCLUDE_TESTS=$(usex test)
+		-DLLVM_BUILD_TESTS=$(usex test)
+		# compilers for lit tests
+		-DLLDB_TEST_C_COMPILER="$(type -P clang)"
+		-DLLDB_TEST_CXX_COMPILER="$(type -P clang++)"
+		# compiler for ole' python tests
+		-DLLDB_TEST_COMPILER="$(type -P clang)"
+
+		# TODO: fix upstream to detect this properly
+		-DHAVE_LIBDL=ON
+		-DHAVE_LIBPTHREAD=ON
+
+		# normally we'd have to set LLVM_ENABLE_TERMINFO, HAVE_TERMINFO
+		# and TERMINFO_LIBS... so just force FindCurses.cmake to use
+		# ncurses with complete library set (including autodetection
+		# of -ltinfo)
+		-DCURSES_NEED_NCURSES=ON
+	)
+	use test && mycmakeargs+=(
+		-DLLVM_MAIN_SRC_DIR="${WORKDIR}/llvm"
+		-DLLVM_EXTERNAL_LIT="${EPREFIX}/usr/bin/lit"
+		-DLLVM_LIT_ARGS="-vv"
+	)
+
+	cmake-utils_src_configure
+}
+
+src_test() {
+	cmake-utils_src_make check-lldb-lit
+	use python && cmake-utils_src_make check-lldb
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	# oh my...
+	if use python; then
+		# remove bundled six module
+		rm "${D}$(python_get_sitedir)/six.py" || die
+
+		# remove custom readline.so for now
+		# TODO: figure out how to deal with it
+		# upstream is basically building a custom readline.so with -ledit
+		# to avoid symbol collisions between readline and libedit...
+		rm "${D}$(python_get_sitedir)/readline.so" || die
+
+		# byte-compile the modules
+		python_optimize
+	fi
+}