[gentoo-commits] repo/gentoo:master commit in: media-sound/teamspeak-client-bin/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     7ebcee0bb2258960da6d9559056bd689d0816c00
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Wed Dec 27 20:55:10 2017 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Wed Dec 27 23:25:12 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=7ebcee0b

media-sound/teamspeak-client-bin: Prepare for dev-libs/quazip w/o qt4

Package-Manager: Portage-2.3.19, Repoman-2.3.6

 .../teamspeak-client-bin-3.0.19.4-r1.ebuild        | 78 ++++++++++++++++++++++
 1 file changed, 78 insertions(+)

diff --git a/media-sound/teamspeak-client-bin/teamspeak-client-bin-3.0.19.4-r1.ebuild b/media-sound/teamspeak-client-bin/teamspeak-client-bin-3.0.19.4-r1.ebuild
new file mode 100644
index 00000000000..c9cb5a1fa0f
--- /dev/null
+++ b/media-sound/teamspeak-client-bin/teamspeak-client-bin-3.0.19.4-r1.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit eutils unpacker
+
+DESCRIPTION="TeamSpeak Client - Voice Communication Software"
+HOMEPAGE="https://www.teamspeak.com/"
+SRC_URI="
+	amd64? ( http://ftp.4players.de/pub/hosted/ts3/releases/${PV}/TeamSpeak3-Client-linux_amd64-${PV/_/-}.run )
+	x86? ( http://ftp.4players.de/pub/hosted/ts3/releases/${PV}/TeamSpeak3-Client-linux_x86-${PV/_/-}.run )"
+
+LICENSE="teamspeak3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="alsa pulseaudio"
+
+REQUIRED_USE="|| ( alsa pulseaudio )"
+
+RDEPEND="
+	>=dev-libs/quazip-0.7.3[-qt4(-),qt5(+)]
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5[accessibility]
+	dev-qt/qtnetwork:5
+	dev-qt/qtsql:5[sqlite]
+	dev-qt/qtwidgets:5
+	sys-libs/glibc
+	sys-libs/zlib
+	alsa? ( media-libs/alsa-lib )
+	pulseaudio? ( media-sound/pulseaudio )"
+
+RESTRICT="mirror strip"
+
+S="${WORKDIR}"
+
+pkg_nofetch() {
+	elog "Please download ${A}"
+	elog "from ${HOMEPAGE}?page=downloads and place this"
+	elog "file in ${DISTDIR}"
+}
+
+src_prepare() {
+	default
+
+	# Remove the qt-libraries as they just cause trouble with the system's Qt, see bug #328807.
+	rm libQt* || die "Couldn't remove bundled Qt libraries."
+
+	rm -r platforms sqldrivers qt.conf || die "Couldn't remove bundle Qt files."
+
+	# Remove unwanted soundbackends.
+	if ! use alsa ; then
+		rm soundbackends/libalsa* || die
+	fi
+
+	if ! use pulseaudio ; then
+		rm soundbackends/libpulseaudio* || die
+	fi
+
+	# Remove quazip
+	rm libquazip.so || die
+
+	# Rename the tsclient to its shorter version, required by the teamspeak3 script we install.
+	mv ts3client_linux_* ts3client || die "Couldn't rename ts3client to its shorter version."
+}
+
+src_install() {
+	insinto /opt/teamspeak3-client
+	doins -r *
+
+	fperms +x /opt/teamspeak3-client/ts3client
+
+	dobin "${FILESDIR}/teamspeak3"
+
+	make_desktop_entry teamspeak3 TeamSpeak3 \
+		"/opt/teamspeak3-client/pluginsdk/docs/client_html/images/logo.png" \
+		Network
+}