[gentoo-commits] repo/gentoo:master commit in: dev-ruby/msgpack/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     7064ce8445708517ce780eeec77b98c0278839e1
Author:     Aric Belsito <lluixhi <AT> gmail <DOT> com>
AuthorDate: Sat Sep  9 23:25:28 2017 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Sat Oct 28 16:19:33 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=7064ce84

dev-ruby/msgpack: add ruby24 to USE_RUBY

drop ruby21 from USE_RUBY
Closes: https://github.com/gentoo/gentoo/pull/5676

 dev-ruby/msgpack/msgpack-1.1.0-r1.ebuild | 44 ++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

diff --git a/dev-ruby/msgpack/msgpack-1.1.0-r1.ebuild b/dev-ruby/msgpack/msgpack-1.1.0-r1.ebuild
new file mode 100644
index 00000000000..dd26691671f
--- /dev/null
+++ b/dev-ruby/msgpack/msgpack-1.1.0-r1.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+
+USE_RUBY="ruby22 ruby23 ruby24"
+
+RUBY_FAKEGEM_TASK_DOC="doc"
+RUBY_FAKEGEM_RECIPE_TEST="rspec3"
+RUBY_FAKEGEM_EXTRADOC="README.rdoc"
+
+inherit multilib ruby-fakegem
+
+DESCRIPTION="Binary-based efficient data interchange format for ruby binding"
+HOMEPAGE="https://msgpack.org/"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc64 ~x86 ~x86-fbsd"
+IUSE="doc"
+
+ruby_add_bdepend "doc? ( dev-ruby/yard )"
+
+all_ruby_prepare() {
+	sed -i -e '/bundler/I s:^:#:' Rakefile || die
+
+	# Remove jruby-specific specs that are run also for other rubies.
+	rm -rf spec/jruby || die
+
+	sed -i -e '/git ls-files/d' msgpack.gemspec || die
+}
+
+each_ruby_configure() {
+	${RUBY} -Cext/${PN} extconf.rb || die "Configuration of extension failed."
+
+	# rb_num2int is not inlined on 32 bit arches but also not explicitly
+	# defined, bug 582968
+	sed -i -e 's:-Wl,--no-undefined::' ext/${PN}/Makefile || die
+}
+
+each_ruby_compile() {
+	emake V=1 -Cext/${PN}
+	cp ext/${PN}/msgpack$(get_modname) lib/${PN} || die "Unable to install msgpack library."
+}