[gentoo-commits] repo/gentoo:master commit in: gnome-extra/gnome-characters/

["Gilles Dartiguelongue" <eva@gentoo.org>]

commit:     3c99fb0fb83e014f9d9f94b182dc1c886c84765f
Author:     Gilles Dartiguelongue <eva <AT> gentoo <DOT> org>
AuthorDate: Fri Aug 11 22:37:23 2017 +0000
Commit:     Gilles Dartiguelongue <eva <AT> gentoo <DOT> org>
CommitDate: Fri Aug 11 23:21:53 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=3c99fb0f

gnome-extra/gnome-characters: version bump 3.22.0 → 3.24.0

Small improvements and translations updates. Switch PYTHON_COMPAT to
python3 as generator scripts have explicity references to it.

Package-Manager: Portage-2.3.6, Repoman-2.3.3

 gnome-extra/gnome-characters/Manifest              |  1 +
 .../gnome-characters-3.24.0.ebuild                 | 56 ++++++++++++++++++++++
 2 files changed, 57 insertions(+)

diff --git a/gnome-extra/gnome-characters/Manifest b/gnome-extra/gnome-characters/Manifest
index 092abaa5ebe..5ba43ab4b60 100644
--- a/gnome-extra/gnome-characters/Manifest
+++ b/gnome-extra/gnome-characters/Manifest
@@ -1 +1,2 @@
 DIST gnome-characters-3.22.0.tar.xz 1481416 SHA256 0778b625646d6d934cf252d58a2e16403889da6bfc237bdca1d3cb3258f63d4e SHA512 c04d79f9b31601e127ae6103b2f473e2e4733facebf504189a8d5721a78b430883a0f790b58537eb7772c5a4ce72013183d037909f30a237cd1482c31144905f WHIRLPOOL 83e892f6f3f0f7c7f6171d9c049e1f029865dfcb6c998c16db5fb9c47ed550d307eb9113dc46324d5c1c3a487ee04a08f9e27357c25d120a577be86b18131b9f
+DIST gnome-characters-3.24.0.tar.xz 1490304 SHA256 9ef4ff28437a63a221c47189231909fb9e4cac838c5f3cf402906fb128b52596 SHA512 28531676e3ed89cea574f800a1f0e19106eb4ccb0edc62ea493bb6680fdbe3b1ed45c3cd865a637c059a89df63b980cd4a9d69d73049778c52725b1d38fdad9d WHIRLPOOL ee087ba7daac78fff365794f09e8e547aebe3bc9288602423a6bead3a5614d99fc620dadc705ba1abae15c1352c00bd93276d5ad82aad268d07a2bbecd5be5a2

diff --git a/gnome-extra/gnome-characters/gnome-characters-3.24.0.ebuild b/gnome-extra/gnome-characters/gnome-characters-3.24.0.ebuild
new file mode 100644
index 00000000000..d6daef0506e
--- /dev/null
+++ b/gnome-extra/gnome-characters/gnome-characters-3.24.0.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+VALA_USE_DEPEND="vapigen"
+PYTHON_COMPAT=( python{3_4,3_5} )
+
+inherit gnome2 python-any-r1 vala virtualx
+
+DESCRIPTION="Unicode character map viewer and library"
+HOMEPAGE="https://wiki.gnome.org/Design/Apps/CharacterMap"
+
+LICENSE="GPL-2 BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+
+RDEPEND="
+	>=dev-libs/gjs-1.43.3
+	>=dev-libs/glib-2.32:2
+	>=dev-libs/gobject-introspection-1.35.9:=
+	>=dev-libs/libunistring-0.9.5
+	>=x11-libs/gtk+-3.20:3[introspection]
+	>=x11-libs/pango-1.36[introspection]
+"
+DEPEND="${RDEPEND}
+	dev-libs/appstream-glib
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	test? (
+		${PYTHON_DEPS}
+		$(python_gen_any_dep 'dev-util/dogtail[${PYTHON_USEDEP}]') )
+"
+
+python_check_deps() {
+	use test && has_version "dev-util/dogtail[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	sed 's/print \(.*\)/print(\1)/' -i "${S}"/tests/smoke_test.py || die
+
+	gnome2_src_prepare
+	vala_src_prepare
+}
+
+src_configure() {
+	gnome2_src_configure $(use_enable test dogtail)
+}
+
+src_test() {
+	virtx emake check
+}