[gentoo-commits] repo/gentoo:master commit in: media-plugins/gst-plugins-vaapi/

["Mart Raudsepp" <leio@gentoo.org>]

commit:     e7a791f5f08fde7c77332e2ede6c6920f2faca71
Author:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
AuthorDate: Sun Dec 17 02:00:05 2017 +0000
Commit:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
CommitDate: Sun Dec 17 02:01:33 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e7a791f5

media-plugins/gst-plugins-vaapi: bump to 1.12.4, compatible with x11-libs/libva-2

This version should be compatible with both libva-1.x and libva-2.x
(VA_API_VERSION 0.x.y and 1.x.y).

Closes: https://bugs.gentoo.org/641272
Package-Manager: Portage-2.3.16, Repoman-2.3.6

 media-plugins/gst-plugins-vaapi/Manifest           |  1 +
 .../gst-plugins-vaapi-1.12.4.ebuild                | 61 ++++++++++++++++++++++
 2 files changed, 62 insertions(+)

diff --git a/media-plugins/gst-plugins-vaapi/Manifest b/media-plugins/gst-plugins-vaapi/Manifest
index f276914f977..7108b9ee314 100644
--- a/media-plugins/gst-plugins-vaapi/Manifest
+++ b/media-plugins/gst-plugins-vaapi/Manifest
@@ -1 +1,2 @@
 DIST gstreamer-vaapi-1.12.3.tar.xz 996360 BLAKE2B d34804f278780e073b553542258f865a93e62d48b0cd276fa7fa47e54f03a5484d7ddc61851f75e583dbcc03d6dbfce6a9c8df0e4c1c6174dfaefdcf867ca068 SHA512 c70da985b1c0c5048be8d83ba62622b9064d78193433b897d54824125de3eeabe4f9765ec0a5199a2d9eaa91d0625dfa2b7ef3d8245b23cf57361691d72b1dc4
+DIST gstreamer-vaapi-1.12.4.tar.xz 998844 BLAKE2B e37d6f66054e46e421ffbd4c27362bba0fb2ad57bfccb4891ba85573dec18ca304654336768a519c202bda0e829b80ab75a5708ddfc1dc9751774b4ef783a16d SHA512 2251395f77be8d17837f4b0d38a2271155a5fbd57560fac9334660abb34a4f609dda8d9714bfa8f64395a85d3fa336f7ad1b8e8e7490b5288843fbe3d1dbd7f5

diff --git a/media-plugins/gst-plugins-vaapi/gst-plugins-vaapi-1.12.4.ebuild b/media-plugins/gst-plugins-vaapi/gst-plugins-vaapi-1.12.4.ebuild
new file mode 100644
index 00000000000..2ec75e8e71e
--- /dev/null
+++ b/media-plugins/gst-plugins-vaapi/gst-plugins-vaapi-1.12.4.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit eutils multilib-minimal
+
+MY_PN="gstreamer-vaapi"
+DESCRIPTION="Hardware accelerated video decoding through VA-API plugin for GStreamer"
+HOMEPAGE="https://cgit.freedesktop.org/gstreamer/gstreamer-vaapi"
+SRC_URI="https://gstreamer.freedesktop.org/src/${MY_PN}/${MY_PN}-${PV}.tar.xz"
+
+LICENSE="LGPL-2.1"
+SLOT="1.0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+IUSE="+drm egl opengl wayland +X"
+REQUIRED_USE="|| ( drm opengl wayland X )"
+
+RDEPEND="
+	>=dev-libs/glib-2.40:2[${MULTILIB_USEDEP}]
+	>=media-libs/gstreamer-1.12.0:${SLOT}[${MULTILIB_USEDEP}]
+	>=media-libs/gst-plugins-base-1.12.0:${SLOT}[${MULTILIB_USEDEP}]
+	>=media-libs/gst-plugins-bad-1.12.0:${SLOT}[opengl?,${MULTILIB_USEDEP}]
+	>=x11-libs/libva-1.4.0:=[drm?,X?,opengl?,wayland?,${MULTILIB_USEDEP}]
+	drm? (
+		>=virtual/libudev-208:=[${MULTILIB_USEDEP}]
+		>=x11-libs/libdrm-2.4.46[${MULTILIB_USEDEP}] )
+	egl? (
+		>=media-libs/gst-plugins-bad-1.12.0:${SLOT}[opengl,${MULTILIB_USEDEP}] )
+	opengl? (
+		>=virtual/opengl-7.0-r1[${MULTILIB_USEDEP}]
+		>=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}]
+		>=x11-libs/libXrandr-1.4.2[${MULTILIB_USEDEP}] )
+	wayland? ( >=dev-libs/wayland-1.0.6[${MULTILIB_USEDEP}] )
+	X? (
+		>=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}]
+		>=x11-libs/libXrandr-1.4.2[${MULTILIB_USEDEP}] )
+"
+DEPEND="${RDEPEND}
+	>=dev-util/gtk-doc-am-1.12
+	>=virtual/pkgconfig-0-r1[${MULTILIB_USEDEP}]
+"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+multilib_src_configure() {
+	ECONF_SOURCE=${S} \
+	econf \
+		--disable-static \
+		$(use_enable drm) \
+		$(use_enable egl) \
+		$(use_enable opengl glx) \
+		$(use_enable wayland) \
+		$(use_enable X x11)
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	prune_libtool_files --modules
+}