[gentoo-commits] repo/gentoo:master commit in: media-gfx/imagemagick/

["Thomas Deutschmann" <whissi@gentoo.org>]

commit:     7d73b772495c377df1cc108bd4d552ff9f1a8282
Author:     Thomas Deutschmann <whissi <AT> gentoo <DOT> org>
AuthorDate: Sat Oct 28 15:13:56 2017 +0000
Commit:     Thomas Deutschmann <whissi <AT> gentoo <DOT> org>
CommitDate: Sat Oct 28 15:14:53 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=7d73b772

media-gfx/imagemagick: Bump to v6.9.9-20

Package-Manager: Portage-2.3.13, Repoman-2.3.4

 media-gfx/imagemagick/Manifest                    |   1 +
 media-gfx/imagemagick/imagemagick-6.9.9.20.ebuild | 185 ++++++++++++++++++++++
 2 files changed, 186 insertions(+)

diff --git a/media-gfx/imagemagick/Manifest b/media-gfx/imagemagick/Manifest
index 5caf997d097..2f8e4255c59 100644
--- a/media-gfx/imagemagick/Manifest
+++ b/media-gfx/imagemagick/Manifest
@@ -1,5 +1,6 @@
 DIST ImageMagick-6.9.9-0.tar.xz 8780640 SHA256 0a8a091dc4f57ec486e03285a1c30dc3f062d58133f848b6274dfc6ae5dbb60b SHA512 ddd2042e5d9fd2ee9ba91f65c7be3f0cf1a8ce340be9cefaaca2517073d2319b43b7190c5302c92e845f8e250d87681e375aec7238ca93401b42dd248776e338 WHIRLPOOL 603965b07098c3963ab5c089ee4a3fa4b1d36eb8fa52d1e5c22d2dd9bdd6b5ffa165713274fb524991faffe447ce7df14df40c8848f1436e7b86c25d901eda45
 DIST ImageMagick-6.9.9-18.tar.xz 8797460 SHA256 121dd50d051488e908306d7d1ba624781f5ec9532d30a2281b4a2bf6f26ee0b4 SHA512 b18733e01c3f41a221a691ceb992bb2e7ecabbdd1b4765c5dd46f00c2047db8534acee9659aed55786baa00062946353bd02ac60b0609caf21f87fb34a40d290 WHIRLPOOL 9077ece10f3ab8be3334816589640523bed69eef1a3cb789653cb9b260caef6721ef941010f806b00a65f8bd5a9bafa87578163b2b92888f488cdabc49218408
+DIST ImageMagick-6.9.9-20.tar.xz 8994128 SHA256 72131caaee1c673923709f7353b6731b43a2735b29110deac5121db403b07f0f SHA512 36c241490ee41de5cd72e5bc297ac2353a0d4574337776445798b0c5823f491304c3f3a728d420d03f66b652eafcdb68ec2992347321ac3919c1d72c0afdb849 WHIRLPOOL 757763b393b2ebc41d264c3e49f42bbfab1a5bf1e0bf0507d944346500fde299280ed9e8710b8f02740bf72934a58cd85afd8cba31963a452a6de9bdaca27f94
 DIST ImageMagick-6.9.9-9.tar.xz 8797832 SHA256 59eed394d295d651e49ec0f3cfe3f0bb7aeccc28bd7a32360db9f8fc4bf9f25c SHA512 d024f753e1bf234e38736935f38a9bf82969ca77130059383f9d1871a39f68d7678a546d2786d57d602744e2008909df3f2ab08e1207b4c97c0952e7b03876d8 WHIRLPOOL f56279a778c81b6a1b61b7e47f24de25b4758c6d46fabf1f63c6847dac151297ec6bd76e390b3f21b0521963b254771ad9779ed3b4e62f0d77e94f225ec595ef
 DIST ImageMagick-7.0.6-9.tar.xz 8550004 SHA256 aa8cb89dad36b555d8ca497f207008a56b315727c9b5d6d7b28f8f9e3ee7ac25 SHA512 5756d2605cbfbd876765372e954aeefdcdf60f1ee364ce40c3302f8958c510e6f0ecf47a3ee3c264eaaade1504bdae068118eb2cb96d418237f7f53da94a6c11 WHIRLPOOL 602c18d89b4f463d1bbd96d2a9e75c3dd2c2b11419ebe8611121f3a8d6c9ec82798cc5b1183d2f8c2cf7e174695faad4b35468540e3ee7a8c58de4a240035dfe
 DIST ImageMagick-7.0.7-6.tar.xz 8556160 SHA256 52ae1acad9cfbba871b9d3cf033235067a49a20a510c1d6228a4fb3372d5b50e SHA512 9dff09a29b94f0de8ede82473820860f812edf3fc8edb0d1f8daa21c127d3e7831047f33ab22c407f2803a03561b690a52525672da837bbab1a1255156b4e6ff WHIRLPOOL ca21db0a46d055e7bc3a942e70f785599eafbd44e325dd6a33bf42dd19e655ebb0143a12d26b460d9708600e3925aab97f7ce403fbadb65eb14cb90cb3254313

diff --git a/media-gfx/imagemagick/imagemagick-6.9.9.20.ebuild b/media-gfx/imagemagick/imagemagick-6.9.9.20.ebuild
new file mode 100644
index 00000000000..d91b5ff35ee
--- /dev/null
+++ b/media-gfx/imagemagick/imagemagick-6.9.9.20.ebuild
@@ -0,0 +1,185 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit eutils flag-o-matic libtool multilib toolchain-funcs versionator
+
+MY_P=ImageMagick-$(replace_version_separator 3 '-')
+
+DESCRIPTION="A collection of tools and libraries for many image formats"
+HOMEPAGE="http://www.imagemagick.org/"
+SRC_URI="mirror://${PN}/${MY_P}.tar.xz"
+
+LICENSE="imagemagick"
+SLOT="0/${PV}"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+IUSE="bzip2 corefonts cxx djvu fftw fontconfig fpx graphviz hdri jbig jpeg jpeg2k lcms lqr lzma opencl openexr openmp pango perl png postscript q32 q8 raw static-libs svg test tiff truetype webp wmf X xml zlib"
+
+RESTRICT="perl? ( userpriv )"
+
+RDEPEND="
+	dev-libs/libltdl:0
+	bzip2? ( app-arch/bzip2 )
+	corefonts? ( media-fonts/corefonts )
+	djvu? ( app-text/djvu )
+	fftw? ( sci-libs/fftw:3.0 )
+	fontconfig? ( media-libs/fontconfig )
+	fpx? ( >=media-libs/libfpx-1.3.0-r1 )
+	graphviz? ( media-gfx/graphviz )
+	jbig? ( >=media-libs/jbigkit-2:= )
+	jpeg? ( virtual/jpeg:0 )
+	jpeg2k? ( >=media-libs/openjpeg-2.1.0:2 )
+	lcms? ( media-libs/lcms:2= )
+	lqr? ( media-libs/liblqr )
+	opencl? ( virtual/opencl )
+	openexr? ( media-libs/openexr:0= )
+	pango? ( x11-libs/pango )
+	perl? ( >=dev-lang/perl-5.8.8:0= )
+	png? ( media-libs/libpng:0= )
+	postscript? ( app-text/ghostscript-gpl )
+	raw? ( media-gfx/ufraw )
+	svg? ( gnome-base/librsvg )
+	tiff? ( media-libs/tiff:0= )
+	truetype? (
+		media-fonts/urw-fonts
+		>=media-libs/freetype-2
+		)
+	webp? ( media-libs/libwebp:0= )
+	wmf? ( media-libs/libwmf )
+	X? (
+		x11-libs/libICE
+		x11-libs/libSM
+		x11-libs/libXext
+		x11-libs/libXt
+		)
+	xml? ( dev-libs/libxml2:= )
+	lzma? ( app-arch/xz-utils )
+	zlib? ( sys-libs/zlib:= )"
+DEPEND="${RDEPEND}
+	!media-gfx/graphicsmagick[imagemagick]
+	virtual/pkgconfig
+	X? ( x11-proto/xextproto )"
+
+REQUIRED_USE="corefonts? ( truetype )
+	test? ( corefonts )"
+
+S=${WORKDIR}/${MY_P}
+
+src_prepare() {
+	local mesa_cards ati_cards nvidia_cards render_cards
+	default
+
+	elibtoolize # for Darwin modules
+
+	# For testsuite, see https://bugs.gentoo.org/show_bug.cgi?id=500580#c3
+	shopt -s nullglob
+	ati_cards=$(echo -n /dev/ati/card* | sed 's/ /:/g')
+	if test -n "${ati_cards}"; then
+		addpredict "${ati_cards}"
+	fi
+	mesa_cards=$(echo -n /dev/dri/card* | sed 's/ /:/g')
+	if test -n "${mesa_cards}"; then
+		addpredict "${mesa_cards}"
+	fi
+	nvidia_cards=$(echo -n /dev/nvidia** | sed 's/ /:/g')
+	if test -n "${nvidia_cards}"; then
+		addpredict "${nvidia_cards}"
+	fi
+	render_cards=$(echo -n /dev/dri/renderD128* | sed 's/ /:/g')
+	if test -n "${render_cards}"; then
+		addpredict "${render_cards}"
+	fi
+	shopt -u nullglob
+	addpredict /dev/nvidiactl
+}
+
+src_configure() {
+	local depth=16
+	use q8 && depth=8
+	use q32 && depth=32
+
+	local openmp=disable
+	use openmp && { tc-has-openmp && openmp=enable; }
+
+	[[ ${CHOST} == *-solaris* ]] && append-ldflags -lnsl -lsocket
+
+	local myeconfargs=(
+		$(use_enable static-libs static)
+		$(use_enable hdri)
+		$(use_enable opencl)
+		--with-threads
+		--with-modules
+		--with-quantum-depth=${depth}
+		$(use_with cxx magick-plus-plus)
+		$(use_with perl)
+		--with-perl-options='INSTALLDIRS=vendor'
+		--with-gs-font-dir="${EPREFIX}"/usr/share/fonts/urw-fonts
+		$(use_with bzip2 bzlib)
+		$(use_with X x)
+		$(use_with zlib)
+		--without-autotrace
+		$(use_with postscript dps)
+		$(use_with djvu)
+		--with-dejavu-font-dir="${EPREFIX}"/usr/share/fonts/dejavu
+		$(use_with fftw)
+		$(use_with fpx)
+		$(use_with fontconfig)
+		$(use_with truetype freetype)
+		$(use_with postscript gslib)
+		$(use_with graphviz gvc)
+		$(use_with jbig)
+		$(use_with jpeg)
+		$(use_with jpeg2k openjp2)
+		$(use_with lcms)
+		$(use_with lqr)
+		$(use_with lzma)
+		$(use_with openexr)
+		$(use_with pango)
+		$(use_with png)
+		$(use_with svg rsvg)
+		$(use_with tiff)
+		$(use_with webp)
+		$(use_with corefonts windows-font-dir "${EPREFIX}"/usr/share/fonts/corefonts)
+		$(use_with wmf)
+		$(use_with xml)
+		--${openmp}-openmp
+		--with-gcc-arch=no-automagic
+	)
+	CONFIG_SHELL=$(type -P bash) econf "${myeconfargs[@]}"
+}
+
+src_test() {
+	LD_LIBRARY_PATH="${S}/coders/.libs:${S}/filters/.libs:${S}/Magick++/lib/.libs:${S}/magick/.libs:${S}/wand/.libs" \
+	emake check
+}
+
+src_install() {
+	# Ensure documentation installation files and paths with each release!
+	emake \
+		DESTDIR="${D}" \
+		DOCUMENTATION_PATH="${EPREFIX}"/usr/share/doc/${PF}/html \
+		install
+
+	rm -f "${ED}"/usr/share/doc/${PF}/html/{ChangeLog,LICENSE,NEWS.txt}
+	dodoc {AUTHORS,README}.txt ChangeLog
+
+	if use perl; then
+		find "${ED}" -type f -name perllocal.pod -exec rm -f {} +
+		find "${ED}" -depth -mindepth 1 -type d -empty -exec rm -rf {} +
+	fi
+
+	find "${ED}" -name '*.la' -exec sed -i -e "/^dependency_libs/s:=.*:='':" {} +
+
+	if use opencl; then
+		cat <<-EOF > "${T}"/99${PN}
+		SANDBOX_PREDICT="/dev/nvidiactl:/dev/nvidia-uvm:/dev/ati/card:/dev/dri/card:/dev/dri/renderD128"
+		EOF
+
+		insinto /etc/sandbox.d
+		doins "${T}"/99${PN} #472766
+	fi
+
+	insinto /usr/share/${PN}
+	doins config/*icm
+}