[gentoo-commits] repo/gentoo:master commit in: net-libs/mbedtls/

["Anthony G. Basile" <blueness@gentoo.org>]

commit:     f1c319f1b201eb23b62d583da0c4c68406a955e2
Author:     Anthony G. Basile <blueness <AT> gentoo <DOT> org>
AuthorDate: Sun Jul 23 16:52:07 2017 +0000
Commit:     Anthony G. Basile <blueness <AT> gentoo <DOT> org>
CommitDate: Sun Jul 23 16:52:33 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f1c319f1

net-libs/mbedtls: version bump to 2.5.2

Package-Manager: Portage-2.3.6, Repoman-2.3.1

 net-libs/mbedtls/Manifest             |  1 +
 net-libs/mbedtls/mbedtls-2.5.2.ebuild | 93 +++++++++++++++++++++++++++++++++++
 2 files changed, 94 insertions(+)

diff --git a/net-libs/mbedtls/Manifest b/net-libs/mbedtls/Manifest
index 4483f5c64ab..67ee96ec1a2 100644
--- a/net-libs/mbedtls/Manifest
+++ b/net-libs/mbedtls/Manifest
@@ -2,3 +2,4 @@ DIST mbedtls-2.2.1.tar.gz 1807209 SHA256 32819c62c20e8740a11b49daa5d09ac6f179edf
 DIST mbedtls-2.4.2.tar.gz 1861681 SHA256 b7afab6a0f86e29c6055848b70d183c4e2531cb0ec955b66c0e4e1b7e4954bf4 SHA512 39ab068ffad99afe228749fc7f69a02a8c79f0fdb73e2dbcde2e97f737338030e2fb8507e9d1cb866429e89b255197a2225607d6645421d31d7f2ccb65bfc04f WHIRLPOOL e74864290e93d9ae52dcf6d9751d0da6b09c84f527e0a548198b2bb4869c4477628237eb1d422dcb47724435d360381fc9d7ddcc930bf078a8e5f63ee83411f4
 DIST mbedtls-2.5.0.tar.gz 1868724 SHA256 5f92c4abfd7939dc41a740cace8e6280b10ec4b7b673636eb59e47ab9258ba9f SHA512 dac13ed4b64ac70c087a563d1cf86c81dab4e4e083896a331476501d485950e6fb2e04baf3ee5ad7848b595c100cc46caebbd1d13417e0003ae8e2d5c7e47b12 WHIRLPOOL e17c24706772af3e1a5ac96f280543d1ecef30e03091b3f1c1addb0f44c2087a5691d6e37ebfeaa3d1b17b707b8865db0266b3842a5f1dfa130bf7ef556e722b
 DIST mbedtls-2.5.1.tar.gz 1890505 SHA256 63010b5d024aee4e6f708dfafe9c45c904dbbfab8b37bfe3ffbf46ac3405e3fa SHA512 99bae9bf180c60c65bd50b2549825b846a000196afd854abfa92b79c3fbd030cc195d1fea704c44d445baa56e2149e4d2a9645da4c53d7988e08a0434b1679e3 WHIRLPOOL 83b0a4a97a80da3f4c84a35c4ee75b4905f3893ca6484ef595da1c7583696ad4304706cf8d1ec9e5bf66ca6b8bf548539b02ecdcbd70f01e49d0ec35fe2c77b5
+DIST mbedtls-2.5.2.tar.gz 1890514 SHA256 faf22d3ff8682b8ca414b553c5f38b2f5204e679171b41ed0a0e3e3d815fe38e SHA512 9bcb7d4ada983927d488eaf53773113591f7da77cde8a9ae8e9117074fe5500925d5e5fed1bef9431491eb4cf930e49bbdf8dfbcf45ef5118918e358384864b2 WHIRLPOOL f5f21461c776cf273ddc1f2469cbb92b4285bc3c14a4af96907aa73306695ba580223261095fd3a1016456c95f3ff8b585ea25b247ba4255beea063e4881ab99

diff --git a/net-libs/mbedtls/mbedtls-2.5.2.ebuild b/net-libs/mbedtls/mbedtls-2.5.2.ebuild
new file mode 100644
index 00000000000..a5f6f23f855
--- /dev/null
+++ b/net-libs/mbedtls/mbedtls-2.5.2.ebuild
@@ -0,0 +1,93 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-utils multilib-minimal
+
+DESCRIPTION="Cryptographic library for embedded systems"
+HOMEPAGE="https://tls.mbed.org/"
+SRC_URI="https://github.com/ARMmbed/mbedtls/archive/${P}.tar.gz"
+S=${WORKDIR}/${PN}-${P}
+
+LICENSE="Apache-2.0"
+SLOT="0/10" # slot for libmbedtls.so
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd"
+IUSE="cpu_flags_x86_sse2 doc havege libressl programs test threads zlib"
+
+RDEPEND="
+	programs? (
+		!libressl? ( dev-libs/openssl:0= )
+		libressl? ( dev-libs/libressl:0= )
+	)
+	zlib? ( >=sys-libs/zlib-1.2.8-r1[${MULTILIB_USEDEP}] )"
+DEPEND="${RDEPEND}
+	doc? ( app-doc/doxygen media-gfx/graphviz )
+	test? ( dev-lang/perl )"
+
+enable_mbedtls_option() {
+	local myopt="$@"
+	# check that config.h syntax is the same at version bump
+	sed -i \
+		-e "s://#define ${myopt}:#define ${myopt}:" \
+		include/mbedtls/config.h || die
+}
+
+src_prepare() {
+	use cpu_flags_x86_sse2 && enable_mbedtls_option MBEDTLS_HAVE_SSE2
+	use zlib && enable_mbedtls_option MBEDTLS_ZLIB_SUPPORT
+	use havege && enable_mbedtls_option MBEDTLS_HAVEGE_C
+	use threads && enable_mbedtls_option MBEDTLS_THREADING_C
+	use threads && enable_mbedtls_option MBEDTLS_THREADING_PTHREAD
+
+	cmake-utils_src_prepare
+}
+
+multilib_src_configure() {
+	local mycmakeargs=(
+		-DENABLE_PROGRAMS=$(multilib_native_usex programs)
+		-DENABLE_ZLIB_SUPPORT=$(usex zlib)
+		-DUSE_STATIC_MBEDTLS_LIBRARY=OFF
+		-DENABLE_TESTING=$(usex test)
+		-DUSE_SHARED_MBEDTLS_LIBRARY=ON
+		-DINSTALL_MBEDTLS_HEADERS=ON
+		-DLIB_INSTALL_DIR="/usr/$(get_libdir)"
+	)
+
+	cmake-utils_src_configure
+}
+
+multilib_src_compile() {
+	cmake-utils_src_compile
+	use doc && multilib_is_native_abi && emake apidoc
+}
+
+multilib_src_test() {
+	LD_LIBRARY_PATH="${LD_LIBRARY_PATH}:${BUILD_DIR}/library" \
+		cmake-utils_src_test
+}
+
+multilib_src_install() {
+	cmake-utils_src_install
+}
+
+multilib_src_install_all() {
+	use doc && HTML_DOCS=( apidoc )
+
+	einstalldocs
+
+	if use programs ; then
+		# avoid file collisions with sys-apps/coreutils
+		local p e
+		for p in "${ED%/}"/usr/bin/* ; do
+			if [[ -x "${p}" && ! -d "${p}" ]] ; then
+				mv "${p}" "${ED%/}"/usr/bin/mbedtls_${p##*/} || die
+			fi
+		done
+		for e in aes hash pkey ssl test ; do
+			docinto "${e}"
+			dodoc programs/"${e}"/*.c
+			dodoc programs/"${e}"/*.txt
+		done
+	fi
+}