[gentoo-commits] repo/gentoo:master commit in: dev-libs/sink/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     e0e7c1b084b748b4c84d65177fdce88645111aca
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Sat Aug 19 19:31:56 2017 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Sat Aug 19 20:20:05 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e0e7c1b0

dev-libs/sink: Add missing DEPENDs, workaround kde5.eclass for now

What a great new way for upstream to hide actual runtime necessities!
'example implementations' much.

Gentoo-bug: 624436
Package-Manager: Portage-2.3.8, Repoman-2.3.3

 dev-libs/sink/sink-0.3.0-r1.ebuild | 49 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

diff --git a/dev-libs/sink/sink-0.3.0-r1.ebuild b/dev-libs/sink/sink-0.3.0-r1.ebuild
new file mode 100644
index 00000000000..f5b019abd29
--- /dev/null
+++ b/dev-libs/sink/sink-0.3.0-r1.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+KDE_TEST="true" # build breaks otherwise. tests not isolated.
+inherit kde5
+
+DESCRIPTION="A data access layer handling synchronization, caching and indexing"
+SRC_URI="mirror://kde/unstable/${PN}/${PV}/src/${P}.tar.xz"
+
+LICENSE="LGPL-2+"
+KEYWORDS="~amd64"
+IUSE=""
+
+# qtgui is bogus but is required because something else in the deptree
+# uses it as a public dependency but doesn't search for it properly
+RDEPEND="
+	$(add_frameworks_dep kcoreaddons)
+	$(add_kdeapps_dep kcontacts)
+	$(add_kdeapps_dep kmime)
+	$(add_qt_dep qtgui)
+	$(add_qt_dep qtnetwork)
+	dev-db/lmdb:=
+	dev-libs/flatbuffers
+	dev-libs/kasync
+	net-libs/kdav2
+	net-libs/kimap2
+	net-misc/curl
+	sys-libs/readline:0=
+"
+DEPEND="${RDEPEND}"
+
+# fails to build
+RESTRICT+=" test"
+
+src_prepare() {
+	kde5_src_prepare
+	# FIXME: sink is useless without its 'examples'. Workaround our eclass
+	sed -i -e "/add_subdirectory(examples)/ s/#DONOTCOMPILE //" \
+		CMakeLists.txt || die "Failed to fix CMakeLists.txt"
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_DISABLE_FIND_PACKAGE_Libgit2=ON
+	)
+	kde5_src_configure
+}