From mboxrd@z Thu Jan  1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-973283-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
	(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
	(No client certificate requested)
	by finch.gentoo.org (Postfix) with ESMTPS id 2D0D21396D0
	for <garchives@archives.gentoo.org>; Sun, 17 Sep 2017 04:06:05 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
	by pigeon.gentoo.org (Postfix) with SMTP id 40716E0E63;
	Sun, 17 Sep 2017 04:06:04 +0000 (UTC)
Received: from smtp.gentoo.org (smtp.gentoo.org [140.211.166.183])
	(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
	(No client certificate requested)
	by pigeon.gentoo.org (Postfix) with ESMTPS id 06E3CE0E63
	for <gentoo-commits@lists.gentoo.org>; Sun, 17 Sep 2017 04:06:03 +0000 (UTC)
Received: from oystercatcher.gentoo.org (oystercatcher.gentoo.org [148.251.78.52])
	(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
	(No client certificate requested)
	by smtp.gentoo.org (Postfix) with ESMTPS id CFB9233BE69
	for <gentoo-commits@lists.gentoo.org>; Sun, 17 Sep 2017 04:06:02 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
	by oystercatcher.gentoo.org (Postfix) with ESMTP id 5585A907F
	for <gentoo-commits@lists.gentoo.org>; Sun, 17 Sep 2017 04:06:01 +0000 (UTC)
From: "William Hubbs" <williamh@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "William Hubbs" <williamh@gentoo.org>
Message-ID: <1505621125.01ffade15e855ac3794100a65bfc6ac61027c3f4.williamh@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: sys-apps/openrc/
X-VCS-Repository: repo/gentoo
X-VCS-Files: sys-apps/openrc/Manifest sys-apps/openrc/openrc-0.31.1.ebuild
X-VCS-Directories: sys-apps/openrc/
X-VCS-Committer: williamh
X-VCS-Committer-Name: William Hubbs
X-VCS-Revision: 01ffade15e855ac3794100a65bfc6ac61027c3f4
X-VCS-Branch: master
Date: Sun, 17 Sep 2017 04:06:01 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Archives-Salt: e66ec709-7cc1-4ca2-a3e6-3c485fc70aef
X-Archives-Hash: 8427679ad01142c5300b0007c6151dc8

commit:     01ffade15e855ac3794100a65bfc6ac61027c3f4
Author:     William Hubbs <williamh <AT> gentoo <DOT> org>
AuthorDate: Sun Sep 17 04:05:25 2017 +0000
Commit:     William Hubbs <williamh <AT> gentoo <DOT> org>
CommitDate: Sun Sep 17 04:05:25 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=01ffade1

sys-apps/openrc: 0.31.1 version bump for cgroup2 fixes

Package-Manager: Portage-2.3.6, Repoman-2.3.3

 sys-apps/openrc/Manifest             |   1 +
 sys-apps/openrc/openrc-0.31.1.ebuild | 329 +++++++++++++++++++++++++++++++++++
 2 files changed, 330 insertions(+)

diff --git a/sys-apps/openrc/Manifest b/sys-apps/openrc/Manifest
index 0a8c206b32d..58bed91f45d 100644
--- a/sys-apps/openrc/Manifest
+++ b/sys-apps/openrc/Manifest
@@ -9,4 +9,5 @@ DIST openrc-0.27.2.tar.gz 223572 SHA256 4e9c12c77c101b6ea255f1a9291c4c4d228c7ddc
 DIST openrc-0.28.tar.gz 224228 SHA256 9548b03ffc164f75887d810469f0535a16c5c8c2e615e250d5753a16e66cf317 SHA512 a10c293bf4287bcc4ffb9c996cbc1294f979483ea9fb2efb0dd1becee193f49ff114530c078850e8c11cf2c0a812be2e74801352fdbfe313b90cd9af5b8ccf93 WHIRLPOOL d55ae26bef0ebf4c17f484c476c08cefe40d0bdaf55a571bb4cfefaf67248661661eb28936e509c4bbccb2f4a0e36e8d01f7b6ae3dc2b1831f571b26d0ac6223
 DIST openrc-0.29.tar.gz 223275 SHA256 b919c4520e93ba02db24e7766d32688928d5bb0cc8fe2f250277c46274d99927 SHA512 1accc52c3e729432fee433395eb7551fa7913004999c595f6485a0505b7916338df6d9e7d95304e865adf67df54378525a758b34bb67beefe240a90700e4f7d8 WHIRLPOOL 341ae930257f23513fd3582a7e329c48f546d306c467bab3430a8838c343d5697db5941e3590a8f1c33f34a0eefac07f0fb9c0e4a752d1659293374057cc4aea
 DIST openrc-0.30.tar.gz 222383 SHA256 29b4d565bc37f51585c4a9aabedad46d79031861209cbda3a916a0a01c56e0bc SHA512 d1893adc776184cdb9a7ab884250d29357d1e4855f5f1f93577e6ca2ff30f3233d263d237672395caaff6e479bcba5e52c31c9089e8904ed70b40a29f10864cb WHIRLPOOL 68f931a6c8fb141d85217fa8d37e9a0507d583e7fc41a5db78b9700223f52ea06ffb514c19f541b93977609c351872804968fdd2ad0431055283c034c2a89698
+DIST openrc-0.31.1.tar.gz 224059 SHA256 2a5cb07ce64fec2b3fd35c11be6b7dfe383fdc6a5449278c67b2f0af026650cc SHA512 98001e05896d113e20fad27ba100e2db5588262cb9c0b52c2800b38fd320b9baf4a99302044ef4045ba3a746d685d0cc27f8fdb42dccbc0574e32c6db9e6d3d2 WHIRLPOOL 00cb1d252d79700b79828fed6e319c124ae1c89bd10f506ff2f0e36961288c1d9a7366abb19e77f866aaa1695b176ecaad892ddd4b5a26713d084d4744470acd
 DIST openrc-0.31.tar.gz 223966 SHA256 9d1631b647b3b8981dcbb5251f9d2444859c6cf0791c1b6b07469953e657eeee SHA512 2c28daa5b2bfd3c31a2b87b08a7b39dc078ab0224c713a2b738e991f968f07d4761770a813fb449df551d6e3db58ed997ac8bbe210d1fb17b4c88ead859eba7b WHIRLPOOL 929dbd2724b6f6aaeaae1d9bce913068ac94ec3e21aefae859d782ed7f6f2a948042a5371afc3a8f631b10552776225b4b8487a11188847366877bfd12889001

diff --git a/sys-apps/openrc/openrc-0.31.1.ebuild b/sys-apps/openrc/openrc-0.31.1.ebuild
new file mode 100644
index 00000000000..278de480e1f
--- /dev/null
+++ b/sys-apps/openrc/openrc-0.31.1.ebuild
@@ -0,0 +1,329 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit flag-o-matic pam toolchain-funcs
+
+DESCRIPTION="OpenRC manages the services, startup and shutdown of a host"
+HOMEPAGE="https://github.com/openrc/openrc/"
+
+if [[ ${PV} == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/OpenRC/${PN}.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/${PN}/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd"
+fi
+
+LICENSE="BSD-2"
+SLOT="0"
+IUSE="audit debug ncurses pam newnet prefix +netifrc selinux static-libs
+	unicode kernel_linux kernel_FreeBSD"
+
+COMMON_DEPEND="kernel_FreeBSD? ( || ( >=sys-freebsd/freebsd-ubin-9.0_rc sys-process/fuser-bsd ) )
+	ncurses? ( sys-libs/ncurses:0= )
+	pam? (
+		sys-auth/pambase
+		virtual/pam
+	)
+	audit? ( sys-process/audit )
+	kernel_linux? (
+		sys-process/psmisc
+		!<sys-process/procps-3.3.9-r2
+	)
+	selinux? (
+		sys-apps/policycoreutils
+		sys-libs/libselinux
+	)
+	!<sys-apps/baselayout-2.1-r1
+	!<sys-fs/udev-init-scripts-27"
+DEPEND="${COMMON_DEPEND}
+	virtual/os-headers
+	ncurses? ( virtual/pkgconfig )"
+RDEPEND="${COMMON_DEPEND}
+	!prefix? (
+		kernel_linux? (
+			>=sys-apps/sysvinit-2.86-r6[selinux?]
+			virtual/tmpfiles
+		)
+		kernel_FreeBSD? ( sys-freebsd/freebsd-sbin )
+	)
+	selinux? (
+		sec-policy/selinux-base-policy
+		sec-policy/selinux-openrc
+	)
+"
+
+PDEPEND="netifrc? ( net-misc/netifrc )"
+
+src_prepare() {
+	default
+
+	sed -i 's:0444:0644:' mk/sys.mk || die
+
+	if [[ ${PV} == "9999" ]] ; then
+		local ver="git-${EGIT_VERSION:0:6}"
+		sed -i "/^GITVER[[:space:]]*=/s:=.*:=${ver}:" mk/gitver.mk || die
+	fi
+}
+
+src_compile() {
+	unset LIBDIR #266688
+
+	MAKE_ARGS="${MAKE_ARGS}
+		LIBNAME=$(get_libdir)
+		LIBEXECDIR=${EPREFIX}/$(get_libdir)/rc
+		MKNET=$(usex newnet)
+		MKSELINUX=$(usex selinux)
+		MKAUDIT=$(usex audit)
+		MKPAM=$(usev pam)
+		MKSTATICLIBS=$(usex static-libs)"
+
+	local brand="Unknown"
+	if use kernel_linux ; then
+		MAKE_ARGS="${MAKE_ARGS} OS=Linux"
+		brand="Linux"
+	elif use kernel_FreeBSD ; then
+		MAKE_ARGS="${MAKE_ARGS} OS=FreeBSD"
+		brand="FreeBSD"
+	fi
+	export BRANDING="Gentoo ${brand}"
+	use prefix && MAKE_ARGS="${MAKE_ARGS} MKPREFIX=yes PREFIX=${EPREFIX}"
+	export DEBUG=$(usev debug)
+	export MKTERMCAP=$(usev ncurses)
+
+	tc-export CC AR RANLIB
+	emake ${MAKE_ARGS}
+}
+
+# set_config <file> <option name> <yes value> <no value> test
+# a value of "#" will just comment out the option
+set_config() {
+	local file="${ED}/$1" var=$2 val com
+	eval "${@:5}" && val=$3 || val=$4
+	[[ ${val} == "#" ]] && com="#" && val='\2'
+	sed -i -r -e "/^#?${var}=/{s:=([\"'])?([^ ]*)\1?:=\1${val}\1:;s:^#?:${com}:}" "${file}"
+}
+
+set_config_yes_no() {
+	set_config "$1" "$2" YES NO "${@:3}"
+}
+
+src_install() {
+	emake ${MAKE_ARGS} DESTDIR="${D}" install
+
+	# move the shared libs back to /usr so ldscript can install
+	# more of a minimal set of files
+	# disabled for now due to #270646
+	#mv "${ED}"/$(get_libdir)/lib{einfo,rc}* "${ED}"/usr/$(get_libdir)/ || die
+	#gen_usr_ldscript -a einfo rc
+	gen_usr_ldscript libeinfo.so
+	gen_usr_ldscript librc.so
+
+	if ! use kernel_linux; then
+		keepdir /$(get_libdir)/rc/init.d
+	fi
+	keepdir /$(get_libdir)/rc/tmp
+
+	# Backup our default runlevels
+	dodir /usr/share/"${PN}"
+	cp -PR "${ED}"/etc/runlevels "${ED}"/usr/share/${PN} || die
+	rm -rf "${ED}"/etc/runlevels
+
+	# Setup unicode defaults for silly unicode users
+	set_config_yes_no /etc/rc.conf unicode use unicode
+
+	# Cater to the norm
+	set_config_yes_no /etc/conf.d/keymaps windowkeys '(' use x86 '||' use amd64 ')'
+
+	# On HPPA, do not run consolefont by default (bug #222889)
+	if use hppa; then
+		rm -f "${ED}"/usr/share/openrc/runlevels/boot/consolefont
+	fi
+
+	# Support for logfile rotation
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}"/openrc.logrotate openrc
+
+	# install gentoo pam.d files
+	newpamd "${FILESDIR}"/start-stop-daemon.pam start-stop-daemon
+	newpamd "${FILESDIR}"/start-stop-daemon.pam supervise-daemon
+
+	# install documentation
+	dodoc ChangeLog *.md
+	if use newnet; then
+		dodoc README.newnet
+	fi
+}
+
+add_boot_init() {
+	local initd=$1
+	local runlevel=${2:-boot}
+	# if the initscript is not going to be installed and is not
+	# currently installed, return
+	[[ -e "${ED}"/etc/init.d/${initd} || -e "${EROOT}"etc/init.d/${initd} ]] \
+		|| return
+	[[ -e "${EROOT}"etc/runlevels/${runlevel}/${initd} ]] && return
+
+	# if runlevels dont exist just yet, then create it but still flag
+	# to pkg_postinst that it needs real setup #277323
+	if [[ ! -d "${EROOT}"etc/runlevels/${runlevel} ]] ; then
+		mkdir -p "${EROOT}"etc/runlevels/${runlevel}
+		touch "${EROOT}"etc/runlevels/.add_boot_init.created
+	fi
+
+	elog "Auto-adding '${initd}' service to your ${runlevel} runlevel"
+	ln -snf /etc/init.d/${initd} "${EROOT}"etc/runlevels/${runlevel}/${initd}
+}
+add_boot_init_mit_config() {
+	local config=$1 initd=$2
+	if [[ -e ${EROOT}${config} ]] ; then
+		if [[ -n $(sed -e 's:#.*::' -e '/^[[:space:]]*$/d' "${EROOT}"${config}) ]] ; then
+			add_boot_init ${initd}
+		fi
+	fi
+}
+
+pkg_preinst() {
+	local f LIBDIR=$(get_libdir)
+
+	# avoid default thrashing in conf.d files when possible #295406
+	if [[ -e "${EROOT}"etc/conf.d/hostname ]] ; then
+		(
+		unset hostname HOSTNAME
+		source "${EROOT}"etc/conf.d/hostname
+		: ${hostname:=${HOSTNAME}}
+		[[ -n ${hostname} ]] && set_config /etc/conf.d/hostname hostname "${hostname}"
+		)
+	fi
+
+	# set default interactive shell to sulogin if it exists
+	set_config /etc/rc.conf rc_shell /sbin/sulogin "#" test -e /sbin/sulogin
+
+	# termencoding was added in 0.2.1 and needed in boot
+	has_version ">=sys-apps/openrc-0.2.1" || add_boot_init termencoding
+
+	# swapfiles was added in 0.9.9 and needed in boot (february 2012)
+	has_version ">=sys-apps/openrc-0.9.9" || add_boot_init swapfiles
+
+	if ! has_version ">=sys-apps/openrc-0.11"; then
+		add_boot_init sysfs sysinit
+	fi
+
+	if ! has_version ">=sys-apps/openrc-0.11.3" ; then
+		migrate_udev_mount_script
+		add_boot_init tmpfiles.setup boot
+	fi
+
+	# these were added in 0.12.
+	if ! has_version ">=sys-apps/openrc-0.12"; then
+		add_boot_init loopback
+		add_boot_init tmpfiles.dev sysinit
+
+		# ensure existing /etc/conf.d/net is not removed
+		# undoes the hack to get around CONFIG_PROTECT in openrc-0.11.8 and earlier
+		# this needs to stay in openrc ebuilds for a long time. :(
+		# Added in 0.12.
+		if [[ -f "${EROOT}"etc/conf.d/net ]]; then
+			einfo "Modifying conf.d/net to keep it from being removed"
+			cat <<-EOF >>"${EROOT}"etc/conf.d/net
+
+# The network scripts are now part of net-misc/netifrc
+# In order to avoid sys-apps/${P} from removing this file, this comment was
+# added; you can safely remove this comment.  Please see
+# /usr/share/doc/netifrc*/README* for more information.
+EOF
+		fi
+	fi
+	has_version ">=sys-apps/openrc-0.14" || add_boot_init binfmt
+
+	if ! has_version ">=sys-apps/openrc-0.18.3"; then
+		add_boot_init mtab
+		if [[ -f "${EROOT}"etc/mtab ]] && [[ ! -L "${EROOT}"etc/mtab ]]; then
+			ewarn "${EROOT}etc/mtab will be replaced with a"
+			ewarn "symbolic link to /proc/self/mounts on the next"
+			ewarn "reboot."
+			ewarn "Change the setting in ${EROOT}etc/conf.d/mtab"
+			ewarn "if you do not want this to happen."
+		fi
+	fi
+}
+
+# >=OpenRC-0.11.3 requires udev-mount to be in the sysinit runlevel with udev.
+migrate_udev_mount_script() {
+	if [ -e "${EROOT}"etc/runlevels/sysinit/udev -a \
+		! -e "${EROOT}"etc/runlevels/sysinit/udev-mount ]; then
+		add_boot_init udev-mount sysinit
+	fi
+	return 0
+}
+
+pkg_postinst() {
+	local LIBDIR=$(get_libdir)
+
+	# Make our runlevels if they don't exist
+	if [[ ! -e "${EROOT}"etc/runlevels ]] || [[ -e "${EROOT}"etc/runlevels/.add_boot_init.created ]] ; then
+		einfo "Copying across default runlevels"
+		cp -RPp "${EROOT}"usr/share/${PN}/runlevels "${EROOT}"etc
+		rm -f "${EROOT}"etc/runlevels/.add_boot_init.created
+	else
+		if [[ ! -e "${EROOT}"etc/runlevels/sysinit/devfs ]] ; then
+			mkdir -p "${EROOT}"etc/runlevels/sysinit
+			cp -RPp "${EROOT}"usr/share/${PN}/runlevels/sysinit/* \
+				"${EROOT}"etc/runlevels/sysinit
+		fi
+		if [[ ! -e "${EROOT}"etc/runlevels/shutdown/mount-ro ]] ; then
+			mkdir -p "${EROOT}"etc/runlevels/shutdown
+			cp -RPp "${EROOT}"usr/share/${PN}/runlevels/shutdown/* \
+				"${EROOT}"etc/runlevels/shutdown
+		fi
+		if [[ ! -e "${EROOT}"etc/runlevels/nonetwork/local ]]; then
+			cp -RPp "${EROOT}"usr/share/${PN}/runlevels/nonetwork \
+				"${EROOT}"etc/runlevels
+		fi
+	fi
+
+	if use hppa; then
+		elog "Setting the console font does not work on all HPPA consoles."
+		elog "You can still enable it by running:"
+		elog "# rc-update add consolefont boot"
+	fi
+
+	# Handle the conf.d/local.{start,stop} -> local.d transition
+	if path_exists -o "${EROOT}"etc/conf.d/local.{start,stop} ; then
+		elog "Moving your ${EROOT}etc/conf.d/local.{start,stop}"
+		elog "files to ${EROOT}etc/local.d"
+		mv "${EROOT}"etc/conf.d/local.start "${EROOT}"etc/local.d/baselayout1.start
+		mv "${EROOT}"etc/conf.d/local.stop "${EROOT}"etc/local.d/baselayout1.stop
+		chmod +x "${EROOT}"etc/local.d/*{start,stop}
+	fi
+
+	if use kernel_linux && [[ "${EROOT}" = "/" ]]; then
+		if ! /$(get_libdir)/rc/sh/migrate-to-run.sh; then
+			ewarn "The dependency data could not be migrated to /run/openrc."
+			ewarn "This means you need to reboot your system."
+		fi
+	fi
+
+	# update the dependency tree after touching all files #224171
+	[[ "${EROOT}" = "/" ]] && "${EROOT}/${LIBDIR}"/rc/bin/rc-depend -u
+
+	if ! use newnet && ! use netifrc; then
+		ewarn "You have emerged OpenRc without network support. This"
+		ewarn "means you need to SET UP a network manager such as"
+		ewarn "	net-misc/netifrc, net-misc/dhcpcd, net-misc/wicd,"
+		ewarn "net-misc/NetworkManager, or net-vpn/badvpn."
+		ewarn "Or, you have the option of emerging openrc with the newnet"
+		ewarn "use flag and configuring /etc/conf.d/network and"
+		ewarn "/etc/conf.d/staticroute if you only use static interfaces."
+		ewarn
+	fi
+
+	if use newnet && [ ! -e "${EROOT}"etc/runlevels/boot/network ]; then
+		ewarn "Please add the network service to your boot runlevel"
+		ewarn "as soon as possible. Not doing so could leave you with a system"
+		ewarn "without networking."
+		ewarn
+	fi
+}