[gentoo-commits] repo/gentoo:master commit in: games-strategy/asc/

["Austin English" <wizardedit@gentoo.org>]

commit:     9945a6cfdaa39ac47f1c5e11a30402cb412c53e1
Author:     Austin English <wizardedit <AT> gentoo <DOT> org>
AuthorDate: Thu Sep  7 17:39:27 2017 +0000
Commit:     Austin English <wizardedit <AT> gentoo <DOT> org>
CommitDate: Thu Sep  7 21:04:16 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9945a6cf

games-strategy/asc: remove deprecated games eclass

Also update to EAPI 6

Gentoo-Bug: https://bugs.gentoo.org/574082
Package-Manager: Portage-2.3.6, Repoman-2.3.2

 games-strategy/asc/asc-2.6.0.0-r2.ebuild | 73 ++++++++++++++++++++++++++++++++
 1 file changed, 73 insertions(+)

diff --git a/games-strategy/asc/asc-2.6.0.0-r2.ebuild b/games-strategy/asc/asc-2.6.0.0-r2.ebuild
new file mode 100644
index 00000000000..9f44b9d7d53
--- /dev/null
+++ b/games-strategy/asc/asc-2.6.0.0-r2.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+WX_GTK_VER=3.0
+inherit eutils toolchain-funcs flag-o-matic wxwidgets
+
+DESCRIPTION="turn based strategy game designed in the tradition of the Battle Isle series"
+HOMEPAGE="http://www.asc-hq.org/"
+SRC_URI="mirror://sourceforge/asc-hq/${P}.tar.bz2
+	http://www.asc-hq.org/music/frontiers.ogg
+	http://www.asc-hq.org/music/time_to_strike.ogg
+	http://www.asc-hq.org/music/machine_wars.ogg"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+RDEPEND="app-arch/bzip2
+	dev-games/physfs
+	dev-lang/lua:0
+	dev-libs/boost
+	dev-libs/expat
+	dev-libs/libsigc++:1.2
+	media-libs/libpng:0
+	media-libs/libsdl[video]
+	media-libs/sdl-image[gif,jpeg,png]
+	media-libs/sdl-mixer[vorbis]
+	media-libs/sdl-sound
+	media-libs/freetype
+	media-libs/xvid
+	x11-libs/wxGTK:${WX_GTK_VER}[X]"
+
+DEPEND="${RDEPEND}
+	app-arch/zip
+	dev-lang/perl
+	virtual/pkgconfig"
+
+PATCHES=( "${FILESDIR}/"/${P}-gcc6-nothrow-in-dtors.patch )
+
+src_unpack() {
+	local f
+
+	unpack ${P}.tar.bz2
+	for f in ${A}
+	do
+		case ${f} in
+		*ogg)
+			cp "${DISTDIR}/${f}" "${S}/data/music" || die
+			;;
+		esac
+	done
+}
+
+src_configure() {
+	need-wxwidgets unicode
+	# Added --disable-paraguitest for bugs 26402 and 4488
+	# Added --disable-paragui for bug 61154 since it's not really used much
+	# and the case is well documented at http://www.asc-hq.org/
+	if [[ $(gcc-major-version) -eq 4 ]] ; then
+		replace-flags -O3 -O2
+	fi
+	econf \
+		--disable-paraguitest \
+		--disable-paragui \
+		--datadir="/usr/share"
+}
+
+src_install() {
+	default
+	dodoc -r doc/*
+}