[gentoo-commits] repo/gentoo:master commit in: sys-apps/util-linux/

["Lars Wendler" <polynomial-c@gentoo.org>]

commit:     68cb7653a83ffa4b214898d4cf6615d515fd0729
Author:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
AuthorDate: Mon Oct 23 11:08:37 2017 +0000
Commit:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
CommitDate: Mon Oct 23 11:11:33 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=68cb7653

sys-apps/util-linux: Bump to version 2.31. Removed old.

Package-Manager: Portage-2.3.12, Repoman-2.3.3

 sys-apps/util-linux/Manifest                       |   4 +-
 ...inux-2.31_rc1.ebuild => util-linux-2.31.ebuild} |   0
 sys-apps/util-linux/util-linux-2.31_rc2.ebuild     | 209 ---------------------
 3 files changed, 1 insertion(+), 212 deletions(-)

diff --git a/sys-apps/util-linux/Manifest b/sys-apps/util-linux/Manifest
index a5781fbff28..a08213dc662 100644
--- a/sys-apps/util-linux/Manifest
+++ b/sys-apps/util-linux/Manifest
@@ -2,6 +2,4 @@ DIST util-linux-2.28.2.tar.xz 4149700 SHA256 b89d37146f20bede93a42c847bce881a17e
 DIST util-linux-2.29.2.tar.xz 4277668 SHA256 accea4d678209f97f634f40a93b7e9fcad5915d1f4749f6c47bee6bf110fe8e3 SHA512 0a87e6758531f74276f3de7607ef545f324b9b36b444aa5d163140c5fb0f4f7602655d7ec9939f92550dcb320d922cd69521a2183199d463795e67d3c27fce79 WHIRLPOOL 1f45711e593c76c6e208a28892ed2bf2622adb5fa1334867e13c6bf775a8903c2f1ebf18c3238d96fe139c5b60d61abf496251cf594a339209ce044f2bb8c17a
 DIST util-linux-2.30.1.tar.xz 4459284 SHA256 1be4363a91ac428c9e43fc04dc6d2c66a19ec1e36f1105bd4b481540be13b841 SHA512 bcf1807198660c133c380e13d6ba5dcdb7470c47bcaeea03ccc5a78a0d834e3df3d13ae5ffc35fd7f8fff7ba062629d4b1f5cde78452b846c9315c51c9e108f5 WHIRLPOOL 19e78768cf2fd2d73bb7b45cb826101b4653bf49c9838bda10f05e508f06b117bb846ce517726465384bfe94ba24981f261d7b5091458242fb0c14d593d4b29e
 DIST util-linux-2.30.2.tar.xz 4442624 SHA256 7b5be5489e9b5b7177832836467aba1c87bf0e9bcbcb5a6f35d76cd4782589dc SHA512 b92ec16d5e8a405ad9ebbac8673bb49c5bf0a7f630118477f12c7a3c6b3b3ee5d56868632dd71fffd5c0434821207c2769f6859b9d398c2df770ec6487d7c32d WHIRLPOOL 771d2af788241db337be1e11be499d42b67ec86fa43da2eb161914194d1f002e95d9080793117a4b58a57691df8677ac59e9356ae2da7076ca48188c185a1843
-DIST util-linux-2.31-rc1.tar.xz 4459892 SHA256 25771b2feb19bed4bf50597c597b2fed4f7580db135fb63a9421ceeeee123436 SHA512 027815da2ee4d342ff1578d5bba71ea63dc1cd6816ad753c644b5422b693e9dfe35ab158101ac9d7f8b7dbee1d2cf97e4930b24ed247eba7be1312e5292c3f9f WHIRLPOOL 6309c11499ee310b754780a31229385ee1fe87f31a84969b490d93d32d294f3a9c096c909abb363f06378e87bea3015bc7150620493989838ae47a4140912b18
-DIST util-linux-2.31-rc2.tar.xz 4472160 SHA256 adf02ca514d20fc31e608f158bf11de27875fb22db9a6702ed60c36dd052b275 SHA512 d5b882dbe566e5ad4cbf3ea328bc777ae643c271c4db4a119f270222ef50d89bdb2244524093df794caf0ec9a6b5f559c618f0e36f2c1e2ce30e24c60e876a97 WHIRLPOOL f790512822ca30c4b1086ed735e234506375eef57721cf9692b460440fb09fc38a9088379a3d74be34d0d46231bd6ef9155aa05ea6338e54f22585418871c36a
-DIST util-linux-2.31_rc2-losetup_types.patch 1472 SHA256 00f04271f725b7d373ffe3db1b591bd8fbaf740fd5641673c47c0e2678720b5f SHA512 353b90e87948fda6aa357470260d6945f0993e89589a1380293b481a839bfe8a4618a55ec92e4c1962e25fe5f74de400cbf2c12371cc0a9298711182d953b51a WHIRLPOOL ff5afe50e51427ab181451c4a823101ceed0d237bcd4c8cc5e30ef365456d3aa1f102d0845e5d84e06f59206edd5ed21f3dabb61d50455f2ca32d8d2d7294342
+DIST util-linux-2.31.tar.xz 4503892 SHA256 f9be7cdcf4fc5c5064a226599acdda6bdf3d86c640152ba01ea642d91108dc8a SHA512 48b668526e96a132736b882090d0e33c20b4b3a0e1760502d83118ed98ccc9423d310848a2bb73f82f85e9c19f6191075ae2c5269b007e76be1fbd7b6b88fbf5 WHIRLPOOL 1667045919e29feafdea35f1c66b47f546b7b111347ad7cfcab94519bfba9119a492fa3475e2fef5d5c3383ff19daf9d4bbad1cca24ca1ea4be138e40e161611

diff --git a/sys-apps/util-linux/util-linux-2.31_rc1.ebuild b/sys-apps/util-linux/util-linux-2.31.ebuild
similarity index 100%
rename from sys-apps/util-linux/util-linux-2.31_rc1.ebuild
rename to sys-apps/util-linux/util-linux-2.31.ebuild

diff --git a/sys-apps/util-linux/util-linux-2.31_rc2.ebuild b/sys-apps/util-linux/util-linux-2.31_rc2.ebuild
deleted file mode 100644
index 493ecb1a0ed..00000000000
--- a/sys-apps/util-linux/util-linux-2.31_rc2.ebuild
+++ /dev/null
@@ -1,209 +0,0 @@
-# Copyright 1999-2017 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-
-PYTHON_COMPAT=( python2_7 python3_{4,5,6} )
-
-inherit ltprune toolchain-funcs libtool flag-o-matic bash-completion-r1 \
-	pam python-single-r1 multilib-minimal systemd
-
-MY_PV="${PV/_/-}"
-MY_P="${PN}-${MY_PV}"
-
-if [[ ${PV} == 9999 ]] ; then
-	inherit git-r3 autotools
-	EGIT_REPO_URI="git://git.kernel.org/pub/scm/utils/util-linux/util-linux.git"
-else
-	[[ "${PV}" = *_rc* ]] || \
-	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-linux ~arm-linux ~x86-linux"
-	SRC_URI="mirror://kernel/linux/utils/util-linux/v${PV:0:4}/${MY_P}.tar.xz"
-
-	SRC_URI+=" https://github.com/karelzak/util-linux/commit/c4e60bc0807b04ab104594abc83301481d5d5995.patch -> ${PN}-2.31_rc2-losetup_types.patch"
-fi
-
-DESCRIPTION="Various useful Linux utilities"
-HOMEPAGE="https://www.kernel.org/pub/linux/utils/util-linux/"
-
-LICENSE="GPL-2 LGPL-2.1 BSD-4 MIT public-domain"
-SLOT="0"
-IUSE="build caps +cramfs fdformat kill ncurses nls pam python +readline selinux slang static-libs +suid systemd test tty-helpers udev unicode"
-
-# Most lib deps here are related to programs rather than our libs,
-# so we rarely need to specify ${MULTILIB_USEDEP}.
-RDEPEND="caps? ( sys-libs/libcap-ng )
-	cramfs? ( sys-libs/zlib )
-	ncurses? ( >=sys-libs/ncurses-5.2-r2:0=[unicode?] )
-	pam? ( sys-libs/pam )
-	python? ( ${PYTHON_DEPS} )
-	readline? ( sys-libs/readline:0= )
-	selinux? ( >=sys-libs/libselinux-2.2.2-r4[${MULTILIB_USEDEP}] )
-	slang? ( sys-libs/slang )
-	!build? ( systemd? ( sys-apps/systemd ) )
-	udev? ( virtual/libudev:= )"
-DEPEND="${RDEPEND}
-	virtual/pkgconfig
-	nls? ( sys-devel/gettext )
-	test? ( sys-devel/bc )
-	virtual/os-headers"
-RDEPEND+="
-	kill? (
-		!sys-apps/coreutils[kill]
-		!sys-process/procps[kill]
-	)
-	!net-wireless/rfkill
-	!sys-process/schedutils
-	!sys-apps/setarch
-	!<sys-apps/sysvinit-2.88-r7
-	!sys-block/eject
-	!<sys-libs/e2fsprogs-libs-1.41.8
-	!<sys-fs/e2fsprogs-1.41.8
-	!<app-shells/bash-completion-2.3-r2"
-
-REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
-
-S="${WORKDIR}/${MY_P}"
-
-PATCHES=(
-	"${DISTDIR}/${P}-losetup_types.patch"
-)
-
-pkg_setup() {
-	use python && python-single-r1_pkg_setup
-}
-
-src_prepare() {
-	default
-
-	if [[ ${PV} == 9999 ]] ; then
-		po/update-potfiles
-		eautoreconf
-	fi
-	# Undo bad ncurses handling by upstream. #601530
-	sed -i -E \
-		-e '/NCURSES_/s:(ncursesw?)[56]-config:$PKG_CONFIG \1:' \
-		-e 's:(ncursesw?)[56]-config --version:$PKG_CONFIG --exists --print-errors \1:' \
-		configure || die
-	elibtoolize
-}
-
-lfs_fallocate_test() {
-	# Make sure we can use fallocate with LFS #300307
-	cat <<-EOF > "${T}"/fallocate.${ABI}.c
-		#define _GNU_SOURCE
-		#include <fcntl.h>
-		main() { return fallocate(0, 0, 0, 0); }
-	EOF
-	append-lfs-flags
-	$(tc-getCC) ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} "${T}"/fallocate.${ABI}.c -o /dev/null >/dev/null 2>&1 \
-		|| export ac_cv_func_fallocate=no
-	rm -f "${T}"/fallocate.${ABI}.c
-}
-
-multilib_src_configure() {
-	lfs_fallocate_test
-	# The scanf test in a run-time test which fails while cross-compiling.
-	# Blindly assume a POSIX setup since we require libmount, and libmount
-	# itself fails when the scanf test fails. #531856
-	tc-is-cross-compiler && export scanf_cv_alloc_modifier=ms
-	export ac_cv_header_security_pam_misc_h=$(multilib_native_usex pam) #485486
-	export ac_cv_header_security_pam_appl_h=$(multilib_native_usex pam) #545042
-
-	local myeconfargs=(
-		--disable-chfn-chsh
-		--disable-login
-		--disable-nologin
-		--disable-reset
-		--disable-su
-		--docdir='${datarootdir}'/doc/${PF}
-		--enable-agetty
-		--enable-bash-completion
-		--enable-fs-paths-extra="${EPREFIX}/usr/sbin:${EPREFIX}/bin:${EPREFIX}/usr/bin"
-		--enable-line
-		--enable-partx
-		--enable-raw
-		--enable-rename
-		--enable-rfkill
-		--enable-schedutils
-		--with-bashcompletiondir="$(get_bashcompdir)"
-		--with-systemdsystemunitdir=$(multilib_native_usex systemd "$(systemd_get_systemunitdir)" "no")
-		$(multilib_native_use_enable caps setpriv)
-		$(multilib_native_use_enable cramfs)
-		$(multilib_native_use_enable fdformat)
-		$(multilib_native_use_enable nls)
-		$(multilib_native_use_enable suid makeinstall-chown)
-		$(multilib_native_use_enable suid makeinstall-setuid)
-		$(multilib_native_use_enable tty-helpers mesg)
-		$(multilib_native_use_enable tty-helpers wall)
-		$(multilib_native_use_enable tty-helpers write)
-		$(multilib_native_use_with python)
-		$(multilib_native_use_with readline)
-		$(multilib_native_use_with slang)
-		$(multilib_native_use_with systemd)
-		$(multilib_native_use_with udev)
-		$(multilib_native_usex ncurses "$(use_with unicode ncursesw)" '--without-ncursesw')
-		$(multilib_native_usex ncurses "$(use_with !unicode ncurses)" '--without-ncurses')
-		$(tc-has-tls || echo --disable-tls)
-		$(use_enable unicode widechar)
-		$(use_enable kill)
-		$(use_enable static-libs static)
-		$(use_with selinux)
-		$(usex ncurses '' '--without-tinfo')
-	)
-	ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
-}
-
-multilib_src_compile() {
-	if multilib_is_native_abi; then
-		default
-	else
-		# build libraries only
-		emake -f Makefile -f - mylibs \
-			<<< 'mylibs: $(usrlib_exec_LTLIBRARIES) $(pkgconfig_DATA)'
-	fi
-}
-
-multilib_src_test() {
-	multilib_is_native_abi && emake check
-}
-
-multilib_src_install() {
-	if multilib_is_native_abi; then
-		default
-	else
-		emake DESTDIR="${D}" install-usrlib_execLTLIBRARIES \
-			install-pkgconfigDATA install-uuidincHEADERS \
-			install-nodist_blkidincHEADERS install-nodist_mountincHEADERS \
-			install-nodist_smartcolsincHEADERS install-nodist_fdiskincHEADERS
-	fi
-
-	if multilib_is_native_abi; then
-		# need the libs in /
-		gen_usr_ldscript -a blkid mount smartcols uuid
-
-		use python && python_optimize
-	fi
-}
-
-multilib_src_install_all() {
-	dodoc AUTHORS NEWS README* Documentation/{TODO,*.txt,releases/*}
-
-	# e2fsprogs-libs didnt install .la files, and .pc work fine
-	prune_libtool_files
-
-	if use pam; then
-		newpamd "${FILESDIR}/runuser.pamd" runuser
-		newpamd "${FILESDIR}/runuser-l.pamd" runuser-l
-	fi
-}
-
-pkg_postinst() {
-	if ! use tty-helpers; then
-		elog "The mesg/wall/write tools have been disabled due to USE=-tty-helpers."
-	fi
-
-	if [[ -z ${REPLACING_VERSIONS} ]]; then
-		elog "The agetty util now clears the terminal by default. You"
-		elog "might want to add --noclear to your /etc/inittab lines."
-	fi
-}