[gentoo-commits] repo/gentoo:master commit in: dev-perl/Finance-YahooQuote/

["Kent Fredric" <kentnl@gentoo.org>]

commit:     056e62af9da171fff44bb4a22cb82c98a5361d4a
Author:     Kent Fredric <kentnl <AT> gentoo <DOT> org>
AuthorDate: Sat Oct 21 09:21:42 2017 +0000
Commit:     Kent Fredric <kentnl <AT> gentoo <DOT> org>
CommitDate: Sat Oct 21 09:25:14 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=056e62af

dev-perl/Finance-YahooQuote: EAPI6 + tests

- EAPI6ify
- Add basic tests
- Gate network tests by DIST_TEST_OVERRRIDE

Package-Manager: Portage-2.3.8, Repoman-2.3.3

 .../Finance-YahooQuote-0.250.0-r1.ebuild           | 50 ++++++++++++++++++++++
 1 file changed, 50 insertions(+)

diff --git a/dev-perl/Finance-YahooQuote/Finance-YahooQuote-0.250.0-r1.ebuild b/dev-perl/Finance-YahooQuote/Finance-YahooQuote-0.250.0-r1.ebuild
new file mode 100644
index 00000000000..c869fc47a9b
--- /dev/null
+++ b/dev-perl/Finance-YahooQuote/Finance-YahooQuote-0.250.0-r1.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+DIST_AUTHOR=EDD
+DIST_VERSION=0.25
+inherit perl-module
+
+DESCRIPTION="Get stock quotes from Yahoo! Finance"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE=""
+
+RDEPEND="
+	dev-perl/libwww-perl
+	virtual/perl-MIME-Base64
+	>=dev-perl/HTML-Parser-2.200.0
+	>=virtual/perl-Text-ParseWords-3.100.0
+"
+DEPEND="${RDEPEND}
+	virtual/perl-ExtUtils-MakeMaker
+"
+src_test() {
+	local MODULES=(
+		"Finance::YahooQuote ${DIST_VERSION}"
+	)
+	local failed=()
+	for dep in "${MODULES[@]}"; do
+		ebegin "Compile testing ${dep}"
+			perl -Mblib="${S}" -M"${dep} ()" -e1
+		eend $? || failed+=( "$dep" )
+	done
+	if [[ ${failed[@]} ]]; then
+		echo
+		eerror "One or more modules failed compile:";
+		for dep in "${failed[@]}"; do
+			eerror "  ${dep}"
+		done
+		die "Failing due to module compilation errors";
+	fi
+	if ! has network ${DIST_TEST_OVERRIDE:-${DIST_TEST:-do parallel}}; then
+		ewarn "Comprehensive tests require network access. For details, see:"
+		ewarn "https://wiki.gentoo.org/wiki/Project:Perl/maint-notes/dev-perl/Finance-YahooQuote"
+		perl_rm_files "t/04custom.t" "t/02simple.t" "t/03extended.t" "t/05test.t";
+	fi
+	perl-module_src_test
+}