[gentoo-commits] repo/gentoo:master commit in: media-gfx/zbar/

[gentoo-commits] repo/gentoo:master commit in: media-gfx/zbar/

[Michael Weber]

commit:     314801d42413fb6991f1ffc144d88964a44f0ac2
Author:     Michael Weber <xmw <AT> gentoo <DOT> org>
AuthorDate: Mon Aug 10 23:16:20 2015 +0000
Commit:     Michael Weber <xmw <AT> gentoo <DOT> org>
CommitDate: Mon Aug 10 23:16:20 2015 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=314801d4

media-gfx/zbar: move sys-devel/gettext from RDEPEND to DEPEND (bug 531546, thanks Nikoli).

Package-Manager: portage-2.2.20

 media-gfx/zbar/zbar-0.10-r5.ebuild        | 4 ++--
 media-gfx/zbar/zbar-0.10_p20121015.ebuild | 4 ++--
 2 files changed, 4 insertions(+), 4 deletions(-)

diff --git a/media-gfx/zbar/zbar-0.10-r5.ebuild b/media-gfx/zbar/zbar-0.10-r5.ebuild
index c9873c2..34c5530 100644
--- a/media-gfx/zbar/zbar-0.10-r5.ebuild
+++ b/media-gfx/zbar/zbar-0.10-r5.ebuild
@@ -17,8 +17,7 @@ SLOT="0"
 KEYWORDS="amd64 ~arm x86"
 IUSE="gtk imagemagick jpeg python qt4 static-libs +threads v4l X xv"
 
-RDEPEND="sys-devel/gettext
-	gtk? ( dev-libs/glib:2 x11-libs/gtk+:2 )
+RDEPEND="gtk? ( dev-libs/glib:2 x11-libs/gtk+:2 )
 	imagemagick? (
 		|| ( media-gfx/imagemagick
 		media-gfx/graphicsmagick[imagemagick] ) )
@@ -29,6 +28,7 @@ RDEPEND="sys-devel/gettext
 	X? ( x11-libs/libXext
 		xv? ( x11-libs/libXv ) )"
 DEPEND="${RDEPEND}
+	sys-devel/gettext
 	virtual/pkgconfig"
 
 REQUIRED_USE="${PYTHON_REQUIRED_USE}"

diff --git a/media-gfx/zbar/zbar-0.10_p20121015.ebuild b/media-gfx/zbar/zbar-0.10_p20121015.ebuild
index c6f6de1..e501a96 100644
--- a/media-gfx/zbar/zbar-0.10_p20121015.ebuild
+++ b/media-gfx/zbar/zbar-0.10_p20121015.ebuild
@@ -17,8 +17,7 @@ SLOT="0"
 KEYWORDS="~amd64 ~arm ~x86"
 IUSE="gtk imagemagick jpeg python qt4 static-libs +threads v4l X xv"
 
-RDEPEND="sys-devel/gettext
-	gtk? ( dev-libs/glib:2 x11-libs/gtk+:2 )
+RDEPEND="gtk? ( dev-libs/glib:2 x11-libs/gtk+:2 )
 	imagemagick? (
 		|| ( media-gfx/imagemagick
 		media-gfx/graphicsmagick[imagemagick] ) )
@@ -29,6 +28,7 @@ RDEPEND="sys-devel/gettext
 	X? ( x11-libs/libXext
 		xv? ( x11-libs/libXv ) )"
 DEPEND="${RDEPEND}
+	sys-devel/gettext
 	virtual/pkgconfig"
 
 REQUIRED_USE="${PYTHON_REQUIRED_USE}"

[gentoo-commits] repo/gentoo:master commit in: media-gfx/zbar/

[Andrew Savchenko]

commit:     6a2f51bbe5ad97c868f2811743dfba5d6a4fabca
Author:     Andrew Savchenko <bircoph <AT> gentoo <DOT> org>
AuthorDate: Wed Sep  7 06:35:39 2016 +0000
Commit:     Andrew Savchenko <bircoph <AT> gentoo <DOT> org>
CommitDate: Wed Sep  7 06:35:39 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=6a2f51bb

media-gfx/zbar: fix bug 589834

Add USE="java" support to fix automagic dependency.

Package-Manager: portage-2.3.0
Signed-off-by: Andrew Savchenko <bircoph <AT> gentoo.org>

 media-gfx/zbar/zbar-0.10_p20121015.ebuild | 27 ++++++++++++++++++++++-----
 1 file changed, 22 insertions(+), 5 deletions(-)

diff --git a/media-gfx/zbar/zbar-0.10_p20121015.ebuild b/media-gfx/zbar/zbar-0.10_p20121015.ebuild
index 5799d94..8a10c4b 100644
--- a/media-gfx/zbar/zbar-0.10_p20121015.ebuild
+++ b/media-gfx/zbar/zbar-0.10_p20121015.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2015 Gentoo Foundation
+# Copyright 1999-2016 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 # $Id$
 
@@ -6,7 +6,7 @@ EAPI=5
 
 PYTHON_COMPAT=( python2_7 )
 
-inherit autotools eutils flag-o-matic python-single-r1
+inherit autotools eutils flag-o-matic java-pkg-opt-2 multilib python-single-r1
 
 DESCRIPTION="Library and tools for reading barcodes from images or video"
 HOMEPAGE="http://zbar.sourceforge.net/"
@@ -15,9 +15,9 @@ SRC_URI="https://dev.gentoo.org/~xmw/zbar-0.10_p20121015.zip"
 LICENSE="LGPL-2.1"
 SLOT="0"
 KEYWORDS="~amd64 ~arm ~x86"
-IUSE="gtk imagemagick jpeg python qt4 static-libs +threads v4l X xv"
+IUSE="gtk imagemagick java jpeg python qt4 static-libs +threads v4l X xv"
 
-RDEPEND="gtk? ( dev-libs/glib:2 x11-libs/gtk+:2 )
+CDEPEND="gtk? ( dev-libs/glib:2 x11-libs/gtk+:2 )
 	imagemagick? (
 		|| ( media-gfx/imagemagick
 		media-gfx/graphicsmagick[imagemagick] ) )
@@ -27,7 +27,10 @@ RDEPEND="gtk? ( dev-libs/glib:2 x11-libs/gtk+:2 )
 	qt4? ( dev-qt/qtcore:4 dev-qt/qtgui:4 )
 	X? ( x11-libs/libXext
 		xv? ( x11-libs/libXv ) )"
-DEPEND="${RDEPEND}
+REPEND="${CDEPEND}
+	java? ( >=virtual/jre-1.4 ) "
+DEPEND="${CDEPEND}
+	java? ( >=virtual/jdk-1.4 )
 	sys-devel/gettext
 	virtual/pkgconfig"
 
@@ -35,6 +38,7 @@ REQUIRED_USE="${PYTHON_REQUIRED_USE}"
 
 pkg_setup() {
 	use python && python-single-r1_pkg_setup
+	java-pkg-opt-2_pkg_setup
 }
 
 src_unpack() {
@@ -49,16 +53,25 @@ src_prepare() {
 		"${FILESDIR}"/${PN}-0.10-v4l2-uvcvideo.patch
 
 	use python && python_fix_shebang examples/upcrpc.py test/*.py
+	java-pkg-opt-2_src_prepare
 
 	sed -e '/AM_INIT_AUTOMAKE/s: -Werror : :' \
 		-e '/^AM_CFLAGS=/s: -Werror::' \
 		-i configure.ac || die
+	sed "s|javadir = \$(pkgdatadir)|javadir = /usr/$(get_libdir)/zbar|" \
+		-i java/Makefile.am
 	eautoreconf
 }
 
 src_configure() {
+	if use java; then
+		export JAVACFLAGS="$(java-pkg_javac-args)"
+		export JAVA_CFLAGS="$(java-pkg_get-jni-cflags)"
+	fi
+
 	append-cppflags -DNDEBUG
 	econf \
+		$(use_with java) \
 		$(use_with jpeg) \
 		$(use_with gtk) \
 		$(use_with imagemagick) \
@@ -77,3 +90,7 @@ src_install() {
 	rm -r "${ED}"/usr/share/doc/${PN}
 	prune_libtool_files --all
 }
+
+pkg_preinst() {
+	java-pkg-opt-2_pkg_preinst
+}

[gentoo-commits] repo/gentoo:master commit in: media-gfx/zbar/

[Michał Górny]

commit:     d87458a9863130f047b27e593fd7e611dcf05303
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sun Aug 27 15:21:13 2017 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Thu Sep  7 20:31:35 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d87458a9

media-gfx/zbar: Use virtualx to fix running tests

 media-gfx/zbar/zbar-0.10_p20121015-r2.ebuild | 6 +++++-
 1 file changed, 5 insertions(+), 1 deletion(-)

diff --git a/media-gfx/zbar/zbar-0.10_p20121015-r2.ebuild b/media-gfx/zbar/zbar-0.10_p20121015-r2.ebuild
index 48f2b35f178..f5177673bfb 100644
--- a/media-gfx/zbar/zbar-0.10_p20121015-r2.ebuild
+++ b/media-gfx/zbar/zbar-0.10_p20121015-r2.ebuild
@@ -5,7 +5,7 @@ EAPI=6
 
 PYTHON_COMPAT=( python2_7 )
 
-inherit autotools flag-o-matic java-pkg-opt-2 python-single-r1
+inherit autotools flag-o-matic java-pkg-opt-2 python-single-r1 virtualx
 
 DESCRIPTION="Library and tools for reading barcodes from images or video"
 HOMEPAGE="http://zbar.sourceforge.net/"
@@ -93,6 +93,10 @@ src_configure() {
 		$(use_enable v4l video)
 }
 
+src_test() {
+	virtx default
+}
+
 src_install() {
 	emake DESTDIR="${D}" install
 	dodoc HACKING NEWS README TODO

[gentoo-commits] repo/gentoo:master commit in: media-gfx/zbar/

[Michał Górny]

commit:     2afbd628378643f8aeaa5779fa35533f4cf6d425
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sun Aug 27 15:16:28 2017 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Thu Sep  7 20:31:35 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=2afbd628

media-gfx/zbar: Tests need Python too

 media-gfx/zbar/zbar-0.10_p20121015-r2.ebuild | 10 +++++++---
 1 file changed, 7 insertions(+), 3 deletions(-)

diff --git a/media-gfx/zbar/zbar-0.10_p20121015-r2.ebuild b/media-gfx/zbar/zbar-0.10_p20121015-r2.ebuild
index a6c0fc5a179..48f2b35f178 100644
--- a/media-gfx/zbar/zbar-0.10_p20121015-r2.ebuild
+++ b/media-gfx/zbar/zbar-0.10_p20121015-r2.ebuild
@@ -14,8 +14,9 @@ SRC_URI="https://dev.gentoo.org/~xmw/zbar-0.10_p20121015.zip"
 LICENSE="LGPL-2.1"
 SLOT="0"
 KEYWORDS="~amd64 ~arm ~x86"
-IUSE="gtk imagemagick java jpeg python qt4 static-libs +threads v4l X xv"
-REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+IUSE="gtk imagemagick java jpeg python qt4 static-libs test +threads v4l X xv"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )
+	test? ( ${PYTHON_REQUIRED_USE} )"
 
 CDEPEND="gtk? ( dev-libs/glib:2 x11-libs/gtk+:2 )
 	imagemagick? ( virtual/imagemagick-tools )
@@ -33,12 +34,15 @@ RDEPEND="${CDEPEND}
 	java? ( >=virtual/jre-1.4 )"
 DEPEND="${CDEPEND}
 	java? ( >=virtual/jdk-1.4 )
+	test? ( ${PYTHON_DEPS} )
 	app-arch/unzip
 	sys-devel/gettext
 	virtual/pkgconfig"
 
 pkg_setup() {
-	use python && python-single-r1_pkg_setup
+	if use python || use test; then
+		python-single-r1_pkg_setup
+	fi
 	java-pkg-opt-2_pkg_setup
 }
 

[gentoo-commits] repo/gentoo:master commit in: media-gfx/zbar/

[Michał Górny]

commit:     a8f6e8e8579c2078fbbfa6e1d566f4d698b6bc93
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sun Aug 27 15:06:00 2017 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Thu Sep  7 20:31:33 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=a8f6e8e8

media-gfx/zbar: Add missing unzip dep

 media-gfx/zbar/zbar-0.10_p20121015-r2.ebuild | 1 +
 1 file changed, 1 insertion(+)

diff --git a/media-gfx/zbar/zbar-0.10_p20121015-r2.ebuild b/media-gfx/zbar/zbar-0.10_p20121015-r2.ebuild
index af638ab9c78..a6c0fc5a179 100644
--- a/media-gfx/zbar/zbar-0.10_p20121015-r2.ebuild
+++ b/media-gfx/zbar/zbar-0.10_p20121015-r2.ebuild
@@ -33,6 +33,7 @@ RDEPEND="${CDEPEND}
 	java? ( >=virtual/jre-1.4 )"
 DEPEND="${CDEPEND}
 	java? ( >=virtual/jdk-1.4 )
+	app-arch/unzip
 	sys-devel/gettext
 	virtual/pkgconfig"
 

[gentoo-commits] repo/gentoo:master commit in: media-gfx/zbar/

[Michał Górny]

commit:     9269e6bb7e59f6686507d78c7662acce54eefc80
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sun Aug 27 15:02:51 2017 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Thu Sep  7 20:31:32 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9269e6bb

media-gfx/zbar: Bump to EAPI=6

 media-gfx/zbar/zbar-0.10_p20121015-r2.ebuild | 99 ++++++++++++++++++++++++++++
 1 file changed, 99 insertions(+)

diff --git a/media-gfx/zbar/zbar-0.10_p20121015-r2.ebuild b/media-gfx/zbar/zbar-0.10_p20121015-r2.ebuild
new file mode 100644
index 00000000000..af638ab9c78
--- /dev/null
+++ b/media-gfx/zbar/zbar-0.10_p20121015-r2.ebuild
@@ -0,0 +1,99 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 )
+
+inherit autotools flag-o-matic java-pkg-opt-2 python-single-r1
+
+DESCRIPTION="Library and tools for reading barcodes from images or video"
+HOMEPAGE="http://zbar.sourceforge.net/"
+SRC_URI="https://dev.gentoo.org/~xmw/zbar-0.10_p20121015.zip"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="gtk imagemagick java jpeg python qt4 static-libs +threads v4l X xv"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+CDEPEND="gtk? ( dev-libs/glib:2 x11-libs/gtk+:2 )
+	imagemagick? ( virtual/imagemagick-tools )
+	jpeg? ( virtual/jpeg:0 )
+	python? (
+		${PYTHON_DEPS}
+		gtk? ( >=dev-python/pygtk-2[${PYTHON_USEDEP}] )
+	)
+	qt4? ( dev-qt/qtcore:4 dev-qt/qtgui:4 )
+	X? (
+		x11-libs/libXext
+		xv? ( x11-libs/libXv )
+	)"
+RDEPEND="${CDEPEND}
+	java? ( >=virtual/jre-1.4 )"
+DEPEND="${CDEPEND}
+	java? ( >=virtual/jdk-1.4 )
+	sys-devel/gettext
+	virtual/pkgconfig"
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+	java-pkg-opt-2_pkg_setup
+}
+
+src_unpack() {
+	#vcs-snapshot doesn't work on .zip
+	default
+	mv * ${P} || die
+}
+
+src_prepare() {
+	eapply "${FILESDIR}"/${PN}-0.10-errors.patch \
+		"${FILESDIR}"/${PN}-0.10-python-crash.patch \
+		"${FILESDIR}"/${PN}-0.10-v4l2-uvcvideo.patch
+
+	if has_version '>=media-gfx/imagemagick-7.0.1.0' ; then
+		eapply "${FILESDIR}/${P}-ImageMagick-7.diff"
+	fi
+
+	use python && python_fix_shebang examples/upcrpc.py test/*.py
+	java-pkg-opt-2_src_prepare
+
+	sed -e '/AM_INIT_AUTOMAKE/s: -Werror : :' \
+		-e '/^AM_CFLAGS=/s: -Werror::' \
+		-i configure.ac || die
+	sed "s|javadir = \$(pkgdatadir)|javadir = /usr/$(get_libdir)/zbar|" \
+		-i java/Makefile.am
+	eautoreconf
+}
+
+src_configure() {
+	if use java; then
+		export JAVACFLAGS="$(java-pkg_javac-args)"
+		export JAVA_CFLAGS="$(java-pkg_get-jni-cflags)"
+	fi
+
+	append-cppflags -DNDEBUG
+	econf \
+		$(use_with java) \
+		$(use_with jpeg) \
+		$(use_with gtk) \
+		$(use_with imagemagick) \
+		$(use_with python) \
+		$(use_with qt4 qt) \
+		$(use_enable static-libs static) \
+		$(use_enable threads pthread) \
+		$(use_with X x) \
+		$(use_with xv xv) \
+		$(use_enable v4l video)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	dodoc HACKING NEWS README TODO
+	find "${D}" -name '*.la' -delete || die
+}
+
+pkg_preinst() {
+	java-pkg-opt-2_pkg_preinst
+}

[gentoo-commits] repo/gentoo:master commit in: media-gfx/zbar/

[Michał Górny]

commit:     e5a0d32d7743b1e6752698cb1ba71eb767b5b48b
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sun Aug 27 15:27:29 2017 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Thu Sep  7 20:31:36 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e5a0d32d

media-gfx/zbar: Tests require USE=X enabled

 media-gfx/zbar/zbar-0.10_p20121015-r2.ebuild | 2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)

diff --git a/media-gfx/zbar/zbar-0.10_p20121015-r2.ebuild b/media-gfx/zbar/zbar-0.10_p20121015-r2.ebuild
index f5177673bfb..e7e5d80d924 100644
--- a/media-gfx/zbar/zbar-0.10_p20121015-r2.ebuild
+++ b/media-gfx/zbar/zbar-0.10_p20121015-r2.ebuild
@@ -16,7 +16,7 @@ SLOT="0"
 KEYWORDS="~amd64 ~arm ~x86"
 IUSE="gtk imagemagick java jpeg python qt4 static-libs test +threads v4l X xv"
 REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )
-	test? ( ${PYTHON_REQUIRED_USE} )"
+	test? ( X ${PYTHON_REQUIRED_USE} )"
 
 CDEPEND="gtk? ( dev-libs/glib:2 x11-libs/gtk+:2 )
 	imagemagick? ( virtual/imagemagick-tools )

[gentoo-commits] repo/gentoo:master commit in: media-gfx/zbar/

[Michał Górny]

commit:     75539e8e845df3d64c0ef32c01cc1d31ab84850a
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sun Aug 27 17:14:26 2017 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Thu Sep  7 20:31:36 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=75539e8e

media-gfx/zbar: Enable multilib support

Bug: https://bugs.gentoo.org/628306
Closes: https://github.com/gentoo/gentoo/pull/5543

 media-gfx/zbar/zbar-0.10_p20121015-r2.ebuild | 34 ++++++++++++++++------------
 1 file changed, 20 insertions(+), 14 deletions(-)

diff --git a/media-gfx/zbar/zbar-0.10_p20121015-r2.ebuild b/media-gfx/zbar/zbar-0.10_p20121015-r2.ebuild
index e7e5d80d924..3a552305df6 100644
--- a/media-gfx/zbar/zbar-0.10_p20121015-r2.ebuild
+++ b/media-gfx/zbar/zbar-0.10_p20121015-r2.ebuild
@@ -5,7 +5,8 @@ EAPI=6
 
 PYTHON_COMPAT=( python2_7 )
 
-inherit autotools flag-o-matic java-pkg-opt-2 python-single-r1 virtualx
+inherit autotools flag-o-matic java-pkg-opt-2 multilib-minimal \
+	python-single-r1 virtualx
 
 DESCRIPTION="Library and tools for reading barcodes from images or video"
 HOMEPAGE="http://zbar.sourceforge.net/"
@@ -18,17 +19,19 @@ IUSE="gtk imagemagick java jpeg python qt4 static-libs test +threads v4l X xv"
 REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )
 	test? ( X ${PYTHON_REQUIRED_USE} )"
 
-CDEPEND="gtk? ( dev-libs/glib:2 x11-libs/gtk+:2 )
+CDEPEND="gtk? ( dev-libs/glib:2[${MULTILIB_USEDEP}]
+		x11-libs/gtk+:2[${MULTILIB_USEDEP}] )
 	imagemagick? ( virtual/imagemagick-tools )
-	jpeg? ( virtual/jpeg:0 )
+	jpeg? ( virtual/jpeg:0[${MULTILIB_USEDEP}] )
 	python? (
 		${PYTHON_DEPS}
 		gtk? ( >=dev-python/pygtk-2[${PYTHON_USEDEP}] )
 	)
-	qt4? ( dev-qt/qtcore:4 dev-qt/qtgui:4 )
+	qt4? ( dev-qt/qtcore:4[${MULTILIB_USEDEP}]
+		dev-qt/qtgui:4[${MULTILIB_USEDEP}] )
 	X? (
-		x11-libs/libXext
-		xv? ( x11-libs/libXv )
+		x11-libs/libXext[${MULTILIB_USEDEP}]
+		xv? ( x11-libs/libXv[${MULTILIB_USEDEP}] )
 	)"
 RDEPEND="${CDEPEND}
 	java? ( >=virtual/jre-1.4 )"
@@ -72,33 +75,36 @@ src_prepare() {
 	eautoreconf
 }
 
-src_configure() {
-	if use java; then
+multilib_src_configure() {
+	if multilib_is_native_abi && use java; then
 		export JAVACFLAGS="$(java-pkg_javac-args)"
 		export JAVA_CFLAGS="$(java-pkg_get-jni-cflags)"
 	fi
 
 	append-cppflags -DNDEBUG
+	ECONF_SOURCE=${S} \
 	econf \
-		$(use_with java) \
+		$(multilib_native_use_with java) \
 		$(use_with jpeg) \
 		$(use_with gtk) \
-		$(use_with imagemagick) \
-		$(use_with python) \
+		$(multilib_native_use_with imagemagick) \
+		$(multilib_native_use_with python) \
 		$(use_with qt4 qt) \
 		$(use_enable static-libs static) \
 		$(use_enable threads pthread) \
 		$(use_with X x) \
 		$(use_with xv xv) \
 		$(use_enable v4l video)
+
+	# work-around out-of-source build issue
+	mkdir gtk pygtk qt test || die
 }
 
 src_test() {
-	virtx default
+	virtx multilib-minimal_src_test
 }
 
-src_install() {
-	emake DESTDIR="${D}" install
+multilib_src_install_all() {
 	dodoc HACKING NEWS README TODO
 	find "${D}" -name '*.la' -delete || die
 }

[gentoo-commits] repo/gentoo:master commit in: media-gfx/zbar/

[Michael Weber]

commit:     1c15f97c3cfb23fccd1f63ddd8016ae95d9f4193
Author:     Michael Weber <xmw <AT> gentoo <DOT> org>
AuthorDate: Mon Dec 18 09:19:28 2017 +0000
Commit:     Michael Weber <xmw <AT> gentoo <DOT> org>
CommitDate: Mon Dec 18 09:19:28 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1c15f97c

media-gfx/zbar: Switch deprecated qt4 function (thanks Sam Jorna).

Closes: https://bugs.gentoo.org/572488
Package-Manager: Portage-2.3.19, Repoman-2.3.6

 media-gfx/zbar/zbar-0.10_p20121015-r2.ebuild | 4 ++++
 1 file changed, 4 insertions(+)

diff --git a/media-gfx/zbar/zbar-0.10_p20121015-r2.ebuild b/media-gfx/zbar/zbar-0.10_p20121015-r2.ebuild
index 3a552305df6..6aa664bfb14 100644
--- a/media-gfx/zbar/zbar-0.10_p20121015-r2.ebuild
+++ b/media-gfx/zbar/zbar-0.10_p20121015-r2.ebuild
@@ -60,6 +60,10 @@ src_prepare() {
 		"${FILESDIR}"/${PN}-0.10-python-crash.patch \
 		"${FILESDIR}"/${PN}-0.10-v4l2-uvcvideo.patch
 
+	# fix use of deprecated qt4 function, bug 572488
+	sed -e 's:numBytes:byteCount:g' \
+		-i "${S}"/include/zbar/QZBarImage.h || die
+
 	if has_version '>=media-gfx/imagemagick-7.0.1.0' ; then
 		eapply "${FILESDIR}/${P}-ImageMagick-7.diff"
 	fi

[gentoo-commits] repo/gentoo:master commit in: media-gfx/zbar/

[Michael Weber]

commit:     941ba5d5bd2504193c493f18c013a47e72a09237
Author:     Michael Weber <xmw <AT> gentoo <DOT> org>
AuthorDate: Mon Dec 18 09:52:04 2017 +0000
Commit:     Michael Weber <xmw <AT> gentoo <DOT> org>
CommitDate: Mon Dec 18 09:52:14 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=941ba5d5

media-gfx/zbar: USE=imagemagick requires different configure switches, thanks ta2002.

Closes: https://bugs.gentoo.org/552350
Package-Manager: Portage-2.3.19, Repoman-2.3.6

 media-gfx/zbar/zbar-0.10_p20121015-r2.ebuild | 11 ++++++++++-
 1 file changed, 10 insertions(+), 1 deletion(-)

diff --git a/media-gfx/zbar/zbar-0.10_p20121015-r2.ebuild b/media-gfx/zbar/zbar-0.10_p20121015-r2.ebuild
index 6aa664bfb14..b31650273b5 100644
--- a/media-gfx/zbar/zbar-0.10_p20121015-r2.ebuild
+++ b/media-gfx/zbar/zbar-0.10_p20121015-r2.ebuild
@@ -86,12 +86,21 @@ multilib_src_configure() {
 	fi
 
 	append-cppflags -DNDEBUG
+
+	# different flags for image/graphics magick (bug 552350)
+	myimagemagick="--without-imagemagick"
+	has_version media-gfx/imagemagick &&
+		myimagemagick="$(multilib_native_use_with imagemagick)"
+	mygraphicsmagick="--without-graphicsmagick"
+	has_version media-gfx/graphicsmagick &&
+		mygraphicsmagick="$(multilib_native_use_with imagemagick graphicsmagick)"
 	ECONF_SOURCE=${S} \
 	econf \
 		$(multilib_native_use_with java) \
 		$(use_with jpeg) \
 		$(use_with gtk) \
-		$(multilib_native_use_with imagemagick) \
+		${myimagemagick} \
+		${mygraphicsmagick} \
 		$(multilib_native_use_with python) \
 		$(use_with qt4 qt) \
 		$(use_enable static-libs static) \

[gentoo-commits] repo/gentoo:master commit in: media-gfx/zbar/

[Michael Weber]

commit:     ceed09475c17126515be605f700f9bb3c540bd1f
Author:     Michael Weber <xmw <AT> gentoo <DOT> org>
AuthorDate: Mon Dec 18 10:37:16 2017 +0000
Commit:     Michael Weber <xmw <AT> gentoo <DOT> org>
CommitDate: Mon Dec 18 10:37:28 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ceed0947

media-gfx/zbar: Fix USE=java tests.

Closes: https://bugs.gentoo.org/629078
Package-Manager: Portage-2.3.19, Repoman-2.3.6

 media-gfx/zbar/zbar-0.10_p20121015-r2.ebuild | 9 ++++++++-
 1 file changed, 8 insertions(+), 1 deletion(-)

diff --git a/media-gfx/zbar/zbar-0.10_p20121015-r2.ebuild b/media-gfx/zbar/zbar-0.10_p20121015-r2.ebuild
index b31650273b5..186a80e32cc 100644
--- a/media-gfx/zbar/zbar-0.10_p20121015-r2.ebuild
+++ b/media-gfx/zbar/zbar-0.10_p20121015-r2.ebuild
@@ -36,7 +36,9 @@ CDEPEND="gtk? ( dev-libs/glib:2[${MULTILIB_USEDEP}]
 RDEPEND="${CDEPEND}
 	java? ( >=virtual/jre-1.4 )"
 DEPEND="${CDEPEND}
-	java? ( >=virtual/jdk-1.4 )
+	java? ( >=virtual/jdk-1.4
+		test? ( dev-java/junit:4
+			dev-java/hamcrest-core:1.3 ) )
 	test? ( ${PYTHON_DEPS} )
 	app-arch/unzip
 	sys-devel/gettext
@@ -83,6 +85,11 @@ multilib_src_configure() {
 	if multilib_is_native_abi && use java; then
 		export JAVACFLAGS="$(java-pkg_javac-args)"
 		export JAVA_CFLAGS="$(java-pkg_get-jni-cflags)"
+		if use test ; then # bug 629078
+			java-pkg_append_ CLASSPATH .
+			java-pkg_append_ CLASSPATH $(java-pkg_getjar --build-only junit-4 junit.jar)
+			java-pkg_append_ CLASSPATH $(java-pkg_getjar --build-only hamcrest-core-1.3 hamcrest-core.jar)
+		fi
 	fi
 
 	append-cppflags -DNDEBUG

[gentoo-commits] repo/gentoo:master commit in: media-gfx/zbar/

[Jason Zaman]

commit:     f63d299ed201dd0f82f043425a92026e32ec8705
Author:     Jason Zaman <perfinion <AT> gentoo <DOT> org>
AuthorDate: Tue Dec 19 10:34:06 2017 +0000
Commit:     Jason Zaman <perfinion <AT> gentoo <DOT> org>
CommitDate: Tue Dec 19 10:38:39 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f63d299e

media-gfx/zbar: amd64 stable

Gentoo-bug: 641190
Package-Manager: Portage-2.3.13, Repoman-2.3.3

 media-gfx/zbar/zbar-0.10_p20121015-r2.ebuild | 2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)

diff --git a/media-gfx/zbar/zbar-0.10_p20121015-r2.ebuild b/media-gfx/zbar/zbar-0.10_p20121015-r2.ebuild
index 186a80e32cc..3e5f42adf8a 100644
--- a/media-gfx/zbar/zbar-0.10_p20121015-r2.ebuild
+++ b/media-gfx/zbar/zbar-0.10_p20121015-r2.ebuild
@@ -14,7 +14,7 @@ SRC_URI="https://dev.gentoo.org/~xmw/zbar-0.10_p20121015.zip"
 
 LICENSE="LGPL-2.1"
 SLOT="0"
-KEYWORDS="~amd64 ~arm ~x86"
+KEYWORDS="amd64 ~arm ~x86"
 IUSE="gtk imagemagick java jpeg python qt4 static-libs test +threads v4l X xv"
 REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )
 	test? ( X ${PYTHON_REQUIRED_USE} )"

[gentoo-commits] repo/gentoo:master commit in: media-gfx/zbar/

[Thomas Deutschmann]

commit:     59fe46ef604a3d7e2eff53531978322477d276a1
Author:     Thomas Deutschmann <whissi <AT> gentoo <DOT> org>
AuthorDate: Tue Feb  6 16:20:59 2018 +0000
Commit:     Thomas Deutschmann <whissi <AT> gentoo <DOT> org>
CommitDate: Tue Feb  6 16:24:12 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=59fe46ef

media-gfx/zbar: x86 stable (bug #641190)

Package-Manager: Portage-2.3.24, Repoman-2.3.6

 media-gfx/zbar/zbar-0.10_p20121015-r2.ebuild | 4 ++--
 1 file changed, 2 insertions(+), 2 deletions(-)

diff --git a/media-gfx/zbar/zbar-0.10_p20121015-r2.ebuild b/media-gfx/zbar/zbar-0.10_p20121015-r2.ebuild
index 3e5f42adf8a..6c764241f4d 100644
--- a/media-gfx/zbar/zbar-0.10_p20121015-r2.ebuild
+++ b/media-gfx/zbar/zbar-0.10_p20121015-r2.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2017 Gentoo Foundation
+# Copyright 1999-2018 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=6
@@ -14,7 +14,7 @@ SRC_URI="https://dev.gentoo.org/~xmw/zbar-0.10_p20121015.zip"
 
 LICENSE="LGPL-2.1"
 SLOT="0"
-KEYWORDS="amd64 ~arm ~x86"
+KEYWORDS="amd64 ~arm x86"
 IUSE="gtk imagemagick java jpeg python qt4 static-libs test +threads v4l X xv"
 REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )
 	test? ( X ${PYTHON_REQUIRED_USE} )"

[gentoo-commits] repo/gentoo:master commit in: media-gfx/zbar/

[Andreas Sturmlechner]

commit:     a58e50c4bddb838a269abf71deeff789e17c2fd4
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Thu May 10 10:07:19 2018 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Thu May 10 10:08:18 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=a58e50c4

media-gfx/zbar: Drop USE=qt4

Closes: https://bugs.gentoo.org/641920
Package-Manager: Portage-2.3.36, Repoman-2.3.9

 media-gfx/zbar/zbar-0.10_p20121015-r3.ebuild | 132 +++++++++++++++++++++++++++
 1 file changed, 132 insertions(+)

diff --git a/media-gfx/zbar/zbar-0.10_p20121015-r3.ebuild b/media-gfx/zbar/zbar-0.10_p20121015-r3.ebuild
new file mode 100644
index 00000000000..ecdd0ad2dbf
--- /dev/null
+++ b/media-gfx/zbar/zbar-0.10_p20121015-r3.ebuild
@@ -0,0 +1,132 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 )
+
+inherit autotools flag-o-matic java-pkg-opt-2 multilib-minimal \
+	python-single-r1 virtualx
+
+DESCRIPTION="Library and tools for reading barcodes from images or video"
+HOMEPAGE="http://zbar.sourceforge.net/"
+SRC_URI="https://dev.gentoo.org/~xmw/zbar-0.10_p20121015.zip"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="amd64 ~arm x86"
+IUSE="gtk imagemagick java jpeg python static-libs test +threads v4l X xv"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )
+	test? ( X ${PYTHON_REQUIRED_USE} )"
+
+CDEPEND="gtk? ( dev-libs/glib:2[${MULTILIB_USEDEP}]
+		x11-libs/gtk+:2[${MULTILIB_USEDEP}] )
+	imagemagick? ( virtual/imagemagick-tools )
+	jpeg? ( virtual/jpeg:0[${MULTILIB_USEDEP}] )
+	python? (
+		${PYTHON_DEPS}
+		gtk? ( >=dev-python/pygtk-2[${PYTHON_USEDEP}] )
+	)
+	X? (
+		x11-libs/libXext[${MULTILIB_USEDEP}]
+		xv? ( x11-libs/libXv[${MULTILIB_USEDEP}] )
+	)"
+RDEPEND="${CDEPEND}
+	java? ( >=virtual/jre-1.4 )"
+DEPEND="${CDEPEND}
+	java? ( >=virtual/jdk-1.4
+		test? ( dev-java/junit:4
+			dev-java/hamcrest-core:1.3 ) )
+	test? ( ${PYTHON_DEPS} )
+	app-arch/unzip
+	sys-devel/gettext
+	virtual/pkgconfig"
+
+pkg_setup() {
+	if use python || use test; then
+		python-single-r1_pkg_setup
+	fi
+	java-pkg-opt-2_pkg_setup
+}
+
+src_unpack() {
+	#vcs-snapshot doesn't work on .zip
+	default
+	mv * ${P} || die
+}
+
+src_prepare() {
+	eapply "${FILESDIR}"/${PN}-0.10-errors.patch \
+		"${FILESDIR}"/${PN}-0.10-python-crash.patch \
+		"${FILESDIR}"/${PN}-0.10-v4l2-uvcvideo.patch
+
+	# fix use of deprecated qt4 function, bug 572488
+	sed -e 's:numBytes:byteCount:g' \
+		-i "${S}"/include/zbar/QZBarImage.h || die
+
+	if has_version '>=media-gfx/imagemagick-7.0.1.0' ; then
+		eapply "${FILESDIR}/${P}-ImageMagick-7.diff"
+	fi
+
+	use python && python_fix_shebang examples/upcrpc.py test/*.py
+	java-pkg-opt-2_src_prepare
+
+	sed -e '/AM_INIT_AUTOMAKE/s: -Werror : :' \
+		-e '/^AM_CFLAGS=/s: -Werror::' \
+		-i configure.ac || die
+	sed "s|javadir = \$(pkgdatadir)|javadir = /usr/$(get_libdir)/zbar|" \
+		-i java/Makefile.am
+	eautoreconf
+}
+
+multilib_src_configure() {
+	if multilib_is_native_abi && use java; then
+		export JAVACFLAGS="$(java-pkg_javac-args)"
+		export JAVA_CFLAGS="$(java-pkg_get-jni-cflags)"
+		if use test ; then # bug 629078
+			java-pkg_append_ CLASSPATH .
+			java-pkg_append_ CLASSPATH $(java-pkg_getjar --build-only junit-4 junit.jar)
+			java-pkg_append_ CLASSPATH $(java-pkg_getjar --build-only hamcrest-core-1.3 hamcrest-core.jar)
+		fi
+	fi
+
+	append-cppflags -DNDEBUG
+
+	# different flags for image/graphics magick (bug 552350)
+	myimagemagick="--without-imagemagick"
+	has_version media-gfx/imagemagick &&
+		myimagemagick="$(multilib_native_use_with imagemagick)"
+	mygraphicsmagick="--without-graphicsmagick"
+	has_version media-gfx/graphicsmagick &&
+		mygraphicsmagick="$(multilib_native_use_with imagemagick graphicsmagick)"
+	ECONF_SOURCE=${S} \
+	econf \
+		$(multilib_native_use_with java) \
+		$(use_with jpeg) \
+		$(use_with gtk) \
+		${myimagemagick} \
+		${mygraphicsmagick} \
+		$(multilib_native_use_with python) \
+		--without-qt \
+		$(use_enable static-libs static) \
+		$(use_enable threads pthread) \
+		$(use_with X x) \
+		$(use_with xv xv) \
+		$(use_enable v4l video)
+
+	# work-around out-of-source build issue
+	mkdir gtk pygtk qt test || die
+}
+
+src_test() {
+	virtx multilib-minimal_src_test
+}
+
+multilib_src_install_all() {
+	dodoc HACKING NEWS README TODO
+	find "${D}" -name '*.la' -delete || die
+}
+
+pkg_preinst() {
+	java-pkg-opt-2_pkg_preinst
+}

[gentoo-commits] repo/gentoo:master commit in: media-gfx/zbar/

[Andreas Sturmlechner]

commit:     2cc5bd6c0709933e3c1f619910e169a73943fec6
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Thu May 10 10:07:36 2018 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Thu May 10 10:08:18 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=2cc5bd6c

media-gfx/zbar: Drop old

Package-Manager: Portage-2.3.36, Repoman-2.3.9

 media-gfx/zbar/zbar-0.10_p20121015-r2.ebuild | 134 ---------------------------
 1 file changed, 134 deletions(-)

diff --git a/media-gfx/zbar/zbar-0.10_p20121015-r2.ebuild b/media-gfx/zbar/zbar-0.10_p20121015-r2.ebuild
deleted file mode 100644
index 6c764241f4d..00000000000
--- a/media-gfx/zbar/zbar-0.10_p20121015-r2.ebuild
+++ /dev/null
@@ -1,134 +0,0 @@
-# Copyright 1999-2018 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-
-PYTHON_COMPAT=( python2_7 )
-
-inherit autotools flag-o-matic java-pkg-opt-2 multilib-minimal \
-	python-single-r1 virtualx
-
-DESCRIPTION="Library and tools for reading barcodes from images or video"
-HOMEPAGE="http://zbar.sourceforge.net/"
-SRC_URI="https://dev.gentoo.org/~xmw/zbar-0.10_p20121015.zip"
-
-LICENSE="LGPL-2.1"
-SLOT="0"
-KEYWORDS="amd64 ~arm x86"
-IUSE="gtk imagemagick java jpeg python qt4 static-libs test +threads v4l X xv"
-REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )
-	test? ( X ${PYTHON_REQUIRED_USE} )"
-
-CDEPEND="gtk? ( dev-libs/glib:2[${MULTILIB_USEDEP}]
-		x11-libs/gtk+:2[${MULTILIB_USEDEP}] )
-	imagemagick? ( virtual/imagemagick-tools )
-	jpeg? ( virtual/jpeg:0[${MULTILIB_USEDEP}] )
-	python? (
-		${PYTHON_DEPS}
-		gtk? ( >=dev-python/pygtk-2[${PYTHON_USEDEP}] )
-	)
-	qt4? ( dev-qt/qtcore:4[${MULTILIB_USEDEP}]
-		dev-qt/qtgui:4[${MULTILIB_USEDEP}] )
-	X? (
-		x11-libs/libXext[${MULTILIB_USEDEP}]
-		xv? ( x11-libs/libXv[${MULTILIB_USEDEP}] )
-	)"
-RDEPEND="${CDEPEND}
-	java? ( >=virtual/jre-1.4 )"
-DEPEND="${CDEPEND}
-	java? ( >=virtual/jdk-1.4
-		test? ( dev-java/junit:4
-			dev-java/hamcrest-core:1.3 ) )
-	test? ( ${PYTHON_DEPS} )
-	app-arch/unzip
-	sys-devel/gettext
-	virtual/pkgconfig"
-
-pkg_setup() {
-	if use python || use test; then
-		python-single-r1_pkg_setup
-	fi
-	java-pkg-opt-2_pkg_setup
-}
-
-src_unpack() {
-	#vcs-snapshot doesn't work on .zip
-	default
-	mv * ${P} || die
-}
-
-src_prepare() {
-	eapply "${FILESDIR}"/${PN}-0.10-errors.patch \
-		"${FILESDIR}"/${PN}-0.10-python-crash.patch \
-		"${FILESDIR}"/${PN}-0.10-v4l2-uvcvideo.patch
-
-	# fix use of deprecated qt4 function, bug 572488
-	sed -e 's:numBytes:byteCount:g' \
-		-i "${S}"/include/zbar/QZBarImage.h || die
-
-	if has_version '>=media-gfx/imagemagick-7.0.1.0' ; then
-		eapply "${FILESDIR}/${P}-ImageMagick-7.diff"
-	fi
-
-	use python && python_fix_shebang examples/upcrpc.py test/*.py
-	java-pkg-opt-2_src_prepare
-
-	sed -e '/AM_INIT_AUTOMAKE/s: -Werror : :' \
-		-e '/^AM_CFLAGS=/s: -Werror::' \
-		-i configure.ac || die
-	sed "s|javadir = \$(pkgdatadir)|javadir = /usr/$(get_libdir)/zbar|" \
-		-i java/Makefile.am
-	eautoreconf
-}
-
-multilib_src_configure() {
-	if multilib_is_native_abi && use java; then
-		export JAVACFLAGS="$(java-pkg_javac-args)"
-		export JAVA_CFLAGS="$(java-pkg_get-jni-cflags)"
-		if use test ; then # bug 629078
-			java-pkg_append_ CLASSPATH .
-			java-pkg_append_ CLASSPATH $(java-pkg_getjar --build-only junit-4 junit.jar)
-			java-pkg_append_ CLASSPATH $(java-pkg_getjar --build-only hamcrest-core-1.3 hamcrest-core.jar)
-		fi
-	fi
-
-	append-cppflags -DNDEBUG
-
-	# different flags for image/graphics magick (bug 552350)
-	myimagemagick="--without-imagemagick"
-	has_version media-gfx/imagemagick &&
-		myimagemagick="$(multilib_native_use_with imagemagick)"
-	mygraphicsmagick="--without-graphicsmagick"
-	has_version media-gfx/graphicsmagick &&
-		mygraphicsmagick="$(multilib_native_use_with imagemagick graphicsmagick)"
-	ECONF_SOURCE=${S} \
-	econf \
-		$(multilib_native_use_with java) \
-		$(use_with jpeg) \
-		$(use_with gtk) \
-		${myimagemagick} \
-		${mygraphicsmagick} \
-		$(multilib_native_use_with python) \
-		$(use_with qt4 qt) \
-		$(use_enable static-libs static) \
-		$(use_enable threads pthread) \
-		$(use_with X x) \
-		$(use_with xv xv) \
-		$(use_enable v4l video)
-
-	# work-around out-of-source build issue
-	mkdir gtk pygtk qt test || die
-}
-
-src_test() {
-	virtx multilib-minimal_src_test
-}
-
-multilib_src_install_all() {
-	dodoc HACKING NEWS README TODO
-	find "${D}" -name '*.la' -delete || die
-}
-
-pkg_preinst() {
-	java-pkg-opt-2_pkg_preinst
-}

[gentoo-commits] repo/gentoo:master commit in: media-gfx/zbar/

[Andreas Sturmlechner]

commit:     396ae5098d33469763456222de5638ff7e983475
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Sun Nov 25 11:48:30 2018 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Sun Nov 25 17:34:57 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=396ae509

media-gfx/zbar: 0.20.1 version bump, add USE qt5, graphicsmagick

Add missing || die

Closes: https://bugs.gentoo.org/667990
Closes: https://bugs.gentoo.org/641920
Closes: https://bugs.gentoo.org/629016
Package-Manager: Portage-2.3.52, Repoman-2.3.12
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 media-gfx/zbar/Manifest           |   1 +
 media-gfx/zbar/zbar-0.20.1.ebuild | 148 ++++++++++++++++++++++++++++++++++++++
 2 files changed, 149 insertions(+)

diff --git a/media-gfx/zbar/Manifest b/media-gfx/zbar/Manifest
index eae44cfe62f..b5bf4950fae 100644
--- a/media-gfx/zbar/Manifest
+++ b/media-gfx/zbar/Manifest
@@ -1 +1,2 @@
 DIST zbar-0.10_p20121015.zip 991578 BLAKE2B 021dfa3920a838fd7bab12b09600ac6949c1495045691c4cc547bfb6ec647658c60984da248b882eabfc0bb123b90401dd3a32adcd66726b1e7072662e303d18 SHA512 7bb74ea5b096093b283c44787547ad0b886281628d012aa7b03ddb477732feb1e12d4d5a661191d34b53b7b272a237f67840e219b0ac5e2803da478a1ddba7a1
+DIST zbar-0.20.1.tar.gz 555199 BLAKE2B f224a2207fa0603da4cc3a0e1d05bc73f3cf0cc9d13c26b3b801d3418f4f6a001b52e468b721552af61f4c8d7357934abd0560c24d3b233107785c69cfe14753 SHA512 21ad9d8fcdecb41bd4b8979366ab8ec6e8eac815f52270b0dc72ce6a126ccef933d048ce8bbe28f46ada5defadf85ba8c97c5c1870c9560a9dab28c585dfaf42

diff --git a/media-gfx/zbar/zbar-0.20.1.ebuild b/media-gfx/zbar/zbar-0.20.1.ebuild
new file mode 100644
index 00000000000..045ba2301cb
--- /dev/null
+++ b/media-gfx/zbar/zbar-0.20.1.ebuild
@@ -0,0 +1,148 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 )
+inherit autotools flag-o-matic java-pkg-opt-2 multilib-minimal python-single-r1 virtualx
+
+DESCRIPTION="Library and tools for reading barcodes from images or video"
+HOMEPAGE="https://github.com/procxx/zbar"
+SRC_URI="https://linuxtv.org/downloads/${PN}/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="graphicsmagick gtk imagemagick java jpeg python qt5 static-libs test +threads v4l X xv"
+REQUIRED_USE="
+	python? ( ${PYTHON_REQUIRED_USE} )
+	test? ( X ${PYTHON_REQUIRED_USE} )
+"
+
+COMMON_DEPEND="
+	gtk? (
+		dev-libs/glib:2[${MULTILIB_USEDEP}]
+		x11-libs/gtk+:2[${MULTILIB_USEDEP}]
+	)
+	imagemagick? (
+		!graphicsmagick? ( media-gfx/imagemagick:= )
+		graphicsmagick? ( media-gfx/graphicsmagick:= )
+	)
+	jpeg? ( virtual/jpeg:0[${MULTILIB_USEDEP}] )
+	python? (
+		${PYTHON_DEPS}
+		gtk? ( >=dev-python/pygtk-2[${PYTHON_USEDEP}] )
+	)
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtwidgets:5
+		dev-qt/qtx11extras:5
+	)
+	X? (
+		x11-libs/libX11[${MULTILIB_USEDEP}]
+		x11-libs/libXext[${MULTILIB_USEDEP}]
+		xv? ( x11-libs/libXv[${MULTILIB_USEDEP}] )
+	)
+"
+RDEPEND="${COMMON_DEPEND}
+	java? ( >=virtual/jre-1.8 )
+"
+DEPEND="${COMMON_DEPEND}
+	sys-devel/gettext
+	virtual/pkgconfig
+	gtk? ( dev-util/glib-utils )
+	java? (
+		>=virtual/jdk-1.8
+		test? (
+			dev-java/junit:4
+			dev-java/hamcrest-core:1.3
+		)
+	)
+	test? ( ${PYTHON_DEPS} )
+"
+
+PATCHES=( "${FILESDIR}"/${PN}-0.10-errors.patch )
+
+pkg_setup() {
+	if use python || use test; then
+		python-single-r1_pkg_setup
+	fi
+	java-pkg-opt-2_pkg_setup
+}
+
+src_prepare() {
+	default
+
+	if has_version '>=media-gfx/imagemagick-7.0.1.0' ; then
+		eapply "${FILESDIR}/${PN}-0.10_p20121015-ImageMagick-7.diff"
+	fi
+
+	use python && python_fix_shebang examples/upcrpc.py test/*.py
+	java-pkg-opt-2_src_prepare
+
+	sed -e '/AM_INIT_AUTOMAKE/s: -Werror : :' \
+		-e '/^AM_CFLAGS=/s: -Werror::' \
+		-i configure.ac || die
+	sed "s|javadir = \$(pkgdatadir)|javadir = /usr/$(get_libdir)/zbar|" \
+		-i java/Makefile.am || die
+	eautoreconf
+}
+
+multilib_src_configure() {
+	append-cppflags -DNDEBUG
+
+	local myeconfargs=(
+		$(use_with gtk)
+		$(multilib_native_use_with graphicsmagick graphicsmagick)
+		$(multilib_native_use_with imagemagick)
+		$(multilib_native_use_with java)
+		$(use_with jpeg)
+		$(multilib_native_use_with python python2)
+		$(use_enable static-libs static)
+		$(use_enable threads pthread)
+		$(use_enable v4l video)
+		$(use_with X x)
+		$(use_with X xshm)
+		$(use_with xv xv)
+	)
+
+	if multilib_is_native_abi; then
+		if use java; then
+			export JAVACFLAGS="$(java-pkg_javac-args)"
+			export JAVA_CFLAGS="$(java-pkg_get-jni-cflags)"
+			if use test ; then # bug 629078
+				java-pkg_append_ CLASSPATH .
+				java-pkg_append_ CLASSPATH $(java-pkg_getjar --build-only junit-4 junit.jar)
+				java-pkg_append_ CLASSPATH $(java-pkg_getjar --build-only hamcrest-core-1.3 hamcrest-core.jar)
+			fi
+		fi
+		if use qt5; then
+			myeconfargs+=(
+				$(use_with qt5 qt)
+				$(use_with qt5)
+			)
+		else
+			myeconfargs+=( --without-qt )
+		fi
+	fi
+
+	ECONF_SOURCE=${S} \
+		econf "${myeconfargs[@]}"
+
+	# work-around out-of-source build issue
+	mkdir gtk pygtk qt test || die
+}
+
+src_test() {
+	virtx multilib-minimal_src_test
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	find "${D}" -name '*.la' -delete || die
+}
+
+pkg_preinst() {
+	java-pkg-opt-2_pkg_preinst
+}

[gentoo-commits] repo/gentoo:master commit in: media-gfx/zbar/

[Louis Sautier]

commit:     cb1a5fb3fdd4f957378e09f02b0dfeda30121329
Author:     Louis Sautier <sbraz <AT> gentoo <DOT> org>
AuthorDate: Wed Dec  5 08:15:50 2018 +0000
Commit:     Louis Sautier <sbraz <AT> gentoo <DOT> org>
CommitDate: Wed Dec  5 08:18:38 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=cb1a5fb3

media-gfx/zbar: update HOMEPAGE and upstream metadata

Package-Manager: Portage-2.3.52, Repoman-2.3.12
Signed-off-by: Louis Sautier <sbraz <AT> gentoo.org>

 media-gfx/zbar/metadata.xml                  | 2 ++
 media-gfx/zbar/zbar-0.10_p20121015-r3.ebuild | 4 ++--
 media-gfx/zbar/zbar-0.20.1.ebuild            | 2 +-
 3 files changed, 5 insertions(+), 3 deletions(-)

diff --git a/media-gfx/zbar/metadata.xml b/media-gfx/zbar/metadata.xml
index 20edbb2faec..fd5ad454e03 100644
--- a/media-gfx/zbar/metadata.xml
+++ b/media-gfx/zbar/metadata.xml
@@ -4,5 +4,7 @@
 	<!-- maintainer-needed -->
 	<upstream>
 		<remote-id type="sourceforge">zbar</remote-id>
+		<remote-id type="github">mchehab/zbar</remote-id>
+		<bugs-to>https://github.com/mchehab/zbar/issues</bugs-to>
 	</upstream>
 </pkgmetadata>

diff --git a/media-gfx/zbar/zbar-0.10_p20121015-r3.ebuild b/media-gfx/zbar/zbar-0.10_p20121015-r3.ebuild
index 719be7784d5..6990df2d2b3 100644
--- a/media-gfx/zbar/zbar-0.10_p20121015-r3.ebuild
+++ b/media-gfx/zbar/zbar-0.10_p20121015-r3.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2018 Gentoo Foundation
+# Copyright 1999-2018 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=6
@@ -7,7 +7,7 @@ PYTHON_COMPAT=( python2_7 )
 inherit autotools flag-o-matic java-pkg-opt-2 multilib-minimal python-single-r1 virtualx
 
 DESCRIPTION="Library and tools for reading barcodes from images or video"
-HOMEPAGE="http://zbar.sourceforge.net/"
+HOMEPAGE="https://github.com/mchehab/zbar"
 SRC_URI="https://dev.gentoo.org/~xmw/zbar-0.10_p20121015.zip"
 
 LICENSE="LGPL-2.1"

diff --git a/media-gfx/zbar/zbar-0.20.1.ebuild b/media-gfx/zbar/zbar-0.20.1.ebuild
index a24c1daade0..8d21ca2a30a 100644
--- a/media-gfx/zbar/zbar-0.20.1.ebuild
+++ b/media-gfx/zbar/zbar-0.20.1.ebuild
@@ -7,7 +7,7 @@ PYTHON_COMPAT=( python2_7 )
 inherit autotools flag-o-matic java-pkg-opt-2 multilib-minimal python-single-r1 virtualx
 
 DESCRIPTION="Library and tools for reading barcodes from images or video"
-HOMEPAGE="https://github.com/procxx/zbar"
+HOMEPAGE="https://github.com/mchehab/zbar"
 SRC_URI="https://linuxtv.org/downloads/${PN}/${P}.tar.gz"
 
 LICENSE="LGPL-2.1"

[gentoo-commits] repo/gentoo:master commit in: media-gfx/zbar/

[Louis Sautier]

commit:     91433e5fca89bb5281548d29e3c13278ad295425
Author:     Louis Sautier <sbraz <AT> gentoo <DOT> org>
AuthorDate: Wed Dec  5 09:49:01 2018 +0000
Commit:     Louis Sautier <sbraz <AT> gentoo <DOT> org>
CommitDate: Wed Dec  5 09:52:47 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=91433e5f

media-gfx/zbar: fix build failures on multilib systems

* Explicitly disable QT on non-native ABIs, otherwise it is implicitly
  enabled by upstream's build system.
* Wrap QT-related headers that are only included for native ABI builds.

Closes: https://bugs.gentoo.org/672500
Package-Manager: Portage-2.3.52, Repoman-2.3.12
Signed-off-by: Louis Sautier <sbraz <AT> gentoo.org>

 media-gfx/zbar/zbar-0.20.1.ebuild | 12 ++++++++++++
 1 file changed, 12 insertions(+)

diff --git a/media-gfx/zbar/zbar-0.20.1.ebuild b/media-gfx/zbar/zbar-0.20.1.ebuild
index 8d21ca2a30a..643a3a60ea9 100644
--- a/media-gfx/zbar/zbar-0.20.1.ebuild
+++ b/media-gfx/zbar/zbar-0.20.1.ebuild
@@ -125,6 +125,8 @@ multilib_src_configure() {
 		else
 			myeconfargs+=( --without-qt )
 		fi
+	else
+			myeconfargs+=( --without-qt )
 	fi
 
 	ECONF_SOURCE=${S} \
@@ -138,6 +140,16 @@ src_test() {
 	virtx multilib-minimal_src_test
 }
 
+src_install() {
+	if use qt5; then
+		local MULTILIB_WRAPPED_HEADERS=(
+			/usr/include/zbar/QZBar.h
+			/usr/include/zbar/QZBarImage.h
+		)
+	fi
+	multilib-minimal_src_install
+}
+
 multilib_src_install_all() {
 	einstalldocs
 	find "${D}" -name '*.la' -delete || die

[gentoo-commits] repo/gentoo:master commit in: media-gfx/zbar/

[Louis Sautier]

commit:     ca3a5c1bc65bfb8b8456a8ab16a83efeec973e82
Author:     Louis Sautier <sbraz <AT> gentoo <DOT> org>
AuthorDate: Wed Dec  5 12:28:13 2018 +0000
Commit:     Louis Sautier <sbraz <AT> gentoo <DOT> org>
CommitDate: Wed Dec  5 12:43:32 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ca3a5c1b

media-gfx/zbar: fix multilib build with USE="v4l qt5"

Closes: https://bugs.gentoo.org/672184
Package-Manager: Portage-2.3.52, Repoman-2.3.12
Signed-off-by: Louis Sautier <sbraz <AT> gentoo.org>

 media-gfx/zbar/zbar-0.20.1.ebuild | 5 +++--
 1 file changed, 3 insertions(+), 2 deletions(-)

diff --git a/media-gfx/zbar/zbar-0.20.1.ebuild b/media-gfx/zbar/zbar-0.20.1.ebuild
index 643a3a60ea9..b62121e32e5 100644
--- a/media-gfx/zbar/zbar-0.20.1.ebuild
+++ b/media-gfx/zbar/zbar-0.20.1.ebuild
@@ -132,8 +132,9 @@ multilib_src_configure() {
 	ECONF_SOURCE=${S} \
 		econf "${myeconfargs[@]}"
 
-	# work-around out-of-source build issue
-	mkdir gtk pygtk qt test || die
+	# work around out-of-source build issues for multilib systems
+	# https://bugs.gentoo.org/672184
+	mkdir gtk pygtk qt test zbarcam || die
 }
 
 src_test() {

[gentoo-commits] repo/gentoo:master commit in: media-gfx/zbar/

[Thomas Deutschmann]

commit:     c495832a6336cbf8c0d153c20072faff0f77f3ba
Author:     Thomas Deutschmann <whissi <AT> gentoo <DOT> org>
AuthorDate: Sat Dec 22 22:22:38 2018 +0000
Commit:     Thomas Deutschmann <whissi <AT> gentoo <DOT> org>
CommitDate: Sat Dec 22 22:22:38 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c495832a

media-gfx/zbar: x86 stable (bug #673020)

Package-Manager: Portage-2.3.52, Repoman-2.3.12
Signed-off-by: Thomas Deutschmann <whissi <AT> gentoo.org>

 media-gfx/zbar/zbar-0.20.1.ebuild | 2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)

diff --git a/media-gfx/zbar/zbar-0.20.1.ebuild b/media-gfx/zbar/zbar-0.20.1.ebuild
index b62121e32e5..1299e249e15 100644
--- a/media-gfx/zbar/zbar-0.20.1.ebuild
+++ b/media-gfx/zbar/zbar-0.20.1.ebuild
@@ -12,7 +12,7 @@ SRC_URI="https://linuxtv.org/downloads/${PN}/${P}.tar.gz"
 
 LICENSE="LGPL-2.1"
 SLOT="0"
-KEYWORDS="~amd64 ~arm ~x86"
+KEYWORDS="~amd64 ~arm x86"
 IUSE="graphicsmagick gtk imagemagick java jpeg python qt5 static-libs test +threads v4l X xv"
 REQUIRED_USE="
 	python? ( ${PYTHON_REQUIRED_USE} )

[gentoo-commits] repo/gentoo:master commit in: media-gfx/zbar/

[Mikle Kolyada]

commit:     8487d4215c53e191bf3b88e821c1ecc4dc7324e2
Author:     Mikle Kolyada <zlogene <AT> gentoo <DOT> org>
AuthorDate: Sat Dec 29 09:16:00 2018 +0000
Commit:     Mikle Kolyada <zlogene <AT> gentoo <DOT> org>
CommitDate: Sat Dec 29 09:16:00 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=8487d421

media-gfx/zbar: amd64 stable wrt bug #673020

Signed-off-by: Mikle Kolyada <zlogene <AT> gentoo.org>
Package-Manager: Portage-2.3.51, Repoman-2.3.11

 media-gfx/zbar/zbar-0.20.1.ebuild | 2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)

diff --git a/media-gfx/zbar/zbar-0.20.1.ebuild b/media-gfx/zbar/zbar-0.20.1.ebuild
index 1299e249e15..700328f7538 100644
--- a/media-gfx/zbar/zbar-0.20.1.ebuild
+++ b/media-gfx/zbar/zbar-0.20.1.ebuild
@@ -12,7 +12,7 @@ SRC_URI="https://linuxtv.org/downloads/${PN}/${P}.tar.gz"
 
 LICENSE="LGPL-2.1"
 SLOT="0"
-KEYWORDS="~amd64 ~arm x86"
+KEYWORDS="amd64 ~arm x86"
 IUSE="graphicsmagick gtk imagemagick java jpeg python qt5 static-libs test +threads v4l X xv"
 REQUIRED_USE="
 	python? ( ${PYTHON_REQUIRED_USE} )

[gentoo-commits] repo/gentoo:master commit in: media-gfx/zbar/

[Andreas Sturmlechner]

commit:     171f77b5e336fc38e73948f801cb5e2672675f7f
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Sat Dec 29 13:36:28 2018 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Sat Dec 29 13:36:28 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=171f77b5

media-gfx/zbar: Drop 0.10_p20121015-r3

Package-Manager: Portage-2.3.52, Repoman-2.3.12
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 media-gfx/zbar/Manifest                      |   1 -
 media-gfx/zbar/zbar-0.10_p20121015-r3.ebuild | 130 ---------------------------
 2 files changed, 131 deletions(-)

diff --git a/media-gfx/zbar/Manifest b/media-gfx/zbar/Manifest
index b5bf4950fae..00a21a631d2 100644
--- a/media-gfx/zbar/Manifest
+++ b/media-gfx/zbar/Manifest
@@ -1,2 +1 @@
-DIST zbar-0.10_p20121015.zip 991578 BLAKE2B 021dfa3920a838fd7bab12b09600ac6949c1495045691c4cc547bfb6ec647658c60984da248b882eabfc0bb123b90401dd3a32adcd66726b1e7072662e303d18 SHA512 7bb74ea5b096093b283c44787547ad0b886281628d012aa7b03ddb477732feb1e12d4d5a661191d34b53b7b272a237f67840e219b0ac5e2803da478a1ddba7a1
 DIST zbar-0.20.1.tar.gz 555199 BLAKE2B f224a2207fa0603da4cc3a0e1d05bc73f3cf0cc9d13c26b3b801d3418f4f6a001b52e468b721552af61f4c8d7357934abd0560c24d3b233107785c69cfe14753 SHA512 21ad9d8fcdecb41bd4b8979366ab8ec6e8eac815f52270b0dc72ce6a126ccef933d048ce8bbe28f46ada5defadf85ba8c97c5c1870c9560a9dab28c585dfaf42

diff --git a/media-gfx/zbar/zbar-0.10_p20121015-r3.ebuild b/media-gfx/zbar/zbar-0.10_p20121015-r3.ebuild
deleted file mode 100644
index 6990df2d2b3..00000000000
--- a/media-gfx/zbar/zbar-0.10_p20121015-r3.ebuild
+++ /dev/null
@@ -1,130 +0,0 @@
-# Copyright 1999-2018 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-
-PYTHON_COMPAT=( python2_7 )
-inherit autotools flag-o-matic java-pkg-opt-2 multilib-minimal python-single-r1 virtualx
-
-DESCRIPTION="Library and tools for reading barcodes from images or video"
-HOMEPAGE="https://github.com/mchehab/zbar"
-SRC_URI="https://dev.gentoo.org/~xmw/zbar-0.10_p20121015.zip"
-
-LICENSE="LGPL-2.1"
-SLOT="0"
-KEYWORDS="amd64 ~arm x86"
-IUSE="gtk imagemagick java jpeg python static-libs test +threads v4l X xv"
-REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )
-	test? ( X ${PYTHON_REQUIRED_USE} )"
-
-CDEPEND="gtk? ( dev-libs/glib:2[${MULTILIB_USEDEP}]
-		x11-libs/gtk+:2[${MULTILIB_USEDEP}] )
-	imagemagick? ( virtual/imagemagick-tools )
-	jpeg? ( virtual/jpeg:0[${MULTILIB_USEDEP}] )
-	python? (
-		${PYTHON_DEPS}
-		gtk? ( >=dev-python/pygtk-2[${PYTHON_USEDEP}] )
-	)
-	X? (
-		x11-libs/libXext[${MULTILIB_USEDEP}]
-		xv? ( x11-libs/libXv[${MULTILIB_USEDEP}] )
-	)"
-RDEPEND="${CDEPEND}
-	java? ( >=virtual/jre-1.4 )"
-DEPEND="${CDEPEND}
-	java? ( >=virtual/jdk-1.4
-		test? ( dev-java/junit:4
-			dev-java/hamcrest-core:1.3 ) )
-	test? ( ${PYTHON_DEPS} )
-	app-arch/unzip
-	sys-devel/gettext
-	virtual/pkgconfig"
-
-pkg_setup() {
-	if use python || use test; then
-		python-single-r1_pkg_setup
-	fi
-	java-pkg-opt-2_pkg_setup
-}
-
-src_unpack() {
-	#vcs-snapshot doesn't work on .zip
-	default
-	mv * ${P} || die
-}
-
-src_prepare() {
-	eapply "${FILESDIR}"/${PN}-0.10-errors.patch \
-		"${FILESDIR}"/${PN}-0.10-python-crash.patch \
-		"${FILESDIR}"/${PN}-0.10-v4l2-uvcvideo.patch
-
-	# fix use of deprecated qt4 function, bug 572488
-	sed -e 's:numBytes:byteCount:g' \
-		-i "${S}"/include/zbar/QZBarImage.h || die
-
-	if has_version '>=media-gfx/imagemagick-7.0.1.0' ; then
-		eapply "${FILESDIR}/${P}-ImageMagick-7.patch"
-	fi
-
-	use python && python_fix_shebang examples/upcrpc.py test/*.py
-	java-pkg-opt-2_src_prepare
-
-	sed -e '/AM_INIT_AUTOMAKE/s: -Werror : :' \
-		-e '/^AM_CFLAGS=/s: -Werror::' \
-		-i configure.ac || die
-	sed "s|javadir = \$(pkgdatadir)|javadir = /usr/$(get_libdir)/zbar|" \
-		-i java/Makefile.am
-	eautoreconf
-}
-
-multilib_src_configure() {
-	if multilib_is_native_abi && use java; then
-		export JAVACFLAGS="$(java-pkg_javac-args)"
-		export JAVA_CFLAGS="$(java-pkg_get-jni-cflags)"
-		if use test ; then # bug 629078
-			java-pkg_append_ CLASSPATH .
-			java-pkg_append_ CLASSPATH $(java-pkg_getjar --build-only junit-4 junit.jar)
-			java-pkg_append_ CLASSPATH $(java-pkg_getjar --build-only hamcrest-core-1.3 hamcrest-core.jar)
-		fi
-	fi
-
-	append-cppflags -DNDEBUG
-
-	# different flags for image/graphics magick (bug 552350)
-	myimagemagick="--without-imagemagick"
-	has_version media-gfx/imagemagick &&
-		myimagemagick="$(multilib_native_use_with imagemagick)"
-	mygraphicsmagick="--without-graphicsmagick"
-	has_version media-gfx/graphicsmagick &&
-		mygraphicsmagick="$(multilib_native_use_with imagemagick graphicsmagick)"
-	ECONF_SOURCE=${S} \
-	econf \
-		$(multilib_native_use_with java) \
-		$(use_with jpeg) \
-		$(use_with gtk) \
-		${myimagemagick} \
-		${mygraphicsmagick} \
-		$(multilib_native_use_with python) \
-		--without-qt \
-		$(use_enable static-libs static) \
-		$(use_enable threads pthread) \
-		$(use_with X x) \
-		$(use_with xv xv) \
-		$(use_enable v4l video)
-
-	# work-around out-of-source build issue
-	mkdir gtk pygtk qt test || die
-}
-
-src_test() {
-	virtx multilib-minimal_src_test
-}
-
-multilib_src_install_all() {
-	dodoc HACKING NEWS README TODO
-	find "${D}" -name '*.la' -delete || die
-}
-
-pkg_preinst() {
-	java-pkg-opt-2_pkg_preinst
-}

[gentoo-commits] repo/gentoo:master commit in: media-gfx/zbar/

[Pacho Ramos]

commit:     5270ac15b862fb09380ac93cbb5c9b37b4e33f15
Author:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
AuthorDate: Sat Jan 12 10:39:26 2019 +0000
Commit:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
CommitDate: Sat Jan 12 10:39:26 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=5270ac15

media-gfx/zbar: Fix deps for v4l

Closes: https://bugs.gentoo.org/673994
Package-Manager: Portage-2.3.53, Repoman-2.3.12
Signed-off-by: Pacho Ramos <pacho <AT> gentoo.org>

 media-gfx/zbar/zbar-0.20.1-r1.ebuild | 163 +++++++++++++++++++++++++++++++++++
 1 file changed, 163 insertions(+)

diff --git a/media-gfx/zbar/zbar-0.20.1-r1.ebuild b/media-gfx/zbar/zbar-0.20.1-r1.ebuild
new file mode 100644
index 00000000000..a374101200a
--- /dev/null
+++ b/media-gfx/zbar/zbar-0.20.1-r1.ebuild
@@ -0,0 +1,163 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 )
+
+inherit autotools flag-o-matic java-pkg-opt-2 multilib-minimal python-single-r1 virtualx
+
+DESCRIPTION="Library and tools for reading barcodes from images or video"
+HOMEPAGE="https://github.com/mchehab/zbar"
+SRC_URI="https://linuxtv.org/downloads/${PN}/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+
+IUSE="graphicsmagick gtk imagemagick java jpeg python qt5 static-libs test +threads v4l X xv"
+REQUIRED_USE="
+	python? ( ${PYTHON_REQUIRED_USE} )
+	test? ( X ${PYTHON_REQUIRED_USE} )
+"
+
+COMMON_DEPEND="
+	gtk? (
+		dev-libs/glib:2[${MULTILIB_USEDEP}]
+		x11-libs/gtk+:2[${MULTILIB_USEDEP}]
+	)
+	imagemagick? (
+		!graphicsmagick? ( media-gfx/imagemagick:= )
+		graphicsmagick? ( media-gfx/graphicsmagick:= )
+	)
+	jpeg? ( virtual/jpeg:0[${MULTILIB_USEDEP}] )
+	python? (
+		${PYTHON_DEPS}
+		gtk? ( >=dev-python/pygtk-2[${PYTHON_USEDEP}] )
+	)
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtwidgets:5
+		dev-qt/qtx11extras:5
+	)
+	v4l? ( media-libs/libv4l:0= )
+	X? (
+		x11-libs/libX11[${MULTILIB_USEDEP}]
+		x11-libs/libXext[${MULTILIB_USEDEP}]
+		xv? ( x11-libs/libXv[${MULTILIB_USEDEP}] )
+	)
+"
+RDEPEND="${COMMON_DEPEND}
+	java? ( >=virtual/jre-1.8 )
+"
+DEPEND="${COMMON_DEPEND}
+	sys-devel/gettext
+	virtual/pkgconfig
+	gtk? ( dev-util/glib-utils )
+	java? (
+		>=virtual/jdk-1.8
+		test? (
+			dev-java/junit:4
+			dev-java/hamcrest-core:1.3
+		)
+	)
+	test? ( ${PYTHON_DEPS} )
+"
+
+PATCHES=( "${FILESDIR}"/${PN}-0.10-errors.patch )
+
+pkg_setup() {
+	if use python || use test; then
+		python-single-r1_pkg_setup
+	fi
+	java-pkg-opt-2_pkg_setup
+}
+
+src_prepare() {
+	default
+
+	if has_version '>=media-gfx/imagemagick-7.0.1.0' ; then
+		eapply "${FILESDIR}/${PN}-0.10_p20121015-ImageMagick-7.patch"
+	fi
+
+	use python && python_fix_shebang examples/upcrpc.py test/*.py
+	java-pkg-opt-2_src_prepare
+
+	sed -e '/AM_INIT_AUTOMAKE/s: -Werror : :' \
+		-e '/^AM_CFLAGS=/s: -Werror::' \
+		-i configure.ac || die
+	sed "s|javadir = \$(pkgdatadir)|javadir = /usr/$(get_libdir)/zbar|" \
+		-i java/Makefile.am || die
+	eautoreconf
+}
+
+multilib_src_configure() {
+	append-cppflags -DNDEBUG
+
+	local myeconfargs=(
+		$(use_with gtk)
+		$(multilib_native_use_with graphicsmagick graphicsmagick)
+		$(multilib_native_use_with imagemagick)
+		$(multilib_native_use_with java)
+		$(use_with jpeg)
+		$(multilib_native_use_with python python2)
+		$(use_enable static-libs static)
+		$(use_enable threads pthread)
+		$(use_enable v4l video)
+		$(use_with X x)
+		$(use_with X xshm)
+		$(use_with xv xv)
+	)
+
+	if multilib_is_native_abi; then
+		if use java; then
+			export JAVACFLAGS="$(java-pkg_javac-args)"
+			export JAVA_CFLAGS="$(java-pkg_get-jni-cflags)"
+			if use test ; then # bug 629078
+				java-pkg_append_ CLASSPATH .
+				java-pkg_append_ CLASSPATH $(java-pkg_getjar --build-only junit-4 junit.jar)
+				java-pkg_append_ CLASSPATH $(java-pkg_getjar --build-only hamcrest-core-1.3 hamcrest-core.jar)
+			fi
+		fi
+		if use qt5; then
+			myeconfargs+=(
+				$(use_with qt5 qt)
+				$(use_with qt5)
+			)
+		else
+			myeconfargs+=( --without-qt )
+		fi
+	else
+			myeconfargs+=( --without-qt )
+	fi
+
+	ECONF_SOURCE=${S} \
+		econf "${myeconfargs[@]}"
+
+	# work around out-of-source build issues for multilib systems
+	# https://bugs.gentoo.org/672184
+	mkdir gtk pygtk qt test zbarcam || die
+}
+
+src_test() {
+	virtx multilib-minimal_src_test
+}
+
+src_install() {
+	if use qt5; then
+		local MULTILIB_WRAPPED_HEADERS=(
+			/usr/include/zbar/QZBar.h
+			/usr/include/zbar/QZBarImage.h
+		)
+	fi
+	multilib-minimal_src_install
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	find "${D}" -name '*.la' -delete || die
+}
+
+pkg_preinst() {
+	java-pkg-opt-2_pkg_preinst
+}

[gentoo-commits] repo/gentoo:master commit in: media-gfx/zbar/

[Mikle Kolyada]

commit:     e5c7baa4ff267423669f3dcb849fee691212516c
Author:     Mikle Kolyada <zlogene <AT> gentoo <DOT> org>
AuthorDate: Tue Feb 12 09:35:53 2019 +0000
Commit:     Mikle Kolyada <zlogene <AT> gentoo <DOT> org>
CommitDate: Tue Feb 12 09:35:53 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e5c7baa4

media-gfx/zbar: x86 stable wrt bug #676570

Signed-off-by: Mikle Kolyada <zlogene <AT> gentoo.org>
Package-Manager: Portage-2.3.51, Repoman-2.3.11

 media-gfx/zbar/zbar-0.20.1-r1.ebuild | 2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)

diff --git a/media-gfx/zbar/zbar-0.20.1-r1.ebuild b/media-gfx/zbar/zbar-0.20.1-r1.ebuild
index a3f82f05236..1a03d35fa4d 100644
--- a/media-gfx/zbar/zbar-0.20.1-r1.ebuild
+++ b/media-gfx/zbar/zbar-0.20.1-r1.ebuild
@@ -12,7 +12,7 @@ SRC_URI="https://linuxtv.org/downloads/${PN}/${P}.tar.gz"
 
 LICENSE="LGPL-2.1"
 SLOT="0"
-KEYWORDS="amd64 ~arm ~x86"
+KEYWORDS="amd64 ~arm x86"
 
 IUSE="graphicsmagick gtk imagemagick java jpeg python qt5 static-libs test +threads v4l X xv"
 REQUIRED_USE="

[gentoo-commits] repo/gentoo:master commit in: media-gfx/zbar/

[Mikle Kolyada]

commit:     e0c71c983390c16e6f0030cd4077a396769d634c
Author:     Mikle Kolyada <zlogene <AT> gentoo <DOT> org>
AuthorDate: Tue Feb 12 09:34:30 2019 +0000
Commit:     Mikle Kolyada <zlogene <AT> gentoo <DOT> org>
CommitDate: Tue Feb 12 09:34:30 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e0c71c98

media-gfx/zbar: amd64 stable wrt bug #676570

Signed-off-by: Mikle Kolyada <zlogene <AT> gentoo.org>
Package-Manager: Portage-2.3.51, Repoman-2.3.11

 media-gfx/zbar/zbar-0.20.1-r1.ebuild | 2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)

diff --git a/media-gfx/zbar/zbar-0.20.1-r1.ebuild b/media-gfx/zbar/zbar-0.20.1-r1.ebuild
index a374101200a..a3f82f05236 100644
--- a/media-gfx/zbar/zbar-0.20.1-r1.ebuild
+++ b/media-gfx/zbar/zbar-0.20.1-r1.ebuild
@@ -12,7 +12,7 @@ SRC_URI="https://linuxtv.org/downloads/${PN}/${P}.tar.gz"
 
 LICENSE="LGPL-2.1"
 SLOT="0"
-KEYWORDS="~amd64 ~arm ~x86"
+KEYWORDS="amd64 ~arm ~x86"
 
 IUSE="graphicsmagick gtk imagemagick java jpeg python qt5 static-libs test +threads v4l X xv"
 REQUIRED_USE="

[gentoo-commits] repo/gentoo:master commit in: media-gfx/zbar/

[Mikle Kolyada]

commit:     084749933c76a97668607c9385f2951ee443112a
Author:     Mikle Kolyada <zlogene <AT> gentoo <DOT> org>
AuthorDate: Tue Feb 12 09:39:14 2019 +0000
Commit:     Mikle Kolyada <zlogene <AT> gentoo <DOT> org>
CommitDate: Tue Feb 12 09:39:14 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=08474993

media-gfx/zbar: Drop old

Signed-off-by: Mikle Kolyada <zlogene <AT> gentoo.org>
Package-Manager: Portage-2.3.51, Repoman-2.3.11

 media-gfx/zbar/zbar-0.20.1.ebuild | 161 --------------------------------------
 1 file changed, 161 deletions(-)

diff --git a/media-gfx/zbar/zbar-0.20.1.ebuild b/media-gfx/zbar/zbar-0.20.1.ebuild
deleted file mode 100644
index 700328f7538..00000000000
--- a/media-gfx/zbar/zbar-0.20.1.ebuild
+++ /dev/null
@@ -1,161 +0,0 @@
-# Copyright 1999-2018 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-
-PYTHON_COMPAT=( python2_7 )
-inherit autotools flag-o-matic java-pkg-opt-2 multilib-minimal python-single-r1 virtualx
-
-DESCRIPTION="Library and tools for reading barcodes from images or video"
-HOMEPAGE="https://github.com/mchehab/zbar"
-SRC_URI="https://linuxtv.org/downloads/${PN}/${P}.tar.gz"
-
-LICENSE="LGPL-2.1"
-SLOT="0"
-KEYWORDS="amd64 ~arm x86"
-IUSE="graphicsmagick gtk imagemagick java jpeg python qt5 static-libs test +threads v4l X xv"
-REQUIRED_USE="
-	python? ( ${PYTHON_REQUIRED_USE} )
-	test? ( X ${PYTHON_REQUIRED_USE} )
-"
-
-COMMON_DEPEND="
-	gtk? (
-		dev-libs/glib:2[${MULTILIB_USEDEP}]
-		x11-libs/gtk+:2[${MULTILIB_USEDEP}]
-	)
-	imagemagick? (
-		!graphicsmagick? ( media-gfx/imagemagick:= )
-		graphicsmagick? ( media-gfx/graphicsmagick:= )
-	)
-	jpeg? ( virtual/jpeg:0[${MULTILIB_USEDEP}] )
-	python? (
-		${PYTHON_DEPS}
-		gtk? ( >=dev-python/pygtk-2[${PYTHON_USEDEP}] )
-	)
-	qt5? (
-		dev-qt/qtcore:5
-		dev-qt/qtgui:5
-		dev-qt/qtwidgets:5
-		dev-qt/qtx11extras:5
-	)
-	X? (
-		x11-libs/libX11[${MULTILIB_USEDEP}]
-		x11-libs/libXext[${MULTILIB_USEDEP}]
-		xv? ( x11-libs/libXv[${MULTILIB_USEDEP}] )
-	)
-"
-RDEPEND="${COMMON_DEPEND}
-	java? ( >=virtual/jre-1.8 )
-"
-DEPEND="${COMMON_DEPEND}
-	sys-devel/gettext
-	virtual/pkgconfig
-	gtk? ( dev-util/glib-utils )
-	java? (
-		>=virtual/jdk-1.8
-		test? (
-			dev-java/junit:4
-			dev-java/hamcrest-core:1.3
-		)
-	)
-	test? ( ${PYTHON_DEPS} )
-"
-
-PATCHES=( "${FILESDIR}"/${PN}-0.10-errors.patch )
-
-pkg_setup() {
-	if use python || use test; then
-		python-single-r1_pkg_setup
-	fi
-	java-pkg-opt-2_pkg_setup
-}
-
-src_prepare() {
-	default
-
-	if has_version '>=media-gfx/imagemagick-7.0.1.0' ; then
-		eapply "${FILESDIR}/${PN}-0.10_p20121015-ImageMagick-7.patch"
-	fi
-
-	use python && python_fix_shebang examples/upcrpc.py test/*.py
-	java-pkg-opt-2_src_prepare
-
-	sed -e '/AM_INIT_AUTOMAKE/s: -Werror : :' \
-		-e '/^AM_CFLAGS=/s: -Werror::' \
-		-i configure.ac || die
-	sed "s|javadir = \$(pkgdatadir)|javadir = /usr/$(get_libdir)/zbar|" \
-		-i java/Makefile.am || die
-	eautoreconf
-}
-
-multilib_src_configure() {
-	append-cppflags -DNDEBUG
-
-	local myeconfargs=(
-		$(use_with gtk)
-		$(multilib_native_use_with graphicsmagick graphicsmagick)
-		$(multilib_native_use_with imagemagick)
-		$(multilib_native_use_with java)
-		$(use_with jpeg)
-		$(multilib_native_use_with python python2)
-		$(use_enable static-libs static)
-		$(use_enable threads pthread)
-		$(use_enable v4l video)
-		$(use_with X x)
-		$(use_with X xshm)
-		$(use_with xv xv)
-	)
-
-	if multilib_is_native_abi; then
-		if use java; then
-			export JAVACFLAGS="$(java-pkg_javac-args)"
-			export JAVA_CFLAGS="$(java-pkg_get-jni-cflags)"
-			if use test ; then # bug 629078
-				java-pkg_append_ CLASSPATH .
-				java-pkg_append_ CLASSPATH $(java-pkg_getjar --build-only junit-4 junit.jar)
-				java-pkg_append_ CLASSPATH $(java-pkg_getjar --build-only hamcrest-core-1.3 hamcrest-core.jar)
-			fi
-		fi
-		if use qt5; then
-			myeconfargs+=(
-				$(use_with qt5 qt)
-				$(use_with qt5)
-			)
-		else
-			myeconfargs+=( --without-qt )
-		fi
-	else
-			myeconfargs+=( --without-qt )
-	fi
-
-	ECONF_SOURCE=${S} \
-		econf "${myeconfargs[@]}"
-
-	# work around out-of-source build issues for multilib systems
-	# https://bugs.gentoo.org/672184
-	mkdir gtk pygtk qt test zbarcam || die
-}
-
-src_test() {
-	virtx multilib-minimal_src_test
-}
-
-src_install() {
-	if use qt5; then
-		local MULTILIB_WRAPPED_HEADERS=(
-			/usr/include/zbar/QZBar.h
-			/usr/include/zbar/QZBarImage.h
-		)
-	fi
-	multilib-minimal_src_install
-}
-
-multilib_src_install_all() {
-	einstalldocs
-	find "${D}" -name '*.la' -delete || die
-}
-
-pkg_preinst() {
-	java-pkg-opt-2_pkg_preinst
-}

[gentoo-commits] repo/gentoo:master commit in: media-gfx/zbar/

[Andreas Sturmlechner]

commit:     f289e9966587b984f21aaeb095955e23bf52ccdf
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Mon Feb  3 14:29:34 2020 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Mon Feb  3 17:35:39 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f289e996

media-gfx/zbar: Minor nitpicks

Unify sed style, add minimum jre version, move einstalldocs

Package-Manager: Portage-2.3.86, Repoman-2.3.20
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 media-gfx/zbar/zbar-0.23.ebuild | 14 ++++++--------
 1 file changed, 6 insertions(+), 8 deletions(-)

diff --git a/media-gfx/zbar/zbar-0.23.ebuild b/media-gfx/zbar/zbar-0.23.ebuild
index 34eb41b923a..495dc423d47 100644
--- a/media-gfx/zbar/zbar-0.23.ebuild
+++ b/media-gfx/zbar/zbar-0.23.ebuild
@@ -54,7 +54,7 @@ COMMON_DEPEND="
 	)"
 
 RDEPEND="${COMMON_DEPEND}
-	java? ( virtual/jre )"
+	java? ( >=virtual/jre-1.8 )"
 
 DEPEND="${COMMON_DEPEND}
 	java? (
@@ -99,9 +99,8 @@ src_prepare() {
 		if use test; then
 			# make tests happy
 			# because one of the test requires loadable py module from the current ${BUILD_DIR}
-			sed -i \
-				-e "s|PYTHONPATH=@abs_top_srcdir@|PYTHONPATH=@builddir@|g" \
-				test/Makefile.am.inc || die
+			sed -e "s|PYTHONPATH=@abs_top_srcdir@|PYTHONPATH=@builddir@|g" \
+				-i test/Makefile.am.inc || die
 		fi
 
 		python_fix_shebang \
@@ -111,13 +110,12 @@ src_prepare() {
 
 	if use java; then
 		java-pkg-opt-2_src_prepare
-		sed "s|javadir = \$(pkgdatadir)|javadir = /usr/$(get_libdir)/zbar|" \
+		sed -e "s|javadir = \$(pkgdatadir)|javadir = /usr/$(get_libdir)/zbar|" \
 			-i java/Makefile.am || die
 	fi
 
 	# do not install {LICENSE,INSTALL,etc}.md doc files with 'make install' (use DOCS=() instead)
-	sed -i \
-		-e "s|^dist_doc_DATA =\(.*\)|dist_doc_DATA =|" Makefile.am || die
+	sed -e "s|^dist_doc_DATA =\(.*\)|dist_doc_DATA =|" -i Makefile.am || die
 
 	eautoreconf
 }
@@ -204,10 +202,10 @@ src_install() {
 		)
 	fi
 	multilib-minimal_src_install
-	einstalldocs
 }
 
 multilib_src_install_all() {
+	einstalldocs
 	find "${D}" -name '*.la' -delete || die
 }
 

[gentoo-commits] repo/gentoo:master commit in: media-gfx/zbar/

[Michał Górny]

commit:     1c98fe8bc128858fa999409a779a1a72812bd524
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Fri Feb  7 15:06:53 2020 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sun Feb  9 16:26:54 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1c98fe8b

media-gfx/zbar: Switch to PYTHON_MULTI_USEDEP API

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 media-gfx/zbar/{zbar-0.20.1-r1.ebuild => zbar-0.20.1-r2.ebuild} | 8 ++++++--
 media-gfx/zbar/{zbar-0.23.ebuild => zbar-0.23-r1.ebuild}        | 4 +++-
 2 files changed, 9 insertions(+), 3 deletions(-)

diff --git a/media-gfx/zbar/zbar-0.20.1-r1.ebuild b/media-gfx/zbar/zbar-0.20.1-r2.ebuild
similarity index 96%
rename from media-gfx/zbar/zbar-0.20.1-r1.ebuild
rename to media-gfx/zbar/zbar-0.20.1-r2.ebuild
index 9a6382e3b61..5aba21e790d 100644
--- a/media-gfx/zbar/zbar-0.20.1-r1.ebuild
+++ b/media-gfx/zbar/zbar-0.20.1-r2.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2019 Gentoo Authors
+# Copyright 1999-2020 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=6
@@ -33,7 +33,11 @@ COMMON_DEPEND="
 	jpeg? ( virtual/jpeg:0[${MULTILIB_USEDEP}] )
 	python? (
 		${PYTHON_DEPS}
-		gtk? ( >=dev-python/pygtk-2[${PYTHON_USEDEP}] )
+		gtk? (
+			$(python_gen_cond_dep '
+				>=dev-python/pygtk-2[${PYTHON_MULTI_USEDEP}]
+			')
+		)
 	)
 	qt5? (
 		dev-qt/qtcore:5

diff --git a/media-gfx/zbar/zbar-0.23.ebuild b/media-gfx/zbar/zbar-0.23-r1.ebuild
similarity index 98%
rename from media-gfx/zbar/zbar-0.23.ebuild
rename to media-gfx/zbar/zbar-0.23-r1.ebuild
index 495dc423d47..87656810dce 100644
--- a/media-gfx/zbar/zbar-0.23.ebuild
+++ b/media-gfx/zbar/zbar-0.23-r1.ebuild
@@ -66,7 +66,9 @@ DEPEND="${COMMON_DEPEND}
 	)
 	test? (
 		${PYTHON_DEPS}
-		dev-python/pillow[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '
+			dev-python/pillow[${PYTHON_MULTI_USEDEP}]
+		')
 	)"
 
 BDEPEND="

[gentoo-commits] repo/gentoo:master commit in: media-gfx/zbar/

[Agostino Sarubbo]

commit:     bb8c1ca931cc56c7c68054d10d0bb35a063b3888
Author:     Agostino Sarubbo <ago <AT> gentoo <DOT> org>
AuthorDate: Fri Feb 21 09:36:58 2020 +0000
Commit:     Agostino Sarubbo <ago <AT> gentoo <DOT> org>
CommitDate: Fri Feb 21 09:36:58 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=bb8c1ca9

media-gfx/zbar: amd64 stable wrt bug #710178

Package-Manager: Portage-2.3.84, Repoman-2.3.20
RepoMan-Options: --include-arches="amd64"
Signed-off-by: Agostino Sarubbo <ago <AT> gentoo.org>

 media-gfx/zbar/zbar-0.23-r1.ebuild | 2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)

diff --git a/media-gfx/zbar/zbar-0.23-r1.ebuild b/media-gfx/zbar/zbar-0.23-r1.ebuild
index 87656810dce..5bdccba179a 100644
--- a/media-gfx/zbar/zbar-0.23-r1.ebuild
+++ b/media-gfx/zbar/zbar-0.23-r1.ebuild
@@ -13,7 +13,7 @@ SRC_URI="https://linuxtv.org/downloads/${PN}/${P}.tar.gz"
 
 LICENSE="LGPL-2.1"
 SLOT="0"
-KEYWORDS="~amd64 ~arm ~x86"
+KEYWORDS="amd64 ~arm ~x86"
 
 IUSE="dbus graphicsmagick gtk +imagemagick introspection java jpeg python qt5 static-libs test +threads v4l X xv"
 REQUIRED_USE="

[gentoo-commits] repo/gentoo:master commit in: media-gfx/zbar/

[Agostino Sarubbo]

commit:     43346056916f99b312d6966be8c580263d260bb9
Author:     Agostino Sarubbo <ago <AT> gentoo <DOT> org>
AuthorDate: Mon Feb 24 16:25:00 2020 +0000
Commit:     Agostino Sarubbo <ago <AT> gentoo <DOT> org>
CommitDate: Mon Feb 24 16:25:00 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=43346056

media-gfx/zbar: x86 stable wrt bug #710178

Package-Manager: Portage-2.3.84, Repoman-2.3.20
RepoMan-Options: --include-arches="x86"
Signed-off-by: Agostino Sarubbo <ago <AT> gentoo.org>

 media-gfx/zbar/zbar-0.23-r1.ebuild | 2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)

diff --git a/media-gfx/zbar/zbar-0.23-r1.ebuild b/media-gfx/zbar/zbar-0.23-r1.ebuild
index 5bdccba179a..015ed0d88df 100644
--- a/media-gfx/zbar/zbar-0.23-r1.ebuild
+++ b/media-gfx/zbar/zbar-0.23-r1.ebuild
@@ -13,7 +13,7 @@ SRC_URI="https://linuxtv.org/downloads/${PN}/${P}.tar.gz"
 
 LICENSE="LGPL-2.1"
 SLOT="0"
-KEYWORDS="amd64 ~arm ~x86"
+KEYWORDS="amd64 ~arm x86"
 
 IUSE="dbus graphicsmagick gtk +imagemagick introspection java jpeg python qt5 static-libs test +threads v4l X xv"
 REQUIRED_USE="

[gentoo-commits] repo/gentoo:master commit in: media-gfx/zbar/

[Andreas Sturmlechner]

commit:     25ce6daf5d2bc9c97993d9cb4b6a3bd16ede1ffb
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Mon Feb 24 18:07:08 2020 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Mon Feb 24 18:07:42 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=25ce6daf

media-gfx/zbar: Drop 0.20.1-r2

Bug: https://bugs.gentoo.org/689406
Package-Manager: Portage-2.3.89, Repoman-2.3.20
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 media-gfx/zbar/Manifest              |   1 -
 media-gfx/zbar/zbar-0.20.1-r2.ebuild | 168 -----------------------------------
 2 files changed, 169 deletions(-)

diff --git a/media-gfx/zbar/Manifest b/media-gfx/zbar/Manifest
index 8d5d753531a..3da8925c591 100644
--- a/media-gfx/zbar/Manifest
+++ b/media-gfx/zbar/Manifest
@@ -1,2 +1 @@
-DIST zbar-0.20.1.tar.gz 555199 BLAKE2B f224a2207fa0603da4cc3a0e1d05bc73f3cf0cc9d13c26b3b801d3418f4f6a001b52e468b721552af61f4c8d7357934abd0560c24d3b233107785c69cfe14753 SHA512 21ad9d8fcdecb41bd4b8979366ab8ec6e8eac815f52270b0dc72ce6a126ccef933d048ce8bbe28f46ada5defadf85ba8c97c5c1870c9560a9dab28c585dfaf42
 DIST zbar-0.23.tar.gz 1301948 BLAKE2B dd74ce44bcb10f8a7cf180b982e5bd82f1f5674540931377d207ab730bb2d080fe222bfc42d4a3d70895ad53b78638e73c2294018b80d30dc28f7e6ecc14c761 SHA512 9737f9dca42c29f92aa1eca5c0808da34f1d16c88c65241c9e3984c487e502f398437e7a707a1edd2c440f784db537ba33ea4008a2d1c1caaf5eea6431b1400b

diff --git a/media-gfx/zbar/zbar-0.20.1-r2.ebuild b/media-gfx/zbar/zbar-0.20.1-r2.ebuild
deleted file mode 100644
index 5aba21e790d..00000000000
--- a/media-gfx/zbar/zbar-0.20.1-r2.ebuild
+++ /dev/null
@@ -1,168 +0,0 @@
-# Copyright 1999-2020 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-PYTHON_COMPAT=( python2_7 )
-
-inherit autotools flag-o-matic java-pkg-opt-2 multilib-minimal python-single-r1 virtualx
-
-DESCRIPTION="Library and tools for reading barcodes from images or video"
-HOMEPAGE="https://github.com/mchehab/zbar"
-SRC_URI="https://linuxtv.org/downloads/${PN}/${P}.tar.gz"
-
-LICENSE="LGPL-2.1"
-SLOT="0"
-KEYWORDS="amd64 ~arm x86"
-
-IUSE="graphicsmagick gtk imagemagick java jpeg python qt5 static-libs test +threads v4l X xv"
-RESTRICT="!test? ( test )"
-REQUIRED_USE="
-	python? ( ${PYTHON_REQUIRED_USE} )
-	test? ( X ${PYTHON_REQUIRED_USE} )
-"
-
-COMMON_DEPEND="
-	gtk? (
-		dev-libs/glib:2[${MULTILIB_USEDEP}]
-		x11-libs/gtk+:2[${MULTILIB_USEDEP}]
-	)
-	imagemagick? (
-		!graphicsmagick? ( media-gfx/imagemagick:= )
-		graphicsmagick? ( media-gfx/graphicsmagick:= )
-	)
-	jpeg? ( virtual/jpeg:0[${MULTILIB_USEDEP}] )
-	python? (
-		${PYTHON_DEPS}
-		gtk? (
-			$(python_gen_cond_dep '
-				>=dev-python/pygtk-2[${PYTHON_MULTI_USEDEP}]
-			')
-		)
-	)
-	qt5? (
-		dev-qt/qtcore:5
-		dev-qt/qtgui:5
-		dev-qt/qtwidgets:5
-		dev-qt/qtx11extras:5
-	)
-	v4l? ( media-libs/libv4l:0= )
-	X? (
-		x11-libs/libX11[${MULTILIB_USEDEP}]
-		x11-libs/libXext[${MULTILIB_USEDEP}]
-		xv? ( x11-libs/libXv[${MULTILIB_USEDEP}] )
-	)
-"
-RDEPEND="${COMMON_DEPEND}
-	java? ( >=virtual/jre-1.8 )
-"
-DEPEND="${COMMON_DEPEND}
-	sys-devel/gettext
-	virtual/pkgconfig
-	gtk? ( dev-util/glib-utils )
-	java? (
-		>=virtual/jdk-1.8
-		test? (
-			dev-java/junit:4
-			dev-java/hamcrest-core:1.3
-		)
-	)
-	test? ( ${PYTHON_DEPS} )
-"
-
-PATCHES=( "${FILESDIR}"/${PN}-0.10-errors.patch )
-
-pkg_setup() {
-	if use python || use test; then
-		python-single-r1_pkg_setup
-	fi
-	java-pkg-opt-2_pkg_setup
-}
-
-src_prepare() {
-	default
-
-	if has_version '>=media-gfx/imagemagick-7.0.1.0' ; then
-		eapply "${FILESDIR}/${PN}-0.10_p20121015-ImageMagick-7.patch"
-	fi
-
-	use python && python_fix_shebang examples/upcrpc.py test/*.py
-	java-pkg-opt-2_src_prepare
-
-	sed -e '/AM_INIT_AUTOMAKE/s: -Werror : :' \
-		-e '/^AM_CFLAGS=/s: -Werror::' \
-		-i configure.ac || die
-	sed "s|javadir = \$(pkgdatadir)|javadir = /usr/$(get_libdir)/zbar|" \
-		-i java/Makefile.am || die
-	eautoreconf
-}
-
-multilib_src_configure() {
-	append-cppflags -DNDEBUG
-
-	local myeconfargs=(
-		$(use_with gtk)
-		$(multilib_native_use_with graphicsmagick graphicsmagick)
-		$(multilib_native_use_with imagemagick)
-		$(multilib_native_use_with java)
-		$(use_with jpeg)
-		$(multilib_native_use_with python python2)
-		$(use_enable static-libs static)
-		$(use_enable threads pthread)
-		$(use_enable v4l video)
-		$(use_with X x)
-		$(use_with X xshm)
-		$(use_with xv xv)
-	)
-
-	if multilib_is_native_abi; then
-		if use java; then
-			export JAVACFLAGS="$(java-pkg_javac-args)"
-			export JAVA_CFLAGS="$(java-pkg_get-jni-cflags)"
-			if use test ; then # bug 629078
-				java-pkg_append_ CLASSPATH .
-				java-pkg_append_ CLASSPATH $(java-pkg_getjar --build-only junit-4 junit.jar)
-				java-pkg_append_ CLASSPATH $(java-pkg_getjar --build-only hamcrest-core-1.3 hamcrest-core.jar)
-			fi
-		fi
-		if use qt5; then
-			myeconfargs+=(
-				$(use_with qt5 qt)
-				$(use_with qt5)
-			)
-		else
-			myeconfargs+=( --without-qt )
-		fi
-	else
-			myeconfargs+=( --without-qt )
-	fi
-
-	ECONF_SOURCE=${S} \
-		econf "${myeconfargs[@]}"
-
-	# work around out-of-source build issues for multilib systems
-	# https://bugs.gentoo.org/672184
-	mkdir gtk pygtk qt test zbarcam || die
-}
-
-src_test() {
-	virtx multilib-minimal_src_test
-}
-
-src_install() {
-	if use qt5; then
-		local MULTILIB_WRAPPED_HEADERS=(
-			/usr/include/zbar/QZBar.h
-			/usr/include/zbar/QZBarImage.h
-		)
-	fi
-	multilib-minimal_src_install
-}
-
-multilib_src_install_all() {
-	einstalldocs
-	find "${D}" -name '*.la' -delete || die
-}
-
-pkg_preinst() {
-	java-pkg-opt-2_pkg_preinst
-}

[gentoo-commits] repo/gentoo:master commit in: media-gfx/zbar/

[Joonas Niilola]

commit:     7da97a920351fe66ee3fad7264817341342334e6
Author:     Yury Martynov <email <AT> linxon <DOT> ru>
AuthorDate: Sun May 10 05:47:41 2020 +0000
Commit:     Joonas Niilola <juippis <AT> gentoo <DOT> org>
CommitDate: Sun May 17 16:41:51 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=7da97a92

media-gfx/zbar: 0.23.1 configure fails with /bin/sh != bash

Closes: https://bugs.gentoo.org/721370
Package-Manager: Portage-2.3.89, Repoman-2.3.20
Signed-off-by: Yury Martynov <email <AT> linxon.ru>
Closes: https://github.com/gentoo/gentoo/pull/15735
Signed-off-by: Joonas Niilola <juippis <AT> gentoo.org>

 media-gfx/zbar/zbar-0.23.1.ebuild | 2 ++
 1 file changed, 2 insertions(+)

diff --git a/media-gfx/zbar/zbar-0.23.1.ebuild b/media-gfx/zbar/zbar-0.23.1.ebuild
index c284e6b7e98..79c9d2c02b8 100644
--- a/media-gfx/zbar/zbar-0.23.1.ebuild
+++ b/media-gfx/zbar/zbar-0.23.1.ebuild
@@ -193,6 +193,8 @@ multilib_src_configure() {
 		use test && myeconfargs+=( --without-zbarimg-tests )
 	fi
 
+	# use bash (bug 721370)
+	CONFIG_SHELL='/bin/bash' \
 	ECONF_SOURCE="${S}" \
 		econf "${myeconfargs[@]}"
 

[gentoo-commits] repo/gentoo:master commit in: media-gfx/zbar/

[Sam James]

commit:     fddfe3a1fe7007115f15b198e3bf61b90e42afcf
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Sun Dec 13 10:34:46 2020 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sun Dec 13 10:34:56 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=fddfe3a1

media-gfx/zbar: arm64 keyworded (bug #759160)

Package-Manager: Portage-3.0.9, Repoman-3.0.2
Signed-off-by: Sam James <sam <AT> gentoo.org>

 media-gfx/zbar/zbar-0.23.1.ebuild | 2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)

diff --git a/media-gfx/zbar/zbar-0.23.1.ebuild b/media-gfx/zbar/zbar-0.23.1.ebuild
index 79c9d2c02b8..23cc7fc6254 100644
--- a/media-gfx/zbar/zbar-0.23.1.ebuild
+++ b/media-gfx/zbar/zbar-0.23.1.ebuild
@@ -13,7 +13,7 @@ SRC_URI="https://github.com/mchehab/zbar/archive/${PV}.tar.gz -> ${P}.tar.gz"
 
 LICENSE="LGPL-2.1"
 SLOT="0"
-KEYWORDS="~amd64 ~arm ~x86"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
 
 IUSE="dbus graphicsmagick gtk +imagemagick introspection java jpeg nls python qt5 static-libs test +threads v4l X xv"
 REQUIRED_USE="

[gentoo-commits] repo/gentoo:master commit in: media-gfx/zbar/

[David Seifert]

commit:     7b77f9a1a893dc1b2e15c708201cf76c645f88dc
Author:     David Seifert <soap <AT> gentoo <DOT> org>
AuthorDate: Sun Feb 21 12:13:53 2021 +0000
Commit:     David Seifert <soap <AT> gentoo <DOT> org>
CommitDate: Sun Feb 21 12:13:53 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=7b77f9a1

media-gfx/zbar: Add python 3.9

Package-Manager: Portage-3.0.14, Repoman-3.0.2
Signed-off-by: David Seifert <soap <AT> gentoo.org>

 media-gfx/zbar/zbar-0.23.1.ebuild | 4 ++--
 1 file changed, 2 insertions(+), 2 deletions(-)

diff --git a/media-gfx/zbar/zbar-0.23.1.ebuild b/media-gfx/zbar/zbar-0.23.1.ebuild
index 6c1c8269865..bb80d1bc91b 100644
--- a/media-gfx/zbar/zbar-0.23.1.ebuild
+++ b/media-gfx/zbar/zbar-0.23.1.ebuild
@@ -1,9 +1,9 @@
-# Copyright 1999-2020 Gentoo Authors
+# Copyright 1999-2021 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
 
-PYTHON_COMPAT=( python3_{7,8} )
+PYTHON_COMPAT=( python3_{7..9} )
 
 inherit autotools flag-o-matic java-pkg-opt-2 multilib-minimal python-single-r1 virtualx
 

[gentoo-commits] repo/gentoo:master commit in: media-gfx/zbar/

[Sam James]

commit:     ca57dc6d99bcb3cd0e1f3883143641f177bf6593
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Sun Feb 21 20:23:25 2021 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sun Feb 21 20:23:25 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ca57dc6d

media-gfx/zbar: Stabilize 0.23.1 x86, #771903

Signed-off-by: Sam James <sam <AT> gentoo.org>

 media-gfx/zbar/zbar-0.23.1.ebuild | 2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)

diff --git a/media-gfx/zbar/zbar-0.23.1.ebuild b/media-gfx/zbar/zbar-0.23.1.ebuild
index bb80d1bc91b..62ce06989f7 100644
--- a/media-gfx/zbar/zbar-0.23.1.ebuild
+++ b/media-gfx/zbar/zbar-0.23.1.ebuild
@@ -13,7 +13,7 @@ SRC_URI="https://github.com/mchehab/zbar/archive/${PV}.tar.gz -> ${P}.tar.gz"
 
 LICENSE="LGPL-2.1"
 SLOT="0"
-KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+KEYWORDS="~amd64 ~arm ~arm64 x86"
 
 IUSE="dbus graphicsmagick gtk +imagemagick introspection java jpeg nls python qt5 static-libs test +threads v4l X xv"
 REQUIRED_USE="

[gentoo-commits] repo/gentoo:master commit in: media-gfx/zbar/

[Sam James]

commit:     816fd834f458b369039c1cf360033e461aca51a0
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Sun Feb 21 20:23:50 2021 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sun Feb 21 20:23:50 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=816fd834

media-gfx/zbar: Stabilize 0.23.1 amd64, #771903

Signed-off-by: Sam James <sam <AT> gentoo.org>

 media-gfx/zbar/zbar-0.23.1.ebuild | 2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)

diff --git a/media-gfx/zbar/zbar-0.23.1.ebuild b/media-gfx/zbar/zbar-0.23.1.ebuild
index 62ce06989f7..d5805ede1de 100644
--- a/media-gfx/zbar/zbar-0.23.1.ebuild
+++ b/media-gfx/zbar/zbar-0.23.1.ebuild
@@ -13,7 +13,7 @@ SRC_URI="https://github.com/mchehab/zbar/archive/${PV}.tar.gz -> ${P}.tar.gz"
 
 LICENSE="LGPL-2.1"
 SLOT="0"
-KEYWORDS="~amd64 ~arm ~arm64 x86"
+KEYWORDS="amd64 ~arm ~arm64 x86"
 
 IUSE="dbus graphicsmagick gtk +imagemagick introspection java jpeg nls python qt5 static-libs test +threads v4l X xv"
 REQUIRED_USE="

[gentoo-commits] repo/gentoo:master commit in: media-gfx/zbar/

[Sam James]

commit:     de0de64dcbef3f6751c06f1ca33dca9761d6566f
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Tue Apr  6 21:15:05 2021 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Tue Apr  6 21:15:05 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=de0de64d

media-gfx/zbar: retire proxied maintainer

Signed-off-by: Sam James <sam <AT> gentoo.org>

 media-gfx/zbar/metadata.xml | 9 +--------
 1 file changed, 1 insertion(+), 8 deletions(-)

diff --git a/media-gfx/zbar/metadata.xml b/media-gfx/zbar/metadata.xml
index 14483e82c58..21d625e4e4c 100644
--- a/media-gfx/zbar/metadata.xml
+++ b/media-gfx/zbar/metadata.xml
@@ -1,14 +1,7 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
-	<maintainer type="person" proxied="yes">
-		<email>email@linxon.ru</email>
-		<name>Yury Martynov</name>
-	</maintainer>
-	<maintainer type="project" proxied="proxy">
-		<email>proxy-maint@gentoo.org</email>
-		<name>Proxy Maintainers</name>
-	</maintainer>
+	<!-- maintainer-needed -->
 	<upstream>
 		<remote-id type="sourceforge">zbar</remote-id>
 		<remote-id type="github">mchehab/zbar</remote-id>

[gentoo-commits] repo/gentoo:master commit in: media-gfx/zbar/

[Jakov Smolić]

commit:     cc4675328d686969e8c7a9a8dacfc7b39880e81c
Author:     Jakov Smolić <jsmolic <AT> gentoo <DOT> org>
AuthorDate: Mon Apr 11 06:34:05 2022 +0000
Commit:     Jakov Smolić <jsmolic <AT> gentoo <DOT> org>
CommitDate: Mon Apr 11 06:34:05 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=cc467532

media-gfx/zbar: Stabilize 0.23.90 amd64, #836843

Signed-off-by: Jakov Smolić <jsmolic <AT> gentoo.org>

 media-gfx/zbar/zbar-0.23.90.ebuild | 2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)

diff --git a/media-gfx/zbar/zbar-0.23.90.ebuild b/media-gfx/zbar/zbar-0.23.90.ebuild
index 91cdcabb9f33..e2cea8bdc500 100644
--- a/media-gfx/zbar/zbar-0.23.90.ebuild
+++ b/media-gfx/zbar/zbar-0.23.90.ebuild
@@ -12,7 +12,7 @@ SRC_URI="https://github.com/mchehab/zbar/archive/${PV}.tar.gz -> ${P}.tar.gz"
 
 LICENSE="LGPL-2.1"
 SLOT="0"
-KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+KEYWORDS="amd64 ~arm ~arm64 ~x86"
 IUSE="dbus graphicsmagick gtk +imagemagick introspection java jpeg nls python qt5 static-libs test +threads v4l X xv"
 
 REQUIRED_USE="

[gentoo-commits] repo/gentoo:master commit in: media-gfx/zbar/

[Jakov Smolić]

commit:     30436f2c8043874307488ce0b4de7de0020171ea
Author:     Jakov Smolić <jsmolic <AT> gentoo <DOT> org>
AuthorDate: Mon Apr 11 06:34:31 2022 +0000
Commit:     Jakov Smolić <jsmolic <AT> gentoo <DOT> org>
CommitDate: Mon Apr 11 06:34:31 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=30436f2c

media-gfx/zbar: Stabilize 0.23.90 x86, #836843

Signed-off-by: Jakov Smolić <jsmolic <AT> gentoo.org>

 media-gfx/zbar/zbar-0.23.90.ebuild | 2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)

diff --git a/media-gfx/zbar/zbar-0.23.90.ebuild b/media-gfx/zbar/zbar-0.23.90.ebuild
index e2cea8bdc500..46b85c382176 100644
--- a/media-gfx/zbar/zbar-0.23.90.ebuild
+++ b/media-gfx/zbar/zbar-0.23.90.ebuild
@@ -12,7 +12,7 @@ SRC_URI="https://github.com/mchehab/zbar/archive/${PV}.tar.gz -> ${P}.tar.gz"
 
 LICENSE="LGPL-2.1"
 SLOT="0"
-KEYWORDS="amd64 ~arm ~arm64 ~x86"
+KEYWORDS="amd64 ~arm ~arm64 x86"
 IUSE="dbus graphicsmagick gtk +imagemagick introspection java jpeg nls python qt5 static-libs test +threads v4l X xv"
 
 REQUIRED_USE="

[gentoo-commits] repo/gentoo:master commit in: media-gfx/zbar/

[Joonas Niilola]

commit:     48c9cdacf049a7af3a8ead57312188e813b47108
Author:     Joonas Niilola <juippis <AT> gentoo <DOT> org>
AuthorDate: Tue Aug  2 10:12:21 2022 +0000
Commit:     Joonas Niilola <juippis <AT> gentoo <DOT> org>
CommitDate: Tue Aug  2 10:13:56 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=48c9cdac

media-gfx/zbar: fix configure logic for imagemagick<->graphicsmagick

 - tested on stable amd64.

Closes: https://bugs.gentoo.org/784362
Signed-off-by: Joonas Niilola <juippis <AT> gentoo.org>

 media-gfx/zbar/zbar-0.23.90.ebuild | 5 +++--
 1 file changed, 3 insertions(+), 2 deletions(-)

diff --git a/media-gfx/zbar/zbar-0.23.90.ebuild b/media-gfx/zbar/zbar-0.23.90.ebuild
index 46b85c382176..3389a83eaacd 100644
--- a/media-gfx/zbar/zbar-0.23.90.ebuild
+++ b/media-gfx/zbar/zbar-0.23.90.ebuild
@@ -72,6 +72,7 @@ DEPEND="${COMMON_DEPEND}
 
 BDEPEND="
 	app-text/xmlto
+	sys-devel/gettext
 	virtual/pkgconfig
 	gtk? ( dev-util/glib-utils )
 	nls? (
@@ -146,12 +147,12 @@ multilib_src_configure() {
 
 	if multilib_is_native_abi; then
 		# both must be enabled to use GraphicsMagick
-		if use graphicsmagick; then
+		if use imagemagick && use graphicsmagick; then
 			myeconfargs+=(
 				--with-graphicsmagick
 				--without-imagemagick
 			)
-		elif use imagemagick; then
+		elif ! use graphicsmagick && use imagemagick; then
 			myeconfargs+=(
 				--with-imagemagick
 				--without-graphicsmagick

[gentoo-commits] repo/gentoo:master commit in: media-gfx/zbar/

[Arthur Zamarin]

commit:     74d16a5b1ff8e680bd85cca58369ca98d075c988
Author:     Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
AuthorDate: Tue Apr 11 19:05:41 2023 +0000
Commit:     Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
CommitDate: Tue Apr 11 19:05:41 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=74d16a5b

media-gfx/zbar: Stabilize 0.23.92 amd64, #904188

Signed-off-by: Arthur Zamarin <arthurzam <AT> gentoo.org>

 media-gfx/zbar/zbar-0.23.92.ebuild | 2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)

diff --git a/media-gfx/zbar/zbar-0.23.92.ebuild b/media-gfx/zbar/zbar-0.23.92.ebuild
index f2233c1e697c..47c378392f9c 100644
--- a/media-gfx/zbar/zbar-0.23.92.ebuild
+++ b/media-gfx/zbar/zbar-0.23.92.ebuild
@@ -12,7 +12,7 @@ SRC_URI="https://github.com/mchehab/zbar/archive/${PV}.tar.gz -> ${P}.tar.gz"
 
 LICENSE="LGPL-2.1"
 SLOT="0"
-KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+KEYWORDS="amd64 ~arm ~arm64 ~x86"
 IUSE="dbus graphicsmagick gtk +imagemagick introspection java jpeg nls python qt5 static-libs test +threads v4l X xv"
 
 REQUIRED_USE="

[gentoo-commits] repo/gentoo:master commit in: media-gfx/zbar/

[Sam James]

commit:     97fc4383a8e3cc625b7209b7043a1a302b69289a
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Wed Apr 12 01:49:52 2023 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Wed Apr 12 01:49:52 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=97fc4383

media-gfx/zbar: Stabilize 0.23.92 x86, #904188

Signed-off-by: Sam James <sam <AT> gentoo.org>

 media-gfx/zbar/zbar-0.23.92.ebuild | 2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)

diff --git a/media-gfx/zbar/zbar-0.23.92.ebuild b/media-gfx/zbar/zbar-0.23.92.ebuild
index 47c378392f9c..5b8d7360950c 100644
--- a/media-gfx/zbar/zbar-0.23.92.ebuild
+++ b/media-gfx/zbar/zbar-0.23.92.ebuild
@@ -12,7 +12,7 @@ SRC_URI="https://github.com/mchehab/zbar/archive/${PV}.tar.gz -> ${P}.tar.gz"
 
 LICENSE="LGPL-2.1"
 SLOT="0"
-KEYWORDS="amd64 ~arm ~arm64 ~x86"
+KEYWORDS="amd64 ~arm ~arm64 x86"
 IUSE="dbus graphicsmagick gtk +imagemagick introspection java jpeg nls python qt5 static-libs test +threads v4l X xv"
 
 REQUIRED_USE="

[gentoo-commits] repo/gentoo:master commit in: media-gfx/zbar/

[Arthur Zamarin]

commit:     235c87a514ce6b92326ae084c749dbc9c86b726c
Author:     Volkmar W. Pogatzki <gentoo <AT> pogatzki <DOT> net>
AuthorDate: Fri Sep 29 11:10:39 2023 +0000
Commit:     Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
CommitDate: Fri Sep 29 13:04:12 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=235c87a5

media-gfx/zbar: drop 0.23.90

Signed-off-by: Volkmar W. Pogatzki <gentoo <AT> pogatzki.net>
Closes: https://github.com/gentoo/gentoo/pull/33120
Signed-off-by: Arthur Zamarin <arthurzam <AT> gentoo.org>

 media-gfx/zbar/Manifest            |   1 -
 media-gfx/zbar/zbar-0.23.90.ebuild | 229 -------------------------------------
 2 files changed, 230 deletions(-)

diff --git a/media-gfx/zbar/Manifest b/media-gfx/zbar/Manifest
index 3cac58789899..bad02d9095d4 100644
--- a/media-gfx/zbar/Manifest
+++ b/media-gfx/zbar/Manifest
@@ -1,2 +1 @@
-DIST zbar-0.23.90.tar.gz 1005314 BLAKE2B 5d0c193509602dfb55741b421e1d28f1424ecec50aa3be584912544a587922c053284c41cf14ff0b4824095d0d376381ed055e7faf9ff394bd8d44fd9ed2971d SHA512 d73d71873bec68ee021997512a9edbd223f5f5fe43c66c4dd3502224ba6009be2e5e1714766cb8e1056244673e87e0939ed0319116f61d7371b5ab79fb5e04eb
 DIST zbar-0.23.92.tar.gz 1005358 BLAKE2B 97af3c399333abfcd64e45e6c4f38e5da6ed1540447f35f0efe9bc0fb8d296d80c964452afa29d26d22bddd8de31bc3ca6582db38afe8416e9480f11b939e040 SHA512 cae47fb199173fc1c052984865ca0e6aeab330bd6d77506a0937994d459deb4419a3e54e2dcd2e9830ffb8acf14f29e22e0a6becc9e4cfe19b07dad1babe9513

diff --git a/media-gfx/zbar/zbar-0.23.90.ebuild b/media-gfx/zbar/zbar-0.23.90.ebuild
deleted file mode 100644
index 68bd3dce3e8e..000000000000
--- a/media-gfx/zbar/zbar-0.23.90.ebuild
+++ /dev/null
@@ -1,229 +0,0 @@
-# Copyright 1999-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-PYTHON_COMPAT=( python3_{9..10} )
-inherit autotools flag-o-matic java-pkg-opt-2 multilib-minimal python-single-r1 qmake-utils virtualx
-
-DESCRIPTION="Library and tools for reading barcodes from images or video"
-HOMEPAGE="https://github.com/mchehab/zbar"
-SRC_URI="https://github.com/mchehab/zbar/archive/${PV}.tar.gz -> ${P}.tar.gz"
-
-LICENSE="LGPL-2.1"
-SLOT="0"
-KEYWORDS="amd64 ~arm ~arm64 x86"
-IUSE="dbus graphicsmagick gtk +imagemagick introspection java jpeg nls python qt5 static-libs test +threads v4l X xv"
-
-REQUIRED_USE="
-	introspection? ( gtk )
-	python? ( ${PYTHON_REQUIRED_USE} )
-	test? (
-		${PYTHON_REQUIRED_USE}
-		X? ( imagemagick )
-	)
-	xv? ( X )"
-
-RESTRICT="!test? ( test )"
-
-COMMON_DEPEND="
-	dbus? ( sys-apps/dbus[${MULTILIB_USEDEP}] )
-	gtk? (
-		dev-libs/glib:2[${MULTILIB_USEDEP}]
-		x11-libs/gtk+:3[${MULTILIB_USEDEP}]
-		introspection? ( dev-libs/gobject-introspection )
-	)
-	imagemagick? (
-		!graphicsmagick? ( media-gfx/imagemagick:=[png,jpeg?] )
-		graphicsmagick? ( media-gfx/graphicsmagick:=[png,jpeg?] )
-	)
-	jpeg? ( virtual/jpeg:0[${MULTILIB_USEDEP}] )
-	python? ( ${PYTHON_DEPS} )
-	qt5? (
-		dev-qt/qtcore:5
-		dev-qt/qtgui:5
-		dev-qt/qtwidgets:5
-		dev-qt/qtx11extras:5
-	)
-	v4l? ( media-libs/libv4l:0=[${MULTILIB_USEDEP}] )
-	X? (
-		x11-libs/libX11[${MULTILIB_USEDEP}]
-		x11-libs/libXext[${MULTILIB_USEDEP}]
-		xv? ( x11-libs/libXv[${MULTILIB_USEDEP}] )
-	)"
-
-RDEPEND="${COMMON_DEPEND}
-	java? ( >=virtual/jre-1.8 )"
-
-DEPEND="${COMMON_DEPEND}
-	java? (
-		>=virtual/jdk-1.8
-		test? (
-			dev-java/hamcrest-core:1.3
-			dev-java/junit:4
-		)
-	)
-	test? (
-		${PYTHON_DEPS}
-		$(python_gen_cond_dep '
-			dev-python/pillow[${PYTHON_USEDEP}]
-		')
-	)"
-
-BDEPEND="
-	app-text/xmlto
-	sys-devel/gettext
-	virtual/pkgconfig
-	gtk? ( dev-util/glib-utils )
-	nls? (
-		sys-devel/gettext
-		virtual/libiconv
-	)"
-
-DOCS=( README.md NEWS.md TODO.md HACKING.md TODO.md ChangeLog )
-
-PATCHES=(
-	# git master
-	"${FILESDIR}/${P}-fix-gtk-default.patch"
-	# TODO: upstream?
-	"${FILESDIR}/${PN}-0.23_fix_python_detect.patch"
-	"${FILESDIR}/${P}-fix-unittest.patch"
-	"${FILESDIR}/${P}-fix-qt5x11extras-detect.patch"
-)
-
-pkg_setup() {
-	if use python || use test; then
-		python-single-r1_pkg_setup
-	fi
-	use java && java-pkg-opt-2_pkg_setup
-}
-
-src_prepare() {
-	default
-
-	if use python || use test; then
-		if use test; then
-			# make tests happy
-			# because one of the test requires loadable py module from the current ${BUILD_DIR}
-			sed -e "s|PYTHONPATH=@abs_top_srcdir@|PYTHONPATH=@builddir@|g" \
-				-i test/Makefile.am.inc || die
-		fi
-
-		python_fix_shebang \
-			examples/*.py \
-			test/{test_python,barcodetest}.py # test_pygtk.py — py2 only
-	fi
-
-	if use java; then
-		java-pkg-opt-2_src_prepare
-		sed -e "s|javadir = \$(pkgdatadir)|javadir = /usr/$(get_libdir)/zbar|" \
-			-i java/Makefile.am || die
-	fi
-
-	# do not install {LICENSE,INSTALL,etc} doc files with 'make install' (use DOCS=() instead)
-	sed -e "s|^dist_doc_DATA =\(.*\)|dist_doc_DATA =|" -i Makefile.am || die
-
-	eautoreconf
-}
-
-multilib_src_configure() {
-	append-cppflags -DNDEBUG
-
-	local myeconfargs=(
-		$(use_with dbus)
-		$(use_with gtk gtk gtk3) # avoid 'auto'
-		$(use_with jpeg)
-		$(multilib_native_use_with introspection gir)
-		$(multilib_native_use_with java)
-		$(multilib_native_use_with python python auto)
-		$(use_enable nls)
-		$(use_enable static-libs static)
-		$(use_enable threads pthread)
-		$(use_enable v4l video)
-		$(use_with X x)
-		$(use_with X xshm)
-		$(use_with xv xv)
-	)
-
-	if multilib_is_native_abi; then
-		# both must be enabled to use GraphicsMagick
-		if use imagemagick && use graphicsmagick; then
-			myeconfargs+=(
-				--with-graphicsmagick
-				--without-imagemagick
-			)
-		elif ! use graphicsmagick && use imagemagick; then
-			myeconfargs+=(
-				--with-imagemagick
-				--without-graphicsmagick
-			)
-		else
-			myeconfargs+=(
-				--without-imagemagick
-				--without-graphicsmagick
-			)
-		fi
-
-		if use java; then
-			export JAVACFLAGS="$(java-pkg_javac-args)"
-			append-cflags "$(java-pkg_get-jni-cflags)"
-			if use test; then # bug 629078
-				myeconfargs+=( --with-java-unit )
-				java-pkg_append_ CLASSPATH .
-				java-pkg_append_ CLASSPATH $(java-pkg_getjar --build-only junit-4 junit.jar)
-				java-pkg_append_ CLASSPATH $(java-pkg_getjar --build-only hamcrest-core-1.3 hamcrest-core.jar)
-			fi
-		fi
-
-		if use qt5; then
-			myeconfargs+=(
-				--with-qt
-				--with-qt5
-			)
-		else
-			myeconfargs+=( --without-qt )
-		fi
-	else
-		myeconfargs+=(
-			--without-graphicsmagick
-			--without-imagemagick
-			--without-qt
-		)
-
-		# zbarimg tests with native abi only
-		# (this option from the patch above, stay up to date)
-		use test && myeconfargs+=( --without-zbarimg-tests )
-	fi
-
-	# use bash (bug 721370)
-	CONFIG_SHELL='/bin/bash' \
-	ECONF_SOURCE="${S}" \
-	MOC="$(qt5_get_bindir)"/moc \
-		econf "${myeconfargs[@]}"
-
-	# work around out-of-source build issues for multilib systems (bug 672184)
-	mkdir qt zbarcam || die
-}
-
-src_test() {
-	virtx multilib-minimal_src_test
-}
-
-src_install() {
-	if use qt5; then
-		local MULTILIB_WRAPPED_HEADERS=(
-			/usr/include/zbar/QZBar.h
-			/usr/include/zbar/QZBarImage.h
-		)
-	fi
-	multilib-minimal_src_install
-}
-
-multilib_src_install_all() {
-	einstalldocs
-	find "${D}" -name '*.la' -delete || die
-}
-
-pkg_preinst() {
-	use java && java-pkg-opt-2_pkg_preinst
-}