[gentoo-commits] repo/gentoo:master commit in: media-video/mediainfo/

["Tim Harder" <radhermit@gentoo.org>]

commit:     6fc0ff3069aee980593b2323ff34cc0da014a9b2
Author:     Tim Harder <radhermit <AT> gentoo <DOT> org>
AuthorDate: Thu Nov  2 21:53:52 2017 +0000
Commit:     Tim Harder <radhermit <AT> gentoo <DOT> org>
CommitDate: Thu Nov  2 22:46:35 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=6fc0ff30

media-video/mediainfo: version bump to 17.10

 media-video/mediainfo/Manifest               |  1 +
 media-video/mediainfo/mediainfo-17.10.ebuild | 71 ++++++++++++++++++++++++++++
 2 files changed, 72 insertions(+)

diff --git a/media-video/mediainfo/Manifest b/media-video/mediainfo/Manifest
index b518a84482d..bbf72d5fdf5 100644
--- a/media-video/mediainfo/Manifest
+++ b/media-video/mediainfo/Manifest
@@ -1 +1,2 @@
 DIST mediainfo_0.7.99.tar.xz 1327592 SHA256 ca308d3fd1ded0baad62be2388f65c98949ab9111589b5561c8f0f9c3537ed88 SHA512 7e50d0757c18e0eb07955a440250ca40fb5ee28dd4565528f8797f842611955942a4a6ff5b3c8736d4e24fe503272b2cd93de55187b2c3bca2c99021fe0330fa WHIRLPOOL 0ac9d9042a5382ae9b3a98879e407013fa593bfc01559834ace61f5b1b9aabde54b31f62a407c01956541cc71e46d879b0fcf57fedd2f5cb46fb7812b0cb5a9f
+DIST mediainfo_17.10.tar.xz 1319988 SHA256 0c1130cfa1878592f1225097a1814126378abbcc33926cdfff6bcc99422670fb SHA512 8e24aa71054c8887dc9fc6f9ddb188dfcf61afa37549aed77f77cd13f31cf1ac2e56c2f4e5901cc4ab9d52403740d82b8081898515b4f81944566941906b63f2 WHIRLPOOL bd2af8e4583b4f64cd65dc74d7f3d3f2491f75dc49825edf496235c82302efebcc84e10dcd76bfa7ae1e9d3d5251776ef69c094058379042f9bee5f30c7738af

diff --git a/media-video/mediainfo/mediainfo-17.10.ebuild b/media-video/mediainfo/mediainfo-17.10.ebuild
new file mode 100644
index 00000000000..f3350adbb93
--- /dev/null
+++ b/media-video/mediainfo/mediainfo-17.10.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+WX_GTK_VER="3.0"
+
+inherit eutils autotools wxwidgets
+
+DESCRIPTION="MediaInfo supplies technical and tag information about media files"
+HOMEPAGE="https://mediaarea.net/mediainfo/ https://github.com/MediaArea/MediaInfo"
+SRC_URI="https://mediaarea.net/download/source/${PN}/${PV}/${P/-/_}.tar.xz"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="curl mms wxwidgets"
+
+RDEPEND="sys-libs/zlib
+	>=media-libs/libzen-0.4.37
+	~media-libs/lib${P}[curl=,mms=]
+	wxwidgets? ( x11-libs/wxGTK:${WX_GTK_VER}[X] )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+S=${WORKDIR}/MediaInfo
+
+pkg_setup() {
+	TARGETS="CLI"
+	use wxwidgets && TARGETS+=" GUI"
+}
+
+src_prepare() {
+	eapply_user
+
+	local target
+	for target in ${TARGETS}; do
+		cd "${S}"/Project/GNU/${target}
+		sed -i -e "s:-O2::" configure.ac
+		eautoreconf
+	done
+}
+
+src_configure() {
+	local target
+	for target in ${TARGETS}; do
+		cd "${S}"/Project/GNU/${target}
+		local args=""
+		[[ ${target} == "GUI" ]] && args="--with-wxwidgets --with-wx-gui"
+		econf ${args}
+	done
+}
+
+src_compile() {
+	local target
+	for target in ${TARGETS}; do
+		cd "${S}"/Project/GNU/${target}
+		default
+	done
+}
+src_install() {
+	local target
+	for target in ${TARGETS}; do
+		cd "${S}"/Project/GNU/${target}
+		default
+		dodoc "${S}"/History_${target}.txt
+		if [[ ${target} == "GUI" ]]; then
+			newicon "${S}"/Source/Resource/Image/MediaInfo.png ${PN}.png
+			make_desktop_entry ${PN}-gui MediaInfo ${PN} "AudioVideo;GTK"
+		fi
+	done
+}