From mboxrd@z Thu Jan  1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-963703-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
	(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
	(No client certificate requested)
	by finch.gentoo.org (Postfix) with ESMTPS id 57283139694
	for <garchives@archives.gentoo.org>; Wed, 26 Jul 2017 17:08:24 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
	by pigeon.gentoo.org (Postfix) with SMTP id A7B791FC075;
	Wed, 26 Jul 2017 17:08:23 +0000 (UTC)
Received: from smtp.gentoo.org (smtp.gentoo.org [140.211.166.183])
	(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
	(No client certificate requested)
	by pigeon.gentoo.org (Postfix) with ESMTPS id 6E47C1FC075
	for <gentoo-commits@lists.gentoo.org>; Wed, 26 Jul 2017 17:08:23 +0000 (UTC)
Received: from oystercatcher.gentoo.org (oystercatcher.gentoo.org [148.251.78.52])
	(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
	(No client certificate requested)
	by smtp.gentoo.org (Postfix) with ESMTPS id 625D234177F
	for <gentoo-commits@lists.gentoo.org>; Wed, 26 Jul 2017 17:08:22 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
	by oystercatcher.gentoo.org (Postfix) with ESMTP id CC94A74C4
	for <gentoo-commits@lists.gentoo.org>; Wed, 26 Jul 2017 17:08:20 +0000 (UTC)
From: "Alexey Shvetsov" <alexxy@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Alexey Shvetsov" <alexxy@gentoo.org>
Message-ID: <1501088688.9fbb45f9277667146be091927e21802ac0f2f5d6.alexxy@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: media-gfx/freecad/
X-VCS-Repository: repo/gentoo
X-VCS-Files: media-gfx/freecad/Manifest media-gfx/freecad/freecad-0.16.6712.ebuild
X-VCS-Directories: media-gfx/freecad/
X-VCS-Committer: alexxy
X-VCS-Committer-Name: Alexey Shvetsov
X-VCS-Revision: 9fbb45f9277667146be091927e21802ac0f2f5d6
X-VCS-Branch: master
Date: Wed, 26 Jul 2017 17:08:20 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Archives-Salt: 0b8136d8-b0e7-41c4-94d5-bd5d28e3db10
X-Archives-Hash: 7edcedeb255e4bcb7e10a0b9e7ced2ef

commit:     9fbb45f9277667146be091927e21802ac0f2f5d6
Author:     Alexey Shvetsov <alexxy <AT> gentoo <DOT> org>
AuthorDate: Wed Jul 26 16:11:19 2017 +0000
Commit:     Alexey Shvetsov <alexxy <AT> gentoo <DOT> org>
CommitDate: Wed Jul 26 17:04:48 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9fbb45f9

media-gfx/freecad: Version bump for 0.16.x series

Package-Manager: Portage-2.3.6, Repoman-2.3.3

 media-gfx/freecad/Manifest                 |   1 +
 media-gfx/freecad/freecad-0.16.6712.ebuild | 132 +++++++++++++++++++++++++++++
 2 files changed, 133 insertions(+)

diff --git a/media-gfx/freecad/Manifest b/media-gfx/freecad/Manifest
index 04eee41d403..b529ef9b5e1 100644
--- a/media-gfx/freecad/Manifest
+++ b/media-gfx/freecad/Manifest
@@ -1,2 +1,3 @@
 DIST freecad-0.15.4671.tar.gz 93680347 SHA256 8dda8f355cb59866a55c9c6096f39a3ebc5347892284db4c305352cc9be03bbc SHA512 695081117b5511bbc0b7335b63a8760e164987a6dff2c5b0dc86b6b0a93bb7d7b83aa9f4fab1d66d7d2c917a42b0135af78553b463579873a1d1e52e3dd9aecb WHIRLPOOL 0c351ad9ee360dfd9af54af9cc348a6ba3d8c15b6743667f6943e41aa252cec9bd2149baa32fceeceac65660a9b629aefba3c80a5c3a84c45a8d502323547287
+DIST freecad-0.16.6712.tar.gz 111706423 SHA256 97aa130addeb0f3c0bf79e4828fbd242b76cc92603771d6b7aeb9dbd9f111a92 SHA512 ea8214b37f7a10a3e3e558e6c1223d9212d6c2906b79961c8cb9211edff97a41e2da0ce6cf64cdc7a22610f6ff13495163c46573b5dd84d4a7cc0260f15e371e WHIRLPOOL 2c6f9e3afeb83befbaeb8d51ddf8272ab21473f8ef73095eebe5985a4f1979bb67767c3fca30ebdc853dfbdcd207e2a58e41f323d6ca8ff9502ee2aef9b33850
 DIST freecad-0.16.tar.gz 111706127 SHA256 6cc71ab4b0dc60b493d3aaa4b42f1ce1af9d4fcd539309ab0792804579e18e09 SHA512 bc9dc8122cabd9a84f2b955746818e0d77ae90e68747ec96521099472b7803df9ff794ed823d6eb29352bd0538b8f01cf81c306ff427f1af2ee049f8f7096dbb WHIRLPOOL 8d90a4213808dcd7ce7adeaeac8a30351e06b217e31326817cb034ec02dcfe7be0ea71cb5bf297e1bab3a8a6c6ac24848f51a0453f9bf09162e700bc52f9cf4d

diff --git a/media-gfx/freecad/freecad-0.16.6712.ebuild b/media-gfx/freecad/freecad-0.16.6712.ebuild
new file mode 100644
index 00000000000..e1f0300bd89
--- /dev/null
+++ b/media-gfx/freecad/freecad-0.16.6712.ebuild
@@ -0,0 +1,132 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 )
+
+inherit cmake-utils eutils xdg-utils fortran-2 python-single-r1
+
+DESCRIPTION="QT based Computer Aided Design application"
+HOMEPAGE="http://www.freecadweb.org/"
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/FreeCAD/FreeCAD.git"
+else
+	SRC_URI="https://github.com/FreeCAD/FreeCAD/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE=""
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+COMMON_DEPEND="
+	${PYTHON_DEPS}
+	dev-cpp/eigen:3
+	dev-java/xerces
+	dev-libs/boost:=[python,${PYTHON_USEDEP}]
+	dev-libs/xerces-c[icu]
+	dev-python/matplotlib[${PYTHON_USEDEP}]
+	dev-python/pyside:0[X,svg,${PYTHON_USEDEP}]
+	dev-python/shiboken:0[${PYTHON_USEDEP}]
+	dev-qt/designer:4
+	dev-qt/qtgui:4[-egl]
+	dev-qt/qtopengl:4[-egl]
+	dev-qt/qtsvg:4
+	dev-qt/qtwebkit:4
+	media-libs/coin
+	media-libs/freetype
+	|| ( sci-libs/opencascade:6.9.1[vtk] sci-libs/opencascade:6.9.0[vtk] sci-libs/opencascade:6.8.0 sci-libs/opencascade:6.7.1 )
+	sci-libs/orocos_kdl
+	sys-libs/zlib
+	virtual/glu"
+RDEPEND="${COMMON_DEPEND}
+	dev-python/numpy[${PYTHON_USEDEP}]
+	dev-python/pivy[${PYTHON_USEDEP}]
+	dev-qt/assistant:4"
+DEPEND="${COMMON_DEPEND}
+	>=dev-lang/swig-2.0.4-r1:0
+	dev-python/pyside-tools:0[${PYTHON_USEDEP}]"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.14.3702-install-paths.patch
+)
+
+# https://bugs.gentoo.org/show_bug.cgi?id=352435
+# https://www.gentoo.org/foundation/en/minutes/2011/20110220_trustees.meeting_log.txt
+RESTRICT="mirror"
+
+# TODO:
+#   DEPEND and RDEPEND:
+#		salome-smesh - science overlay
+#		zipio++ - not in portage yet
+
+S="${WORKDIR}/FreeCAD-${PV}"
+
+DOCS=( README.md ChangeLog.txt )
+
+pkg_setup() {
+	fortran-2_pkg_setup
+	python-single-r1_pkg_setup
+
+	[[ -z ${CASROOT} ]] && die "empty \$CASROOT, run eselect opencascade set or define otherwise"
+}
+
+src_configure() {
+	export QT_SELECT=4
+
+	#-DOCC_* defined with cMake/FindOpenCasCade.cmake
+	#-DCOIN3D_* defined with cMake/FindCoin3D.cmake
+	#-DSOQT_ not used
+	local mycmakeargs=(
+		-DOCC_INCLUDE_DIR="${CASROOT}"/inc
+		-DOCC_LIBRARY_DIR="${CASROOT}"/$(get_libdir)
+		-DCMAKE_INSTALL_DATADIR=share/${P}
+		-DCMAKE_INSTALL_DOCDIR=share/doc/${PF}
+		-DCMAKE_INSTALL_INCLUDEDIR=include/${P}
+		-DFREECAD_USE_EXTERNAL_KDL="ON"
+	)
+
+	# TODO to remove embedded dependencies:
+	#
+	#	-DFREECAD_USE_EXTERNAL_ZIPIOS="ON" -- this option needs zipios++ but it's not yet in portage so the embedded zipios++
+	#                (under src/zipios++) will be used
+	#	salomesmesh is in 3rdparty but upstream's find_package function is not complete yet to compile against external version
+	#                (external salomesmesh is available in "science" overlay)
+
+	cmake-utils_src_configure
+	einfo "${P} will be built against opencascade version ${CASROOT}"
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	make_desktop_entry FreeCAD "FreeCAD" "" "" "MimeType=application/x-extension-fcstd;"
+
+	# install mimetype for FreeCAD files
+	insinto /usr/share/mime/packages
+	newins "${FILESDIR}"/${PN}.sharedmimeinfo "${PN}.xml"
+
+	# install icons to correct place rather than /usr/share/freecad
+	pushd "${ED%/}"/usr/share/${P} || die
+	local size
+	for size in 16 32 48 64; do
+		newicon -s ${size} freecad-icon-${size}.png freecad.png
+	done
+	doicon -s scalable freecad.svg
+	newicon -s 64 -c mimetypes freecad-doc.png application-x-extension-fcstd.png
+	popd || die
+
+	python_optimize "${ED%/}"/usr/{,share/${P}/}Mod/
+}
+
+pkg_postinst() {
+	xdg_mimeinfo_database_update
+}
+
+pkg_postrm() {
+	xdg_mimeinfo_database_update
+}