[gentoo-commits] repo/gentoo:master commit in: media-sound/cantata/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     d4bd1d8d39b9a6d785e11f8eb804cc4977ce8ae1
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Wed Aug  2 06:25:13 2017 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Wed Aug  2 19:29:50 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d4bd1d8d

media-sound/cantata: 2.1.0 version bump

Package-Manager: Portage-2.3.6, Repoman-2.3.1

 media-sound/cantata/Manifest             |   1 +
 media-sound/cantata/cantata-2.1.0.ebuild | 113 +++++++++++++++++++++++++++++++
 media-sound/cantata/metadata.xml         |   1 +
 3 files changed, 115 insertions(+)

diff --git a/media-sound/cantata/Manifest b/media-sound/cantata/Manifest
index c7c120f44e4..6b8b4883803 100644
--- a/media-sound/cantata/Manifest
+++ b/media-sound/cantata/Manifest
@@ -1 +1,2 @@
 DIST cantata-2.0.1.tar.bz2 2151126 SHA256 122bda13c0b4078b84640dabef444b37d705d71c6f95209a2d949acd28a0bbca SHA512 69ae0c67970ec43f407c5ad11c0ddf254060a16de5023b2fdaf14ad9637ad8be06101ebe6c5cb07283e058400b24d80177b89f10a7be486cdb994aed1ff5ba02 WHIRLPOOL 138fab5ebbe9418b2c2d37b5c479fa7118a4c567f9ecd2a1fe2f4f1ff53e78803ca1f0192c126940ab2409b13448631a6e96e4e1542255378ff2f237df46ea3c
+DIST cantata-2.1.0.tar.bz2 2207271 SHA256 9317afcae75c709ec733da069d4245b47e6e2c297a259eaf87a181fa9d1cd4c4 SHA512 bf03933785110d0d0c1dfbfc27f4974869ae7c79afe3cf1da1f3024c95d86733d8bea77f2a882887de79a7897ffcdac4262e58747dd4e979824943991675c5d2 WHIRLPOOL 5d58b84290c387d535e556553e64bba36520a099565c44bed1c4e9cf800c2a432ac09296b989a557e72d81a951c926b4bb638f2d2ab7976735059ebb74b8c8e2

diff --git a/media-sound/cantata/cantata-2.1.0.ebuild b/media-sound/cantata/cantata-2.1.0.ebuild
new file mode 100644
index 00000000000..65f1626c7dd
--- /dev/null
+++ b/media-sound/cantata/cantata-2.1.0.ebuild
@@ -0,0 +1,113 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PLOCALES="cs de en_GB es fr hu it ja ko pl ru zh_CN"
+inherit cmake-utils gnome2-utils l10n qmake-utils xdg
+
+DESCRIPTION="Featureful and configurable Qt client for the music player daemon (MPD)"
+HOMEPAGE="https://github.com/CDrummond/cantata"
+SRC_URI="https://github.com/CDrummond/cantata/releases/download/v${PV}/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="cdda cddb cdio http-server mtp musicbrainz replaygain taglib udisks"
+REQUIRED_USE="
+	?? ( cdda cdio )
+	cdda? ( udisks || ( cddb musicbrainz ) )
+	cddb? ( || ( cdio cdda ) taglib )
+	cdio? ( udisks || ( cddb musicbrainz ) )
+	mtp? ( taglib udisks )
+	musicbrainz? ( || ( cdio cdda ) taglib )
+	replaygain? ( taglib )
+"
+
+RDEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtsql:5[sqlite]
+	dev-qt/qtsvg:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	|| ( kde-frameworks/breeze-icons:5 kde-frameworks/oxygen-icons:* )
+	sys-libs/zlib
+	virtual/libudev:=
+	cdda? ( media-sound/cdparanoia )
+	cdio? ( dev-libs/libcdio-paranoia )
+	cddb? ( media-libs/libcddb )
+	mtp? ( media-libs/libmtp )
+	musicbrainz? ( media-libs/musicbrainz:5= )
+	replaygain? (
+		media-libs/libebur128
+		media-sound/mpg123
+		virtual/ffmpeg
+	)
+	taglib? (
+		media-libs/taglib[asf(+),mp4(+)]
+		media-libs/taglib-extras
+		udisks? ( sys-fs/udisks:2 )
+	)
+"
+DEPEND="${RDEPEND}
+	dev-qt/qtconcurrent:5
+	dev-qt/linguist-tools:5
+"
+
+# cantata has no tests
+RESTRICT="test"
+
+src_prepare() {
+	remove_locale() {
+		rm "translations/${PN}_${1}".ts || die
+	}
+
+	cmake-utils_src_prepare
+
+	# Unbundle 3rd party libs
+	rm -r 3rdparty/{ebur128,qtsingleapplication} || die
+
+	l10n_find_plocales_changes "translations" "${PN}_" ".ts"
+	l10n_for_each_disabled_locale_do remove_locale
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DCANTATA_HELPERS_LIB_DIR="$(get_libdir)"
+		-DENABLE_CDPARANOIA=$(usex cdda)
+		-DENABLE_CDIOPARANOIA=$(usex cdio)
+		-DENABLE_CDDB=$(usex cddb)
+		-DENABLE_HTTP_SERVER=$(usex http-server)
+		-DENABLE_MTP=$(usex mtp)
+		-DENABLE_MUSICBRAINZ=$(usex musicbrainz)
+		-DLRELEASE_EXECUTABLE="$(qt5_get_bindir)/lrelease"
+		-DENABLE_FFMPEG=$(usex replaygain)
+		-DENABLE_MPG123=$(usex replaygain)
+		-DENABLE_TAGLIB=$(usex taglib)
+		-DENABLE_TAGLIB_EXTRAS=$(usex taglib)
+		-DENABLE_DEVICES_SUPPORT=$(usex udisks)
+		-DENABLE_HTTP_STREAM_PLAYBACK=OFF
+		-DENABLE_REMOTE_DEVICES=OFF
+		-DENABLE_UDISKS2=ON
+	)
+
+	cmake-utils_src_configure
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+	xdg_pkg_preinst
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+	xdg_pkg_postinst
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+	xdg_pkg_postrm
+}

diff --git a/media-sound/cantata/metadata.xml b/media-sound/cantata/metadata.xml
index 9943c92723b..62779a1ff0c 100644
--- a/media-sound/cantata/metadata.xml
+++ b/media-sound/cantata/metadata.xml
@@ -6,6 +6,7 @@
 		<name>Gentoo KDE Project</name>
 	</maintainer>
 	<use>
+		<flag name="cdio">Use <pkg>dev-libs/libcdio-paranoia</pkg> for CD support (instead of cdparanoia)</flag>
 		<flag name="http-server">Enable internal HTTP server to play non-MPD files</flag>
 		<flag name="replaygain">Enable ReplayGain support, for relative volume adjustments</flag>
 	</use>