[gentoo-commits] repo/gentoo:master commit in: dev-util/sysdig/

["Michał Górny" <mgorny@gentoo.org>]

commit:     201769ddc0c7e397204b05c74c518f18d86e87ac
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Tue Jul 25 07:26:56 2017 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Tue Jul 25 07:57:40 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=201769dd

dev-util/sysdig: Bump to 0.17.0

 dev-util/sysdig/Manifest             |  1 +
 dev-util/sysdig/sysdig-0.17.0.ebuild | 91 ++++++++++++++++++++++++++++++++++++
 2 files changed, 92 insertions(+)

diff --git a/dev-util/sysdig/Manifest b/dev-util/sysdig/Manifest
index afad59c1966..78acfcdd8dc 100644
--- a/dev-util/sysdig/Manifest
+++ b/dev-util/sysdig/Manifest
@@ -1 +1,2 @@
 DIST sysdig-0.16.0.tar.gz 713245 SHA256 73a0190c973e4a591013d0c73ff2ea9f623ab50b78ff78f7a33fe31460ba24a1 SHA512 d8f3f0327ca1cd0fface433ccd41bf0919aba120bc2d01806806d0f3e88fa6982277d553ee9719f07d255495b946c765a156a5e69c03c0e830c510fc83def65e WHIRLPOOL e17ce8d22cada60f02db468a3103c54237482400c3bfe9a9833d3f5eb61953e910ddb8dbd642bc316c237d4b023da089624cd82f9879241ba5cd407fc60b649f
+DIST sysdig-0.17.0.tar.gz 718719 SHA256 f009acc32f2b15fcb0d2267bde6f6de9b3445179003c979ba61a8836abdb78f9 SHA512 476e130151d1a8e9e782f074c45448becbef10397c0040e33febaf89c73f22c1716ebeeb2683f489a74c83f5d67174c9f21bb05d4327f35fb03ca1b9822889bc WHIRLPOOL a8f3e0aa45e00d9e6b02e0c26f3ec2f91cbf4d9a6caf955684617e2a1e7c9c0b92c0bdda3b2c254129008ea42bd2386710ef391714e13631e0e7d62fe9226ed0

diff --git a/dev-util/sysdig/sysdig-0.17.0.ebuild b/dev-util/sysdig/sysdig-0.17.0.ebuild
new file mode 100644
index 00000000000..ebc9e98519a
--- /dev/null
+++ b/dev-util/sysdig/sysdig-0.17.0.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+: ${CMAKE_MAKEFILE_GENERATOR:=ninja}
+MODULES_OPTIONAL_USE=modules
+inherit linux-mod bash-completion-r1 cmake-utils
+
+DESCRIPTION="A system exploration and troubleshooting tool"
+HOMEPAGE="https://www.sysdig.org/"
+SRC_URI="https://github.com/draios/sysdig/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+modules"
+
+RDEPEND="
+	app-misc/jq:0=
+	dev-lang/luajit:2=
+	>=dev-libs/jsoncpp-0.6_pre:0=
+	dev-libs/libb64:0=
+	sys-libs/ncurses:0=
+	sys-libs/zlib:0=
+	dev-libs/openssl:0=
+	net-misc/curl:0="
+DEPEND="${RDEPEND}
+	app-arch/xz-utils
+	virtual/os-headers"
+
+# needed for the kernel module
+CONFIG_CHECK="HAVE_SYSCALL_TRACEPOINTS ~TRACEPOINTS"
+
+pkg_pretend() {
+	linux-mod_pkg_setup
+}
+
+pkg_setup() {
+	linux-mod_pkg_setup
+}
+
+src_prepare() {
+	sed -i -e 's:-ggdb::' CMakeLists.txt || die
+
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		# we will use linux-mod for that
+		-DBUILD_DRIVER=OFF
+		# libscap examples are not installed or really useful
+		-DBUILD_LIBSCAP_EXAMPLES=OFF
+
+		# unbundle the deps
+		-DUSE_BUNDLED_DEPS=OFF
+	)
+
+	cmake-utils_src_configure
+
+	# setup linux-mod ugliness
+	MODULE_NAMES="sysdig-probe(extra:${S}/driver:)"
+	BUILD_PARAMS='KERNELDIR="${KERNEL_DIR}"'
+	BUILD_TARGETS="all"
+
+	if use modules; then
+		cmake-utils_src_make configure_driver
+
+		cp "${BUILD_DIR}"/driver/Makefile.dkms driver/Makefile || die
+	fi
+}
+
+src_compile() {
+	cmake-utils_src_compile
+
+	linux-mod_src_compile
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	linux-mod_src_install
+
+	# remove sources
+	rm -r "${ED%/}"/usr/src || die
+
+	# move bashcomp to the proper location
+	dobashcomp "${ED%/}"/usr/etc/bash_completion.d/sysdig || die
+	rm -r "${ED%/}"/usr/etc || die
+}