[gentoo-commits] repo/gentoo:master commit in: net-libs/tox/

["Michał Górny" <mgorny@gentoo.org>]

commit:     e6517297dc7dd3e056092286087e913ca155d8e5
Author:     Zetok Zalbavar <zetok <AT> openmailbox <DOT> org>
AuthorDate: Wed Aug 16 21:22:49 2017 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Fri Aug 18 22:13:30 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e6517297

net-libs/tox: bump version to v0.1.10

 net-libs/tox/Manifest          |  1 +
 net-libs/tox/tox-0.1.10.ebuild | 76 ++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 77 insertions(+)

diff --git a/net-libs/tox/Manifest b/net-libs/tox/Manifest
index 20709e1d7f3..4cf9effb75d 100644
--- a/net-libs/tox/Manifest
+++ b/net-libs/tox/Manifest
@@ -1,3 +1,4 @@
+DIST c-toxcore-0.1.10.tar.gz 820090 SHA256 4e9a2881dd0ea8e65a35fc9621644ccf500c1797a2d37983b0057ed3be971299 SHA512 428fee2d811d0b6d5d005f082aa06f95765794b1a8bc77ec4411bb9ec9085b99675535b88db50f5ad7313850a0bb3c54c4e2e8d8864cea7c0c7d81be9879b157 WHIRLPOOL 122a6f89c1d34afc685b80e74b9c20e3175ba49865d25a580f0e850d7851304b9077842f23084d4691efa9896d33ddfe136deac034d0eb51f821622e068bc988
 DIST tox-0.1.1.tar.gz 416532 SHA256 c3a6329731a35c1e9cd8ad204407ddbc408f325056de2b1baa1fc44bc8bfcb37 SHA512 5bdaf047594e943f854fda0f0265167e0dccf05fedfec6b4d9b628b242de23f9dd9b870bbdcca4cb02f9742fa2472e4c7e1047370732cb2ee529467f15e81fc1 WHIRLPOOL 32ee00f6eaf98473ce3de080ba36185da2c225b2037574b55060a12e88876fb1f7df492614fbbb493ba85a44a319f3e0c254c0daec1e8cc18472ba075834039f
 DIST tox-0.1.2.tar.gz 417957 SHA256 605a462f77b497009217b8dbd01108d112e9a8b018473826379f9f4ffa5c0b66 SHA512 39c52dd205205e271b2b15db30a007af89ba9ede00e2717f3ec7431bbfec984984236a493f2a4943cb8deff5d8a4eba1949d9e8332caebadeb352c477b1a5208 WHIRLPOOL 78c72bb16ddc964ce7f69f0721ac864fe64e3c7635614e6ee325af26a8d8ef0142a6cc6f7fd31516ef3f3ce6e2366551a501052809716d72580d39f4e8baaf2a
 DIST tox-0.1.4.tar.lz 305312 SHA256 b27cba1719e06591fb7b3dbb757e3b9c531462adbb42fba572b35acb76f077d8 SHA512 8d094275cc56193d33f380eb3c8ba708ce7a94b01ba378d68707240efd1550dd0e4a0ffd0f97bedd96c5ce6145b27e14fdb5b570ed0e5247b01f5d4e15b4fe3a WHIRLPOOL a227d8ba321d6a69398c63f8c2720fb812198918c6b717a72b4b7863ef7a64e482cbf628b51018df10ace9000e5a8dd22edbc0a1c6ffecbcd0fd31aa31ea7d73

diff --git a/net-libs/tox/tox-0.1.10.ebuild b/net-libs/tox/tox-0.1.10.ebuild
new file mode 100644
index 00000000000..ce36d284017
--- /dev/null
+++ b/net-libs/tox/tox-0.1.10.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit autotools systemd user
+
+DESCRIPTION="Encrypted P2P, messaging, and audio/video calling platform"
+HOMEPAGE="https://tox.chat"
+SRC_URI="https://github.com/TokTok/c-toxcore/releases/download/v${PV}/c-toxcore-${PV}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0/0.1"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="+av daemon log-debug log-error log-info log-trace log-warn +no-log ntox static-libs test"
+
+REQUIRED_USE="^^ ( no-log log-trace log-debug log-info log-warn log-error )"
+
+RDEPEND="
+	av? ( media-libs/libvpx:=
+		media-libs/opus )
+	daemon? ( dev-libs/libconfig )
+	ntox? ( sys-libs/ncurses:0= )
+	>=dev-libs/libsodium-0.6.1:=[asm,urandom]"
+DEPEND="${RDEPEND}
+	test? ( dev-libs/check )
+	virtual/pkgconfig"
+
+S="${WORKDIR}/c-toxcore-${PV}"
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(usex log-trace "--enable-logging --with-log-level=TRACE" "") \
+		$(usex log-debug "--enable-logging --with-log-level=DEBUG" "") \
+		$(usex log-info "--enable-logging --with-log-level=INFO" "") \
+		$(usex log-warn "--enable-logging --with-log-level=WARNING" "") \
+		$(usex log-error "--enable-logging --with-log-level=ERROR" "") \
+		$(use_enable av) \
+		$(use_enable test tests) \
+		$(use_enable ntox) \
+		$(use_enable daemon) \
+		$(use_enable static-libs static)
+}
+
+src_install() {
+	default
+	if use daemon; then
+		newinitd "${FILESDIR}"/initd tox-dht-daemon
+		newconfd "${FILESDIR}"/confd tox-dht-daemon
+		insinto /etc
+		doins "${FILESDIR}"/tox-bootstrapd.conf
+		systemd_dounit "${FILESDIR}"/tox-bootstrapd.service
+	fi
+
+	find "${D}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	if use daemon; then
+		enewgroup ${PN}
+		enewuser ${PN} -1 -1 -1 ${PN}
+		if [[ -f ${EROOT%/}/var/lib/tox-dht-bootstrap/key ]]; then
+			ewarn "Backwards compatability with the bootstrap daemon might have been"
+			ewarn "broken a while ago. To resolve this issue, REMOVE the following files:"
+			ewarn "    ${EROOT%/}/var/lib/tox-dht-bootstrap/key"
+			ewarn "    ${EROOT%/}/etc/tox-bootstrapd.conf"
+			ewarn "    ${EROOT%/}/run/tox-dht-bootstrap/tox-dht-bootstrap.pid"
+			ewarn "Then just reinstall net-libs/tox"
+		fi
+	fi
+}