[gentoo-commits] repo/gentoo:master commit in: xfce-extra/xfce4-power-manager/

["Michał Górny" <mgorny@gentoo.org>]

commit:     4769fcbc72aca2bd01565d66b1b38c0e36429bd1
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Tue Dec 19 06:51:31 2017 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Tue Dec 19 06:52:30 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=4769fcbc

xfce-extra/xfce4-power-manager: Bump to 1.6.1

 xfce-extra/xfce4-power-manager/Manifest            |  1 +
 .../xfce4-power-manager-1.6.1.ebuild               | 62 ++++++++++++++++++++++
 2 files changed, 63 insertions(+)

diff --git a/xfce-extra/xfce4-power-manager/Manifest b/xfce-extra/xfce4-power-manager/Manifest
index 0ca96b687c9..2664e9d864f 100644
--- a/xfce-extra/xfce4-power-manager/Manifest
+++ b/xfce-extra/xfce4-power-manager/Manifest
@@ -1 +1,2 @@
 DIST xfce4-power-manager-1.6.0.tar.bz2 1171114 BLAKE2B 96550ad0381b9482d9e5ad5057c94923c649498593be9726c0628ec7d36e2b2a1a939048b86a46e6bd10a4e9936924d217bcc83bc9f0b76d72ef99245f099b2f SHA512 1b3628793a8bfb7a487fc4f1182769b0d7a90784aa4ef7800997dd7e9a061d938493b8c5653672b293fb018dd5b5209bb83caa16310c1de370413f98d8af1053
+DIST xfce4-power-manager-1.6.1.tar.bz2 1180710 BLAKE2B bffb5f00a42a3242a0b9d35b48fe6d9813d3292757844e911a8e71d05cb59f2f91d93ab5a77ac15ae35c90ccfa60ce39db23bc94a0350232538c8621fec4473f SHA512 b81ce1b35892a6cd0b1d4fb590ccc25b906cde6f782de2fffbe78ea89e00df15e51ea1f47576c173b7512cd617f5142868fca8cf81519b6fe165a5ecc67a5478

diff --git a/xfce-extra/xfce4-power-manager/xfce4-power-manager-1.6.1.ebuild b/xfce-extra/xfce4-power-manager/xfce4-power-manager-1.6.1.ebuild
new file mode 100644
index 00000000000..e4f7280d253
--- /dev/null
+++ b/xfce-extra/xfce4-power-manager/xfce4-power-manager-1.6.1.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit gnome2-utils
+
+DESCRIPTION="Power manager for the Xfce desktop environment"
+HOMEPAGE="https://goodies.xfce.org/projects/applications/xfce4-power-manager"
+SRC_URI="mirror://xfce/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86"
+IUSE="debug kernel_linux networkmanager +panel-plugin policykit systemd"
+
+COMMON_DEPEND=">=dev-libs/glib-2.42:=
+	>=sys-power/upower-0.99.0
+	sys-power/pm-utils
+	>=x11-libs/gtk+-3.14:3=
+	>=x11-libs/libnotify-0.7:=
+	x11-libs/libX11:=
+	>=x11-libs/libXrandr-1.2:=
+	x11-libs/libXext:=
+	x11-libs/libXtst:=
+	>=xfce-base/xfconf-4.12:=
+	>=xfce-base/libxfce4ui-4.12:=[gtk3(+)]
+	>=xfce-base/libxfce4util-4.12:=
+	panel-plugin? ( >=xfce-base/xfce4-panel-4.12:= )
+	policykit? (
+		>=sys-auth/polkit-0.112
+		!systemd? ( sys-auth/consolekit )
+	)"
+RDEPEND="${COMMON_DEPEND}
+	networkmanager? ( net-misc/networkmanager )"
+DEPEND="${COMMON_DEPEND}
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig
+	x11-proto/xproto"
+
+src_configure() {
+	local myconf=(
+		$(use_enable policykit polkit)
+		$(use_enable networkmanager network-manager)
+		$(use_enable panel-plugin xfce4panel)
+	)
+
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+}