[gentoo-commits] repo/gentoo:master commit in: net-misc/aria2/

["Sebastian Pipping" <sping@gentoo.org>]

commit:     c01c40a2835dc2c4bea97c389236d3752f27a7e3
Author:     Sebastian Pipping <sping <AT> gentoo <DOT> org>
AuthorDate: Thu Nov  9 16:54:18 2017 +0000
Commit:     Sebastian Pipping <sping <AT> gentoo <DOT> org>
CommitDate: Thu Nov  9 16:54:18 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c01c40a2

net-misc/aria2: 1.33.1

Package-Manager: Portage-2.3.10, Repoman-2.3.3

 net-misc/aria2/Manifest            |   1 +
 net-misc/aria2/aria2-1.33.1.ebuild | 152 +++++++++++++++++++++++++++++++++++++
 2 files changed, 153 insertions(+)

diff --git a/net-misc/aria2/Manifest b/net-misc/aria2/Manifest
index 7ebc69433be..019ddcc3b10 100644
--- a/net-misc/aria2/Manifest
+++ b/net-misc/aria2/Manifest
@@ -2,3 +2,4 @@ DIST aria2-1.30.0.tar.xz 1497124 SHA256 bf6c5366d11d2a6038c8e19f01f9b874041793aa
 DIST aria2-1.31.0.tar.xz 1501388 SHA256 7b85619048b23406f241e38a5b1b8b0bc2cae9e80fd117810c2a71ecca813f8c SHA512 a0a1312522324dc0bc24cf1a5cceaef49d40445668ed0bd98dc3cdd5e2edb428552e97504c8c072f5d1180d6bbd252de01d290ef5c94d1803b8ade330bc2710f WHIRLPOOL 0b5af6d2f9f7e62a2620003a0aa44e842517cb33be00a7e1b0f7ac2720823c5d32deafd91ae096d8ef028f89885c08f459a03955ee349fd6d21dade190895596
 DIST aria2-1.32.0.tar.xz 1502192 SHA256 546e9194a9135d665fce572cb93c88f30fb5601d113bfa19951107ced682dc50 SHA512 7c14c395fab3024191145b5c965c6c89211cd36ce405cafeef350aa6df9850bee9de65e756eab7d0bdeccb9409b829ea21552b9aac0166f50dcc17501b3dca8b WHIRLPOOL 763188033573b5928c7935229505cd82f39009952aa78b7871c1c1579dde54b46185a0d378e3d7241230d0611ba1b7d96c04ed4c09049d38d89b6b550391a0aa
 DIST aria2-1.33.0.tar.xz 1526936 SHA256 996e3fc2fd07ce2dd517e20a1f79b8b3dbaa5c7e27953b5fc19dae38f3874b8c SHA512 6b28282b5688444c99c3219d185c5c87f1760300f47fb9a87f9ee5eb62dd366d55a7706bb6edb16957f0a6926b354b0c6cbbe9887c94980c3027775d06589fea WHIRLPOOL 16bf3179f15830cfbfbe8f44781aa1a2fb0a500f650dd342aff114b13a6b3280045036cf5acc937bc22a0eeef95c83165e4cb9c3dd05032b7bed511e8d7b3bcd
+DIST aria2-1.33.1.tar.xz 1505208 SHA256 2539e4844f55a1f1f5c46ad42744335266053a69162e964d9a2d80a362c75e1b SHA512 5379768a0960e46ed616a2540508d0dda4172c8d1a05021e50243241adb64448f5fa01878868ea206ec6b462fea39fa82284bb0f78ceec299eb289f94815b94a WHIRLPOOL cb9ce23e733e7075a7ecb27a2574bd821bf4109c9900235df5d49e85ba4d6ded7ea17c7d912ccf8cbb6b43ea74b90db257f84013d6a307852c3071cc523ab5a9

diff --git a/net-misc/aria2/aria2-1.33.1.ebuild b/net-misc/aria2/aria2-1.33.1.ebuild
new file mode 100644
index 00000000000..de956e8d169
--- /dev/null
+++ b/net-misc/aria2/aria2-1.33.1.ebuild
@@ -0,0 +1,152 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+inherit bash-completion-r1
+
+DESCRIPTION="A download utility with segmented downloading with BitTorrent support"
+HOMEPAGE="https://aria2.github.io/"
+SRC_URI="https://github.com/aria2/${PN}/releases/download/release-${PV}/${P}.tar.xz"
+
+LICENSE="GPL-2"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+SLOT="0"
+IUSE="adns bittorrent +gnutls jemalloc libuv +libxml2 metalink +nettle nls sqlite scripts ssh ssl tcmalloc test xmlrpc"
+
+CDEPEND="sys-libs/zlib:0=
+	ssl? (
+		app-misc/ca-certificates
+		gnutls? ( >=net-libs/gnutls-1.2.9:0= )
+		!gnutls? ( dev-libs/openssl:0= ) )
+	adns? ( >=net-dns/c-ares-1.5.0:0= )
+	bittorrent? (
+		ssl? (
+			gnutls? (
+				nettle? ( >=dev-libs/nettle-2.4:0=[gmp] >=dev-libs/gmp-6:0= )
+				!nettle? ( >=dev-libs/libgcrypt-1.2.2:0= ) ) )
+		!ssl? (
+			nettle? ( >=dev-libs/nettle-2.4:0=[gmp] >=dev-libs/gmp-6:0= )
+			!nettle? ( >=dev-libs/libgcrypt-1.2.2:0= ) ) )
+	jemalloc? ( dev-libs/jemalloc )
+	libuv? ( dev-libs/libuv:0= )
+	metalink? (
+		libxml2? ( >=dev-libs/libxml2-2.6.26:2= )
+		!libxml2? ( dev-libs/expat:0= ) )
+	sqlite? ( dev-db/sqlite:3= )
+	ssh? ( net-libs/libssh2:= )
+	tcmalloc? ( dev-util/google-perftools )
+	xmlrpc? (
+		libxml2? ( >=dev-libs/libxml2-2.6.26:2= )
+		!libxml2? ( dev-libs/expat:0= ) )"
+
+DEPEND="${CDEPEND}
+	app-arch/xz-utils
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )
+	test? ( >=dev-util/cppunit-1.12.0:0 )"
+RDEPEND="${CDEPEND}
+	nls? ( virtual/libiconv virtual/libintl )
+	scripts? ( dev-lang/ruby )"
+
+# xmlrpc has no explicit switch, it's turned out by any XML library
+# so metalink implicitly forces it on
+REQUIRED_USE="?? ( jemalloc tcmalloc )
+	metalink? ( xmlrpc )"
+RESTRICT="!test? ( test )"
+
+pkg_setup() {
+	if use scripts && ! use xmlrpc; then
+		ewarn "Please note that you may need to enable USE=xmlrpc to run the aria2rpc"
+		ewarn "and aria2mon scripts against the local aria2."
+	fi
+}
+
+src_prepare() {
+	default
+	sed -i -e "s|/tmp|${T}|" test/*.cc test/*.txt || die "sed failed"
+}
+
+src_configure() {
+	local myconf=(
+		# threads, epoll: check for best portability
+
+		# do not try to compile and run a test LIBXML program
+		--disable-xmltest
+		# enable the shared library
+		--enable-libaria2
+		# zlib should always be available anyway
+		--with-libz
+		--with-ca-bundle="${EPREFIX}/etc/ssl/certs/ca-certificates.crt"
+
+		# optional features
+		$(use_enable bittorrent)
+		$(use_enable metalink)
+		$(use_enable nls)
+		$(use_with adns libcares)
+		$(use_with jemalloc)
+		$(use_with libuv)
+		$(use_with sqlite sqlite3)
+		$(use_with ssh libssh2)
+		$(use_with tcmalloc)
+	)
+
+	# SSL := gnutls / openssl
+	# USE=ssl
+	#  + USE=gnutls -> gnutls
+	#  + USE=-gnutls -> openssl
+
+	if use ssl; then
+		myconf+=( $(use_with gnutls) $(use_with !gnutls openssl) )
+	else
+		myconf+=( --without-gnutls --without-openssl )
+	fi
+
+	# message-digest := nettle / gcrypt / openssl
+	# bignum := nettle+gmp / gcrypt / openssl
+	# bittorrent := message-digest + bignum
+	# USE=bittorrent
+	#  + USE=(ssl -gnutls) -> openssl
+	#  + USE=nettle -> nettle+gmp
+	#  + USE=-nettle -> gcrypt
+
+	if use !bittorrent || use ssl && use !gnutls; then
+		myconf+=( --without-libgcrypt --without-libnettle --without-libgmp )
+	else
+		myconf+=( $(use_with !nettle libgcrypt)
+			$(use_with nettle libnettle) $(use_with nettle libgmp) )
+	fi
+
+	# metalink+xmlrpc := libxml2 / expat
+	# USE=(metalink || xmlrpc)
+	#  + USE=libxml2 -> libxml2
+	#  + USE=-libxml2 -> expat
+
+	if use metalink || use xmlrpc; then
+		myconf+=( $(use_with !libxml2 libexpat) $(use_with libxml2) )
+	else
+		myconf+=( --without-libexpat --without-libxml2 )
+	fi
+
+	# Note:
+	# - always enable gzip/http compression since zlib should always be available anyway
+	# - always enable epoll since we can assume kernel 2.6.x
+	# - other options for threads: solaris, pth, win32
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+	rm -rf "${D}"/usr/share/doc/aria2 \
+		"${D}"/usr/share/doc/${PF}/README{,.html}
+
+	dobashcomp doc/bash_completion/aria2c
+	use scripts && dobin doc/xmlrpc/aria2{mon,rpc}
+}
+
+pkg_postinst() {
+	if use xmlrpc; then
+		elog "If you would like to use the additional aria2mon and aria2rpc tools,"
+		elog "you need to have \033[1mdev-lang/ruby\033[0m installed."
+	fi
+}