[gentoo-commits] repo/gentoo:master commit in: app-accessibility/speech-dispatcher/

["Michael Palimaka" <kensington@gentoo.org>]

commit:     df108f64fe52cc9371808a0cdddddfbf4136503c
Author:     Michael Palimaka <kensington <AT> gentoo <DOT> org>
AuthorDate: Thu Oct 12 11:11:57 2017 +0000
Commit:     Michael Palimaka <kensington <AT> gentoo <DOT> org>
CommitDate: Thu Oct 12 11:15:07 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=df108f64

app-accessibility/speech-dispatcher: version bump 0.8.7

Closes: https://bugs.gentoo.org/604396
Closes: https://bugs.gentoo.org/604398
Package-Manager: Portage-2.3.8, Repoman-2.3.3

 app-accessibility/speech-dispatcher/Manifest       |   1 +
 .../speech-dispatcher-0.8.7.ebuild                 | 109 +++++++++++++++++++++
 2 files changed, 110 insertions(+)

diff --git a/app-accessibility/speech-dispatcher/Manifest b/app-accessibility/speech-dispatcher/Manifest
index 7fffba5e2bc..bf52f651ed6 100644
--- a/app-accessibility/speech-dispatcher/Manifest
+++ b/app-accessibility/speech-dispatcher/Manifest
@@ -1,2 +1,3 @@
 DIST speech-dispatcher-0.8.1.tar.gz 1309969 SHA256 d25727239bbee4ee7881dd5e23e4da64a184b2ff3c8c9830088a671fb23b7757 SHA512 35f1ae547001a45d7945406ae5672829ff9ab6ac3f0cccb9eb3670dd92888a63c7cc4270ee90b5a166e6788afe3b117b5c3ef62c41a9df9f9af94dc4e0948fe8 WHIRLPOOL 945ef7ab1d771dc1e3727f223cfadfd309db03813f11fe995c0f4caf3a6f24bc9abc18e1f2f342b072bcd5fd0d626dae315f1fd0228d4172e051a2aba1255092
 DIST speech-dispatcher-0.8.3.tar.gz 1292321 SHA256 96a293b2ba1e2498f1280c75a9607891a9990947a8d87e9855c2a642c93f1e4f SHA512 48eaa1fb27a14ad6c6a1f214044fbddde85ff07e636355e75f4f3ac1e46cea0cbbbd2cb9ce01ce4b9cb27d5395d840bd38afd2c65ec0fabcc8787483ae7a7b67 WHIRLPOOL 606bee401a98c91aa34f071007cabc3d7ad5f2a5a9425a32d40a8cce75a4b13795b4877a42451be37ea14a68a008fc1e0e063d881c08a78dce41f3a800962fd1
+DIST speech-dispatcher-0.8.7.tar.gz 1333677 SHA256 200be1adb054dd14bfbc46e798ac6a7c0d4abaa13343fb987312c5265e4cb134 SHA512 0e7af02e8521aa8d397ea4d0329f9a8d56970beed645456dfedc738ececd2ccd8ecfdf66e92ae852878a473ba991175e1d4dc2b8b0148c958163682b49678375 WHIRLPOOL daa32fc0150aec77db006908086db49fdef81f64d7e6d3953434ecb61e27f1b7c93d47208d545f903c5b1ad8a29a2c6a694fbd95983251867ab3574bd9c1ec02

diff --git a/app-accessibility/speech-dispatcher/speech-dispatcher-0.8.7.ebuild b/app-accessibility/speech-dispatcher/speech-dispatcher-0.8.7.ebuild
new file mode 100644
index 00000000000..215c3bf2c2c
--- /dev/null
+++ b/app-accessibility/speech-dispatcher/speech-dispatcher-0.8.7.ebuild
@@ -0,0 +1,109 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python3_{4,5,6} )
+
+inherit eutils python-r1
+
+DESCRIPTION="Speech synthesis interface"
+HOMEPAGE="http://www.freebsoft.org/speechd"
+SRC_URI="http://www.freebsoft.org/pub/projects/speechd/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="alsa ao +espeak flite nas pulseaudio python static-libs"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+COMMON_DEPEND="python? ( ${PYTHON_DEPS} )
+	>=dev-libs/dotconf-1.3
+	>=dev-libs/glib-2.28:2
+	dev-libs/libltdl:0
+	>=media-libs/libsndfile-1.0.2
+	alsa? ( media-libs/alsa-lib )
+	ao? ( media-libs/libao )
+	espeak? ( app-accessibility/espeak )
+	flite? ( app-accessibility/flite )
+	nas? ( media-libs/nas )
+	pulseaudio? ( media-sound/pulseaudio )"
+DEPEND="${COMMON_DEPEND}
+	>=dev-util/intltool-0.40.0
+	virtual/pkgconfig"
+RDEPEND="${COMMON_DEPEND}
+	dev-python/pyxdg"
+
+src_configure() {
+	local myeconfargs=(
+		--disable-python
+		$(use_enable static-libs static)
+		$(use_with alsa)
+		$(use_with ao libao)
+		$(use_with espeak)
+		$(use_with flite)
+		$(use_with pulseaudio pulse)
+		$(use_with nas)
+	)
+	econf ${myeconfargs[@]}
+}
+
+src_compile() {
+	use python && python_copy_sources
+
+	emake
+
+	if use python; then
+		building() {
+			cd src/api/python || die
+			emake \
+				pyexecdir="$(python_get_sitedir)" \
+				pythondir="$(python_get_sitedir)"
+		}
+		python_foreach_impl run_in_build_dir building
+	fi
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	dodoc ANNOUNCE AUTHORS BUGS FAQ NEWS README*
+
+	prune_libtool_files --all
+
+	if use python; then
+		installation() {
+			cd src/api/python || die
+			emake \
+				DESTDIR="${D}" \
+				pyexecdir="$(python_get_sitedir)" \
+				pythondir="$(python_get_sitedir)" \
+				install
+		}
+		python_foreach_impl run_in_build_dir installation
+		python_replicate_script "${ED}"/usr/bin/spd-conf
+	fi
+}
+
+pkg_postinst() {
+	local editconfig="n"
+	if ! use espeak; then
+		ewarn "You have disabled espeak, which is speech-dispatcher's"
+		ewarn "default speech synthesizer."
+		ewarn
+		editconfig="y"
+	fi
+	if ! use pulseaudio; then
+		ewarn "You have disabled pulseaudio support."
+		ewarn "pulseaudio is speech-dispatcher's default audio subsystem."
+		ewarn
+		editconfig="y"
+	fi
+	if [[ "${editconfig}" == "y" ]]; then
+		ewarn "You must edit ${EROOT}etc/speech-dispatcher/speechd.conf"
+		ewarn "and make sure the settings there match your system."
+		ewarn
+	fi
+	elog "For festival support, you need to"
+	elog "install app-accessibility/festival-freebsoft-utils."
+}