From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-966320-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
(No client certificate requested)
by finch.gentoo.org (Postfix) with ESMTPS id 62B591396D0
for <garchives@archives.gentoo.org>; Thu, 10 Aug 2017 19:58:27 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id 482811FC002;
Thu, 10 Aug 2017 19:58:26 +0000 (UTC)
Received: from smtp.gentoo.org (smtp.gentoo.org [140.211.166.183])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id F13BA1FC002
for <gentoo-commits@lists.gentoo.org>; Thu, 10 Aug 2017 19:58:25 +0000 (UTC)
Received: from oystercatcher.gentoo.org (oystercatcher.gentoo.org [148.251.78.52])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id 8DD873419D4
for <gentoo-commits@lists.gentoo.org>; Thu, 10 Aug 2017 19:58:24 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id 0E41A3E99
for <gentoo-commits@lists.gentoo.org>; Thu, 10 Aug 2017 19:58:23 +0000 (UTC)
From: "Dirkjan Ochtman" <djc@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Dirkjan Ochtman" <djc@gentoo.org>
Message-ID: <1502395094.0a16ae3418799bb39ce9cc3f5bee848803e3e06a.djc@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: dev-vcs/mercurial/
X-VCS-Repository: repo/gentoo
X-VCS-Files: dev-vcs/mercurial/Manifest dev-vcs/mercurial/mercurial-4.3.ebuild
X-VCS-Directories: dev-vcs/mercurial/
X-VCS-Committer: djc
X-VCS-Committer-Name: Dirkjan Ochtman
X-VCS-Revision: 0a16ae3418799bb39ce9cc3f5bee848803e3e06a
X-VCS-Branch: master
Date: Thu, 10 Aug 2017 19:58:23 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Archives-Salt: 6c466512-8276-43b5-85f1-c70a69e843bd
X-Archives-Hash: 68abaeabd2c03d489bfefcf03ee84d9b
commit: 0a16ae3418799bb39ce9cc3f5bee848803e3e06a
Author: Dirkjan Ochtman <djc <AT> gentoo <DOT> org>
AuthorDate: Thu Aug 10 19:57:21 2017 +0000
Commit: Dirkjan Ochtman <djc <AT> gentoo <DOT> org>
CommitDate: Thu Aug 10 19:58:14 2017 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=0a16ae34
dev-vcs/mercurial: version bump 4.3 with security issues (bug 627484)
Package-Manager: Portage-2.3.6, Repoman-2.3.1
dev-vcs/mercurial/Manifest | 1 +
dev-vcs/mercurial/mercurial-4.3.ebuild | 134 +++++++++++++++++++++++++++++++++
2 files changed, 135 insertions(+)
diff --git a/dev-vcs/mercurial/Manifest b/dev-vcs/mercurial/Manifest
index a7594e75d5c..ba851c077e7 100644
--- a/dev-vcs/mercurial/Manifest
+++ b/dev-vcs/mercurial/Manifest
@@ -3,3 +3,4 @@ DIST mercurial-4.1.3.tar.gz 5134965 SHA256 103d2ae187d5c94110c0e86ccc3b46f55fcd8
DIST mercurial-4.2.1.tar.gz 5317692 SHA256 d7d5572f5aa0797fbf2168440eaa51149df88645fe37af8b15fa660d9a8158a0 SHA512 0349fb5343210869bacb2247d30546676e5cf486f64fb8ebb2b1c6cdf7d564e7b754a43fb5b61c7d7e66a67609c514c8e15f415f4189bccbebb2fbb5a5474645 WHIRLPOOL f64df61fe2a10abca4765f150952e5d529034909666f1bee6df40d628af52d650086bd51c5d2db2e0ce2874f38fd439bb9d958bda3d2d63dccbf861b933d51f1
DIST mercurial-4.2.2.tar.gz 5319282 SHA256 b20132dec5ae6d27ee43a133144069895befe09f7e454bfa9e39950a185f0afe SHA512 16324fec97146d749fe6bdb4c35466f6f1786213451015a34d34f8a0d042870d7fc29b6fd74d720191d24e84e57b3d931bb58594bcd7a89399bfbb427e7af994 WHIRLPOOL 9a82b7af0ca793aa17cbcce184a4d292689cbc503ba16ab2a1d349397c2ea9b01d7585eb5a1c4f260145f42de2b34de0b577747ee7b47d2abcf1184c0dc3f71f
DIST mercurial-4.2.tar.gz 5303367 SHA256 23a412308fc9c2b354a0e91a89588a4af2af061b47da80bc4233ccb0cceef47d SHA512 bd03134a70fe0576a31d86cb6ca2d232b8f98bd9b038dc972a4d332889bb39c776f47d44ea9c45588d6e53590a8e3fbd48ca25238525919b8e44beab3d3c79cb WHIRLPOOL 930882698c0e662f5fadc8a57a14ce00270cce70f7a9f8f0081647a28c3558aeda1a4d7bc5aa7e264cb60ec85051dae6a16cc62df0f51be3cc406bf587ff5485
+DIST mercurial-4.3.tar.gz 5469979 SHA256 ebf11176e9b5354ec7a1bde6c5382c914d10c397410531faf89f8b5124a7cb65 SHA512 d74ae5f35d8c415c07737b59e6c5455963dfbf5d038c43d683fd34dd84423b9ccf9cd670667f458db20d8580fc7c7d9e5609d29d990e1e94683734694211c417 WHIRLPOOL 54583dbc826fdec3e737dc49d1a8ce180d29579d091c86e48a3b7c68bb4a2d399c5aff3b2ff0e30cd911e8955537a621c73c330d70a55f7efcdeafd21257178f
diff --git a/dev-vcs/mercurial/mercurial-4.3.ebuild b/dev-vcs/mercurial/mercurial-4.3.ebuild
new file mode 100644
index 00000000000..a04546c6f07
--- /dev/null
+++ b/dev-vcs/mercurial/mercurial-4.3.ebuild
@@ -0,0 +1,134 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 )
+PYTHON_REQ_USE="threads"
+
+inherit bash-completion-r1 elisp-common eutils distutils-r1 flag-o-matic
+
+DESCRIPTION="Scalable distributed SCM"
+HOMEPAGE="https://www.mercurial-scm.org/"
+SRC_URI="https://www.mercurial-scm.org/release/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="bugzilla emacs gpg test tk"
+
+RDEPEND="bugzilla? ( dev-python/mysql-python[${PYTHON_USEDEP}] )
+ gpg? ( app-crypt/gnupg )
+ tk? ( dev-lang/tk )
+ app-misc/ca-certificates"
+DEPEND="emacs? ( virtual/emacs )
+ test? ( app-arch/unzip
+ dev-python/pygments[${PYTHON_USEDEP}] )"
+
+SITEFILE="70${PN}-gentoo.el"
+
+PATCHES=( "${FILESDIR}/${PN}-3.0.1-po_fixes.patch" )
+
+python_prepare_all() {
+ # fix up logic that won't work in Gentoo Prefix (also won't outside in
+ # certain cases), bug #362891
+ sed -i -e 's:xcodebuild:nocodebuild:' setup.py || die
+
+ distutils-r1_python_prepare_all
+}
+
+python_configure_all() {
+ strip-flags -ftracer -ftree-vectorize
+ # Note: make it impl-conditional if py3 is supported
+ append-flags -fno-strict-aliasing
+
+ "${PYTHON}" setup.py build_mo || die
+}
+
+python_compile_all() {
+ rm -r contrib/{win32,macosx} || die
+ if use emacs; then
+ cd contrib || die
+ elisp-compile mercurial.el || die "elisp-compile failed!"
+ fi
+}
+
+python_install_all() {
+ distutils-r1_python_install_all
+
+ newbashcomp contrib/bash_completion hg
+
+ insinto /usr/share/zsh/site-functions
+ newins contrib/zsh_completion _hg
+
+ rm -f doc/*.?.txt
+ dodoc CONTRIBUTORS
+ cp hgweb*.cgi "${ED}"/usr/share/doc/${PF}/ || die
+
+ dobin hgeditor
+ dobin contrib/hgk
+ python_foreach_impl python_doscript contrib/hg-ssh
+
+ if use emacs; then
+ elisp-install ${PN} contrib/mercurial.el* || die "elisp-install failed!"
+ elisp-site-file-install "${FILESDIR}"/${SITEFILE}
+ fi
+
+ local RM_CONTRIB=(hgk hg-ssh bash_completion zsh_completion wix buildrpm plan9
+ *.el mercurial.spec)
+ for f in ${RM_CONTRIB[@]}; do
+ rm -r contrib/$f || die
+ done
+
+ dodoc -r contrib
+ docompress -x /usr/share/doc/${PF}/contrib
+ doman doc/*.?
+
+ insinto /etc/mercurial/hgrc.d
+ doins "${FILESDIR}/cacerts.rc"
+}
+
+src_test() {
+ pushd tests &>/dev/null || die
+ rm -rf *svn* # Subversion tests fail with 1.5
+ rm -f test-archive* # Fails due to verbose tar output changes
+ rm -f test-convert-baz* # GNU Arch baz
+ rm -f test-convert-cvs* # CVS
+ rm -f test-convert-darcs* # Darcs
+ rm -f test-convert-git* # git
+ rm -f test-convert-mtn* # monotone
+ rm -f test-convert-tla* # GNU Arch tla
+ #rm -f test-doctest* # doctest always fails with python 2.5.x
+ rm -f test-largefiles* # tends to time out
+
+ popd &>/dev/null || die
+ distutils-r1_src_test
+}
+
+python_test() {
+ local TEST_DIR
+
+ rm -rf "${TMPDIR}"/test
+ distutils_install_for_testing
+ cd tests || die
+ "${PYTHON}" run-tests.py --verbose \
+ --tmpdir="${TMPDIR}"/test \
+ --with-hg="${TEST_DIR}"/scripts/hg \
+ || die "Tests fail with ${EPYTHON}"
+}
+
+pkg_postinst() {
+ use emacs && elisp-site-regen
+
+ elog "If you want to convert repositories from other tools using convert"
+ elog "extension please install correct tool:"
+ elog " dev-vcs/cvs"
+ elog " dev-vcs/darcs"
+ elog " dev-vcs/git"
+ elog " dev-vcs/monotone"
+ elog " dev-vcs/subversion"
+}
+
+pkg_postrm() {
+ use emacs && elisp-site-regen
+}