From mboxrd@z Thu Jan  1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-990488-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
	(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
	(No client certificate requested)
	by finch.gentoo.org (Postfix) with ESMTPS id 32116139083
	for <garchives@archives.gentoo.org>; Fri, 15 Dec 2017 07:04:47 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
	by pigeon.gentoo.org (Postfix) with SMTP id 60137E1091;
	Fri, 15 Dec 2017 07:04:44 +0000 (UTC)
Received: from smtp.gentoo.org (smtp.gentoo.org [140.211.166.183])
	(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
	(No client certificate requested)
	by pigeon.gentoo.org (Postfix) with ESMTPS id 2B1C8E1097
	for <gentoo-commits@lists.gentoo.org>; Fri, 15 Dec 2017 07:04:43 +0000 (UTC)
Received: from oystercatcher.gentoo.org (oystercatcher.gentoo.org [148.251.78.52])
	(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
	(No client certificate requested)
	by smtp.gentoo.org (Postfix) with ESMTPS id B8D8A33BF0F
	for <gentoo-commits@lists.gentoo.org>; Fri, 15 Dec 2017 07:04:42 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
	by oystercatcher.gentoo.org (Postfix) with ESMTP id 5E0AFAE86
	for <gentoo-commits@lists.gentoo.org>; Fri, 15 Dec 2017 07:04:41 +0000 (UTC)
From: "Hans de Graaff" <graaff@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Hans de Graaff" <graaff@gentoo.org>
Message-ID: <1513321453.144561282b6207b18e8d5de8401c4ac881b7db28.graaff@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: dev-lang/ruby/
X-VCS-Repository: repo/gentoo
X-VCS-Files: dev-lang/ruby/Manifest dev-lang/ruby/ruby-2.2.9.ebuild
X-VCS-Directories: dev-lang/ruby/
X-VCS-Committer: graaff
X-VCS-Committer-Name: Hans de Graaff
X-VCS-Revision: 144561282b6207b18e8d5de8401c4ac881b7db28
X-VCS-Branch: master
Date: Fri, 15 Dec 2017 07:04:41 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Archives-Salt: 97994705-a97b-40b3-95ae-274f283f7a1c
X-Archives-Hash: 38a32137bb2de922523d54a0b77d1f8e

commit:     144561282b6207b18e8d5de8401c4ac881b7db28
Author:     Hans de Graaff <graaff <AT> gentoo <DOT> org>
AuthorDate: Fri Dec 15 07:03:49 2017 +0000
Commit:     Hans de Graaff <graaff <AT> gentoo <DOT> org>
CommitDate: Fri Dec 15 07:04:13 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=14456128

dev-lang/ruby: add 2.2.9

Package-Manager: Portage-2.3.13, Repoman-2.3.3

 dev-lang/ruby/Manifest          |   2 +
 dev-lang/ruby/ruby-2.2.9.ebuild | 245 ++++++++++++++++++++++++++++++++++++++++
 2 files changed, 247 insertions(+)

diff --git a/dev-lang/ruby/Manifest b/dev-lang/ruby/Manifest
index b724484caed..51028353a45 100644
--- a/dev-lang/ruby/Manifest
+++ b/dev-lang/ruby/Manifest
@@ -1,6 +1,8 @@
 DIST ruby-2.2.8.tar.xz 10520648 BLAKE2B 96c483786b1a7e0b1483c337a13fe7e07e740bb21b507b518e142dc9ac8cf19ba00c094b4357db4305c645d370d776269145b699ad11429aa56a0de78abfbf83 SHA512 e21004bee537f0c706f4ac9526507b414ddb6a8d721e8fad8d7fe88992a4f048eb5eb79f8d8b8af2a8b331dcfa74b560490218a1acb3532c2cdb4fb4909da3c9
+DIST ruby-2.2.9.tar.xz 10511456 BLAKE2B aeb631c47def96e8dd19e4f7281ef95833d9d0cde0912ffccd341032d2be22d6eebf259b0926f248298a5a290fd4d99b7ec38e29b805c9d77d4f3f4481fc0edb SHA512 c4ef84cd00f72f60d6c168f0726d9d7e9573549c2bbae83893e1a9d5e64fc7938f4c9d50a47147b28b37cbf36263f95e10a810c0797bad941775a48d75a8c933
 DIST ruby-2.3.5.tar.xz 11437868 BLAKE2B db50d7b36b6a8fa5b0b030f56d5d7bfc3c43e21d7255e9db73fed4d42cda1f161457c0f478e865766e2b7ef703335aa5b6bdf0bbc23c26a1cdb0163b75528de0 SHA512 c55e3b71241f505b6bbad78b3bd40235064faae3443ca14b77b6356556caed6a0d055dc2e2cd7ebdb5290ab908e06d2b7d68f72469af5017eda4b29664b0d889
 DIST ruby-2.4.2.tar.xz 10046412 BLAKE2B 33af07ee102367fe811dd3248edc72238bddfc3332f64280b6b36497c7de70bce939127c1efcc965072451ddd60ede98c855fc1fd24be9b12eedc58a21faad5a SHA512 c1d42272fb0d94b693452e703b0ea4942bf59cbd4b08ba83bf039f54be97ebc88511632413da0164970b4cf97bc302bccb88aab48edfa8fa147498e7ee741595
 DIST ruby-patches-2.2.8.tar.bz2 5764 BLAKE2B f50729480a4231db51de7981acb04dafa09d5fde592cf4a824a6fefe8ae3189ab9e82857e7ca41f1bb32dff1c4057ac37badf971c1b8f2981189e13d42dd38d2 SHA512 296387ec7f2ff82ad55f147d8f9568de544403d286ad24bb60aca916215d7ff6e1d6aca5a31c00a1999504989cda2bbd3260cae96c18ba73f9ffdcfd6b2695bd
+DIST ruby-patches-2.2.9.tar.bz2 5764 BLAKE2B f50729480a4231db51de7981acb04dafa09d5fde592cf4a824a6fefe8ae3189ab9e82857e7ca41f1bb32dff1c4057ac37badf971c1b8f2981189e13d42dd38d2 SHA512 296387ec7f2ff82ad55f147d8f9568de544403d286ad24bb60aca916215d7ff6e1d6aca5a31c00a1999504989cda2bbd3260cae96c18ba73f9ffdcfd6b2695bd
 DIST ruby-patches-2.3.5.tar.bz2 3593 BLAKE2B 48aba5d68ad7b648065a3580cb7160470ad308659fa11249afab1efe6482edf3805087f4054762717a89b61da4fd7a50c84ab8e76ba00052fd95d937655dcdba SHA512 eacb7f6787b36c7d848453b29152190a164ebc6882ab509eeb6584e49af4b66a665c4baff4ecf75e5831ae54d47dbc651d6f048918f3327500c429f1f419ed94
 DIST ruby-patches-2.4.2.tar.bz2 3443 BLAKE2B d90cfb496ad8701fccb061fd314a7f2394b251c921f270f17c8335f617e71dacc8e4a2df4e76842b67eb34627e5f5291d8a2723f6dfed53a36ace3abad95a179 SHA512 fb8349c67c72caf10ec12c4b5410194b4df24345446c2e3b6c6176d00727bfe803f4a905ef094a2d52315b6f4c3ce74fb8fbaa2fdf5efe46e6ccb24bf8418b17

diff --git a/dev-lang/ruby/ruby-2.2.9.ebuild b/dev-lang/ruby/ruby-2.2.9.ebuild
new file mode 100644
index 00000000000..bde37ba6f66
--- /dev/null
+++ b/dev-lang/ruby/ruby-2.2.9.ebuild
@@ -0,0 +1,245 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+
+#PATCHSET=1
+
+inherit autotools eutils flag-o-matic multilib versionator
+
+MY_P="${PN}-$(get_version_component_range 1-3)"
+S=${WORKDIR}/${MY_P}
+
+SLOT=$(get_version_component_range 1-2)
+MY_SUFFIX=$(delete_version_separator 1 ${SLOT})
+RUBYVERSION=2.2.0
+
+if [[ -n ${PATCHSET} ]]; then
+	if [[ ${PVR} == ${PV} ]]; then
+		PATCHSET="${PV}-r0.${PATCHSET}"
+	else
+		PATCHSET="${PVR}.${PATCHSET}"
+	fi
+else
+	PATCHSET="${PVR}"
+fi
+
+DESCRIPTION="An object-oriented scripting language"
+HOMEPAGE="http://www.ruby-lang.org/"
+SRC_URI="mirror://ruby/2.2/${MY_P}.tar.xz
+		 https://dev.gentoo.org/~flameeyes/ruby-team/${PN}-patches-${PATCHSET}.tar.bz2"
+
+LICENSE="|| ( Ruby-BSD BSD-2 )"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd"
+IUSE="berkdb debug doc examples gdbm ipv6 jemalloc libressl +rdoc rubytests socks5 ssl tk xemacs ncurses +readline"
+
+RDEPEND="
+	berkdb? ( sys-libs/db:= )
+	gdbm? ( sys-libs/gdbm )
+	jemalloc? ( dev-libs/jemalloc )
+	ssl? (
+		!libressl? ( dev-libs/openssl:0= )
+		libressl? ( dev-libs/libressl )
+	)
+	socks5? ( >=net-proxy/dante-1.1.13 )
+	tk? (
+		dev-lang/tcl:0=[threads]
+		dev-lang/tk:0=[threads]
+	)
+	ncurses? ( sys-libs/ncurses:0= )
+	readline?  ( sys-libs/readline:0= )
+	dev-libs/libyaml
+	virtual/libffi
+	sys-libs/zlib
+	>=app-eselect/eselect-ruby-20141227
+	!<dev-ruby/rdoc-3.9.4
+	!<dev-ruby/rubygems-1.8.10-r1"
+
+DEPEND="${RDEPEND}"
+
+BUNDLED_GEMS="
+	>=dev-ruby/minitest-5.4.3[ruby_targets_ruby22]
+	>=dev-ruby/power_assert-0.2.2[ruby_targets_ruby22]
+	>=dev-ruby/test-unit-3.0.8[ruby_targets_ruby22]
+"
+
+PDEPEND="
+	${BUNDLED_GEMS}
+	virtual/rubygems[ruby_targets_ruby22]
+	>=dev-ruby/json-1.8.1[ruby_targets_ruby22]
+	>=dev-ruby/rake-0.9.6[ruby_targets_ruby22]
+	rdoc? ( >=dev-ruby/rdoc-4.0.1[ruby_targets_ruby22] )
+	xemacs? ( app-xemacs/ruby-modes )"
+
+src_prepare() {
+	EPATCH_FORCE="yes" EPATCH_SUFFIX="patch" \
+		epatch "${WORKDIR}/patches"
+
+	# We can no longer unbundle all of rake because rubygems now depends
+	# on this. We leave the actual rake code around to bootstrap
+	# rubygems, but remove the bits that would cause a file collision.
+	einfo "Unbundling gems..."
+	cd "$S"
+	rm -rf \
+		{bin,lib}/rake lib/rake.rb man/rake.1 \
+		bin/gem || die "removal failed"
+	# Remove bundled gems that we will install via PDEPEND, bug
+	# 539700. Use explicit version numbers to ensure rm fails when they
+	# change so we can update dependencies accordingly.
+	rm gems/{minitest-5.4.3,power_assert-0.2.2,test-unit-3.0.8}.gem || die
+
+	# Fix a hardcoded lib path in configure script
+	sed -i -e "s:\(RUBY_LIB_PREFIX=\"\${prefix}/\)lib:\1$(get_libdir):" \
+		configure.in || die "sed failed"
+
+	eautoreconf
+}
+
+src_configure() {
+	local modules= myconf=
+
+	# -fomit-frame-pointer makes ruby segfault, see bug #150413.
+	filter-flags -fomit-frame-pointer
+	# In many places aliasing rules are broken; play it safe
+	# as it's risky with newer compilers to leave it as it is.
+	append-flags -fno-strict-aliasing
+	# SuperH needs this
+	use sh && append-flags -mieee
+
+	# Socks support via dante
+	if use socks5 ; then
+		# Socks support can't be disabled as long as SOCKS_SERVER is
+		# set and socks library is present, so need to unset
+		# SOCKS_SERVER in that case.
+		unset SOCKS_SERVER
+	fi
+
+	# Increase GC_MALLOC_LIMIT if set (default is 8000000)
+	if [ -n "${RUBY_GC_MALLOC_LIMIT}" ] ; then
+		append-flags "-DGC_MALLOC_LIMIT=${RUBY_GC_MALLOC_LIMIT}"
+	fi
+
+	# ipv6 hack, bug 168939. Needs --enable-ipv6.
+	use ipv6 || myconf="${myconf} --with-lookup-order-hack=INET"
+
+	# Determine which modules *not* to build depending in the USE flags.
+	if ! use readline ; then
+		modules="${modules},readline"
+	fi
+	if ! use berkdb ; then
+		modules="${modules},dbm"
+	fi
+	if ! use gdbm ; then
+		modules="${modules},gdbm"
+	fi
+	if ! use ssl ; then
+		modules="${modules},openssl"
+	fi
+	if ! use ncurses ; then
+		modules="${modules},curses"
+	fi
+	if ! use tk ; then
+		modules="${modules},tk"
+	fi
+
+	# Provide an empty LIBPATHENV because we disable rpath but we do not
+	# need LD_LIBRARY_PATH by default since that breaks USE=multitarget
+	# #564272
+	INSTALL="${EPREFIX}/usr/bin/install -c" LIBPATHENV="" econf \
+		--program-suffix=${MY_SUFFIX} \
+		--with-soname=ruby${MY_SUFFIX} \
+		--docdir=${EPREFIX}/usr/share/doc/${P} \
+		--enable-shared \
+		--enable-pthread \
+		--disable-rpath \
+		--with-out-ext="${modules}" \
+		$(use_with jemalloc jemalloc) \
+		$(use_enable socks5 socks) \
+		$(use_enable doc install-doc) \
+		--enable-ipv6 \
+		$(use_enable debug) \
+		${myconf} \
+		--enable-option-checking=no \
+		|| die "econf failed"
+}
+
+src_compile() {
+	emake V=1 EXTLDFLAGS="${LDFLAGS}" || die "emake failed"
+}
+
+src_test() {
+	emake -j1 V=1 test || die "make test failed"
+
+	elog "Ruby's make test has been run. Ruby also ships with a make check"
+	elog "that cannot be run until after ruby has been installed."
+	elog
+	if use rubytests; then
+		elog "You have enabled rubytests, so they will be installed to"
+		elog "/usr/share/${PN}-${SLOT}/test. To run them you must be a user other"
+		elog "than root, and you must place them into a writeable directory."
+		elog "Then call: "
+		elog
+		elog "ruby${MY_SUFFIX} -C /location/of/tests runner.rb"
+	else
+		elog "Enable the rubytests USE flag to install the make check tests"
+	fi
+}
+
+src_install() {
+	# Remove the remaining bundled gems. We do this late in the process
+	# since they are used during the build to e.g. create the
+	# documentation.
+	rm -rf ext/json || die
+
+	# Ruby is involved in the install process, we don't want interference here.
+	unset RUBYOPT
+
+	local MINIRUBY=$(echo -e 'include Makefile\ngetminiruby:\n\t@echo $(MINIRUBY)'|make -f - getminiruby)
+
+	LD_LIBRARY_PATH="${S}:${D}/usr/$(get_libdir)${LD_LIBRARY_PATH+:}${LD_LIBRARY_PATH}"
+	RUBYLIB="${S}:${D}/usr/$(get_libdir)/ruby/${RUBYVERSION}"
+	for d in $(find "${S}/ext" -type d) ; do
+		RUBYLIB="${RUBYLIB}:$d"
+	done
+	export LD_LIBRARY_PATH RUBYLIB
+
+	emake V=1 DESTDIR="${D}" install || die "make install failed"
+
+	# Remove installed rubygems copy
+	rm -rf "${D}/usr/$(get_libdir)/ruby/${RUBYVERSION}/rubygems" || die "rm rubygems failed"
+	rm -rf "${D}/usr/$(get_libdir)/ruby/${RUBYVERSION}"/rdoc* || die "rm rdoc failed"
+	rm -rf "${D}/usr/bin/"{ri,rdoc}"${MY_SUFFIX}" || die "rm rdoc bins failed"
+
+	if use doc; then
+		make DESTDIR="${D}" install-doc || die "make install-doc failed"
+	fi
+
+	if use examples; then
+		insinto /usr/share/doc/${PF}
+		doins -r sample
+	fi
+
+	dodoc ChangeLog NEWS doc/NEWS* README* || die
+
+	if use rubytests; then
+		pushd test
+		insinto /usr/share/${PN}-${SLOT}/test
+		doins -r .
+		popd
+	fi
+}
+
+pkg_postinst() {
+	if [[ ! -n $(readlink "${ROOT}"usr/bin/ruby) ]] ; then
+		eselect ruby set ruby${MY_SUFFIX}
+	fi
+
+	elog
+	elog "To switch between available Ruby profiles, execute as root:"
+	elog "\teselect ruby set ruby(21|22|...)"
+	elog
+}
+
+pkg_postrm() {
+	eselect ruby cleanup
+}