From mboxrd@z Thu Jan  1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-969759-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
	(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
	(No client certificate requested)
	by finch.gentoo.org (Postfix) with ESMTPS id C24BF1396D0
	for <garchives@archives.gentoo.org>; Wed, 30 Aug 2017 05:51:01 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
	by pigeon.gentoo.org (Postfix) with SMTP id EA566E0CEB;
	Wed, 30 Aug 2017 05:51:00 +0000 (UTC)
Received: from smtp.gentoo.org (smtp.gentoo.org [140.211.166.183])
	(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
	(No client certificate requested)
	by pigeon.gentoo.org (Postfix) with ESMTPS id B5351E0CEB
	for <gentoo-commits@lists.gentoo.org>; Wed, 30 Aug 2017 05:51:00 +0000 (UTC)
Received: from oystercatcher.gentoo.org (unknown [IPv6:2a01:4f8:202:4333:225:90ff:fed9:fc84])
	(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
	(No client certificate requested)
	by smtp.gentoo.org (Postfix) with ESMTPS id 1977F33D3C7
	for <gentoo-commits@lists.gentoo.org>; Wed, 30 Aug 2017 05:50:59 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
	by oystercatcher.gentoo.org (Postfix) with ESMTP id 33286878B
	for <gentoo-commits@lists.gentoo.org>; Wed, 30 Aug 2017 05:50:56 +0000 (UTC)
From: "Jeroen Roovers" <jer@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Jeroen Roovers" <jer@gentoo.org>
Message-ID: <1504072235.804e51e6b4b5dbd6e51bb06c1ce267945e1f7c10.jer@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: net-analyzer/wireshark/
X-VCS-Repository: repo/gentoo
X-VCS-Files: net-analyzer/wireshark/Manifest net-analyzer/wireshark/wireshark-2.2.9.ebuild
X-VCS-Directories: net-analyzer/wireshark/
X-VCS-Committer: jer
X-VCS-Committer-Name: Jeroen Roovers
X-VCS-Revision: 804e51e6b4b5dbd6e51bb06c1ce267945e1f7c10
X-VCS-Branch: master
Date: Wed, 30 Aug 2017 05:50:56 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Archives-Salt: 0b9d64d7-c5d9-4cbe-bf95-8dbf298304e6
X-Archives-Hash: d708209ae5496ae9c420ee8f5dfd9d8e

commit:     804e51e6b4b5dbd6e51bb06c1ce267945e1f7c10
Author:     Jeroen Roovers <jer <AT> gentoo <DOT> org>
AuthorDate: Wed Aug 30 05:50:35 2017 +0000
Commit:     Jeroen Roovers <jer <AT> gentoo <DOT> org>
CommitDate: Wed Aug 30 05:50:35 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=804e51e6

net-analyzer/wireshark: Old.

Package-Manager: Portage-2.3.8, Repoman-2.3.3

 net-analyzer/wireshark/Manifest               |   1 -
 net-analyzer/wireshark/wireshark-2.2.9.ebuild | 259 --------------------------
 2 files changed, 260 deletions(-)

diff --git a/net-analyzer/wireshark/Manifest b/net-analyzer/wireshark/Manifest
index 40c72c80708..9b783365f9f 100644
--- a/net-analyzer/wireshark/Manifest
+++ b/net-analyzer/wireshark/Manifest
@@ -1,3 +1,2 @@
 DIST wireshark-2.2.7.tar.bz2 32309420 SHA256 689ddf62221b152779d8846ab5b2063cc7fd41ec1a9f04eefab09b5d5486dbb5 SHA512 417836810eb895b3f2a6ac1cfd138fb0275382ea2edc60fc5f5e5f8ce433b56b8120aa8b58b4f77296986630fdf49e4c5c3859b2c2c5e26b1ce0651393b7d716 WHIRLPOOL 0361821da9c113a8de1339cc48cae0291be84bcffb1ba34b1fc3f457b22525329e954a2060f7eef25bca550d0ccdaf4a9e9587d35394b0abd9b0d38bc6023e44
-DIST wireshark-2.2.9.tar.bz2 32341866 SHA256 c8b32c0e7d44a277e737c53d9d142ad3fe4265338f25a7fd8c891f58a7633fc2 SHA512 ee680ee5da66e251b4bb647296da2c8b9d6ec6b1b74d41d8ac05fd77ce8bec7cd9a5a83bf3769bec4a53e0b50086c6674c0c6fa659b752569d1508f57d0c07c8 WHIRLPOOL fc6b954a432f9994c214fbb3fbccca6d53c09c0ecdf8727fb262d687713f3d6b9b858799853d9e2746686bb7d29be46629f423fb513c57d1abf0b6da3065e638
 DIST wireshark-2.4.1.tar.xz 28780384 SHA256 02ddbcf9b10f9dfa1e36eec00fe00cb5b5ce8e07203843baf056ac7909911fcd SHA512 66f3f9abecc00c4c153c61f42739522b091ba06cc68b6bd79fe45a1064192fbb88e38e96d4df6722255b06a3520f23d2db6c5fa5e4faf5e8641cf2f5dce10056 WHIRLPOOL 3cdf5b1a3fe95bfaf2416f1ea1310999dd6d34babd5c040797ae4b2ea5faee7b90797a6507fed9be77e6038e90acd052484982b2dc62d9da67ac1e2520ef94c2

diff --git a/net-analyzer/wireshark/wireshark-2.2.9.ebuild b/net-analyzer/wireshark/wireshark-2.2.9.ebuild
deleted file mode 100644
index e6842e6fd3b..00000000000
--- a/net-analyzer/wireshark/wireshark-2.2.9.ebuild
+++ /dev/null
@@ -1,259 +0,0 @@
-# Copyright 1999-2017 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-inherit autotools eutils fcaps flag-o-matic multilib qmake-utils user
-
-DESCRIPTION="A network protocol analyzer formerly known as ethereal"
-HOMEPAGE="https://www.wireshark.org/"
-SRC_URI="${HOMEPAGE}download/src/all-versions/${P/_/}.tar.bz2"
-
-LICENSE="GPL-2"
-SLOT="0/${PV}"
-KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
-IUSE="
-	adns androiddump +caps ciscodump cpu_flags_x86_sse4_2 crypt doc doc-pdf
-	geoip +gtk kerberos lua +netlink +pcap portaudio +qt5 sbc selinux smi
-	libssh randpkt randpktdump sshdump ssl tfshark zlib
-"
-REQUIRED_USE="
-	ciscodump? ( libssh )
-	sshdump? ( libssh )
-	ssl? ( crypt )
-"
-
-S=${WORKDIR}/${P/_/}
-
-CDEPEND="
-	>=dev-libs/glib-2.14:2
-	netlink? ( dev-libs/libnl:3 )
-	adns? ( >=net-dns/c-ares-1.5 )
-	crypt? ( dev-libs/libgcrypt:0 )
-	caps? ( sys-libs/libcap )
-	geoip? ( dev-libs/geoip )
-	gtk? (
-		x11-libs/gdk-pixbuf
-		x11-libs/gtk+:3
-		x11-libs/pango
-		x11-misc/xdg-utils
-	)
-	kerberos? ( virtual/krb5 )
-	libssh? ( >=net-libs/libssh-0.6 )
-	lua? ( >=dev-lang/lua-5.1:* )
-	pcap? ( net-libs/libpcap )
-	portaudio? ( media-libs/portaudio )
-	qt5? (
-		dev-qt/qtcore:5
-		dev-qt/qtgui:5
-		dev-qt/qtmultimedia:5
-		dev-qt/qtprintsupport:5
-		dev-qt/qtwidgets:5
-		media-libs/speex
-		x11-misc/xdg-utils
-	)
-	sbc? ( media-libs/sbc )
-	smi? ( net-libs/libsmi )
-	ssl? ( net-libs/gnutls:= )
-	zlib? ( sys-libs/zlib !=sys-libs/zlib-1.2.4 )
-"
-# We need perl for `pod2html`.  The rest of the perl stuff is to block older
-# and broken installs. #455122
-DEPEND="
-	${CDEPEND}
-	dev-lang/perl
-	!<virtual/perl-Pod-Simple-3.170
-	!<perl-core/Pod-Simple-3.170
-	doc? (
-		app-doc/doxygen
-		app-text/asciidoc
-		dev-libs/libxml2
-		dev-libs/libxslt
-		doc-pdf? ( dev-java/fop )
-		www-client/lynx
-	)
-	qt5? (
-		dev-qt/linguist-tools:5
-	)
-	sys-devel/bison
-	sys-devel/flex
-	virtual/pkgconfig
-"
-RDEPEND="
-	${CDEPEND}
-	gtk? ( virtual/freedesktop-icon-theme )
-	qt5? ( virtual/freedesktop-icon-theme )
-	selinux? ( sec-policy/selinux-wireshark )
-"
-PATCHES=(
-	"${FILESDIR}"/${PN}-1.99.8-qtchooser.patch
-	"${FILESDIR}"/${PN}-2.1.0-sse4_2-r1.patch
-	"${FILESDIR}"/${PN}-99999999-androiddump.patch
-)
-
-pkg_setup() {
-	enewgroup wireshark
-}
-
-src_prepare() {
-	default
-
-	eautoreconf
-}
-
-src_configure() {
-	local myconf
-
-	# Workaround bug #213705. If krb5-config --libs has -lcrypto then pass
-	# --with-ssl to ./configure. (Mimics code from acinclude.m4).
-	if use kerberos; then
-		case $(krb5-config --libs) in
-			*-lcrypto*)
-				ewarn "Kerberos was built with ssl support: linkage with openssl is enabled."
-				ewarn "Note there are annoying license incompatibilities between the OpenSSL"
-				ewarn "license and the GPL, so do your check before distributing such package."
-				myconf+=( "--with-ssl" )
-				;;
-		esac
-	fi
-
-	# Enable wireshark binary with any supported GUI toolkit (bug #473188)
-	if use gtk || use qt5; then
-		myconf+=( "--enable-wireshark" )
-	else
-		myconf+=( "--disable-wireshark" )
-	fi
-
-	if ! use qt5; then
-		myconf+=( "--with-qt=no" )
-	fi
-
-	if use qt5; then
-		export QT_MIN_VERSION=5.3.0
-		append-cxxflags -fPIC -DPIC
-	fi
-
-	# Hack around inability to disable doxygen/fop doc generation
-	use doc || export ac_cv_prog_HAVE_DOXYGEN=false
-	use doc-pdf || export ac_cv_prog_HAVE_FOP=false
-
-	# dumpcap requires libcap
-	# --disable-profile-build bugs #215806, #292991, #479602
-	econf \
-		$(use androiddump && use pcap && echo --enable-androiddump-use-libpcap=yes) \
-		$(use_enable androiddump) \
-		$(use_enable ciscodump) \
-		$(use_enable randpkt) \
-		$(use_enable randpktdump) \
-		$(use_enable sshdump) \
-		$(use_enable tfshark) \
-		$(use_with adns c-ares) \
-		$(use_with caps libcap) \
-		$(use_with crypt gcrypt) \
-		$(use_with geoip) \
-		$(use_with gtk gtk 3) \
-		$(use_with kerberos krb5) \
-		$(use_with libssh ssh) \
-		$(use_with lua) \
-		$(use_with pcap dumpcap-group wireshark) \
-		$(use_with pcap) \
-		$(use_with portaudio) \
-		$(use_with sbc) \
-		$(use_with smi libsmi) \
-		$(use_with ssl gnutls) \
-		$(use_with zlib) \
-		$(usex cpu_flags_x86_sse4_2 --enable-sse4_2 '') \
-		$(usex netlink --with-libnl=3 --without-libnl) \
-		$(usex qt5 --with-qt=5 '') \
-		$(usex qt5 LRELEASE=$(qt5_get_bindir)/lrelease '') \
-		$(usex qt5 MOC=$(qt5_get_bindir)/moc '') \
-		$(usex qt5 RCC=$(qt5_get_bindir)/rcc '') \
-		$(usex qt5 UIC=$(qt5_get_bindir)/uic '') \
-		--disable-profile-build \
-		--disable-warnings-as-errors \
-		--sysconfdir="${EPREFIX}"/etc/wireshark \
-		${myconf[@]}
-}
-
-src_compile() {
-	default
-
-	if use doc; then
-		emake -j1 -C docbook
-		if use doc-pdf; then
-			addpredict "/root/.java"
-			emake -C docbook all-pdf
-		fi
-	fi
-}
-
-src_install() {
-	default
-
-	# FAQ is not required as is installed from help/faq.txt
-	dodoc AUTHORS ChangeLog NEWS README{,.bsd,.linux,.macos,.vmware} \
-		doc/{randpkt.txt,README*}
-
-	if use doc; then
-		docinto /usr/share/doc/${PF}/html
-		dodoc -r docbook/{release-notes.html,ws{d,u}g_html{,_chunked}}
-		if use doc-pdf; then
-			docinto /usr/share/doc/${PF}/pdf/
-			dodoc docbook/{developer,user}-guide-{a4,us}.pdf docbook/release-notes.pdf
-		fi
-	fi
-
-	# install headers
-	local wsheader
-	for wsheader in \
-		config.h \
-		epan/*.h \
-		epan/crypt/*.h \
-		epan/dfilter/*.h \
-		epan/dissectors/*.h \
-		epan/ftypes/*.h \
-		epan/wmem/*.h \
-		register.h \
-		wiretap/*.h \
-		ws_diag_control.h \
-		ws_symbol_export.h \
-		wsutil/*.h
-	do
-		insinto /usr/include/wireshark/$( dirname ${wsheader} )
-		doins ${wsheader}
-	done
-
-	#with the above this really shouldn't be needed, but things may be looking in wiretap/ instead of wireshark/wiretap/
-	insinto /usr/include/wiretap
-	doins wiretap/wtap.h
-
-	if use gtk || use qt5; then
-		local c d
-		for c in hi lo; do
-			for d in 16 32 48; do
-				insinto /usr/share/icons/${c}color/${d}x${d}/apps
-				newins image/${c}${d}-app-wireshark.png wireshark.png
-			done
-		done
-		for d in 16 24 32 48 64 128 256 ; do
-			insinto /usr/share/icons/hicolor/${d}x${d}/mimetypes
-			newins image/WiresharkDoc-${d}.png application-vnd.tcpdump.pcap.png
-		done
-	fi
-
-	prune_libtool_files
-}
-
-pkg_postinst() {
-	# Add group for users allowed to sniff.
-	enewgroup wireshark
-
-	if use pcap; then
-		fcaps -o 0 -g wireshark -m 4710 -M 0710 \
-			cap_dac_read_search,cap_net_raw,cap_net_admin \
-			"${EROOT}"/usr/bin/dumpcap
-	fi
-
-	ewarn "NOTE: To capture traffic with wireshark as normal user you have to"
-	ewarn "add yourself to the wireshark group. This security measure ensures"
-	ewarn "that only trusted users are allowed to sniff your traffic."
-}