[gentoo-commits] repo/gentoo:master commit in: sys-devel/bc/

["Thomas Deutschmann" <whissi@gentoo.org>]

commit:     29ee592113d6c5fec7f06bd4d0d1111b06034a89
Author:     Thomas Deutschmann <whissi <AT> gentoo <DOT> org>
AuthorDate: Sat Oct 28 13:09:32 2017 +0000
Commit:     Thomas Deutschmann <whissi <AT> gentoo <DOT> org>
CommitDate: Sat Oct 28 13:10:19 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=29ee5921

sys-devel/bc: Rev bump to re-trigger mirroring of SRC_URI

In addition, ebuild was bumped to EAPI=6.

Closes: https://bugs.gentoo.org/615978
Package-Manager: Portage-2.3.11, Repoman-2.3.3

 sys-devel/bc/bc-1.07.1-r1.ebuild | 49 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

diff --git a/sys-devel/bc/bc-1.07.1-r1.ebuild b/sys-devel/bc/bc-1.07.1-r1.ebuild
new file mode 100644
index 00000000000..fcd02f0f33e
--- /dev/null
+++ b/sys-devel/bc/bc-1.07.1-r1.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+inherit flag-o-matic toolchain-funcs
+
+DESCRIPTION="Handy console-based calculator utility"
+HOMEPAGE="https://www.gnu.org/software/bc/bc.html"
+SRC_URI="mirror://gnu/bc/${P}.tar.gz"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~x64-cygwin ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="libedit readline static"
+
+RDEPEND="!readline? ( libedit? ( dev-libs/libedit:= ) )
+	readline? (
+		>=sys-libs/readline-4.1:0=
+		>=sys-libs/ncurses-5.2:=
+	)"
+DEPEND="${RDEPEND}
+	sys-apps/ed
+	sys-devel/flex"
+
+src_configure() {
+	local libedit
+	if use readline ; then
+		libedit="--without-libedit"
+	else
+		libedit=$(use_with libedit)
+	fi
+	use static && append-ldflags -static
+	# Clobber any CONFIG_SHELL setting the user has forced on us.
+	# We should be able to delete this w/the next release as it
+	# should use updated autoconf.
+	CONFIG_SHELL=/bin/bash \
+	econf \
+		$(use_with readline) \
+		${libedit}
+
+	# Do not regen docs -- configure produces a small fragment that includes
+	# the version info which causes all pages to regen (newer file). #554774
+	touch -r doc doc/*
+}
+
+src_compile() {
+	emake AR="$(tc-getAR)"
+}