[gentoo-commits] repo/gentoo:master commit in: x11-themes/adwaita-qt/

["Pacho Ramos" <pacho@gentoo.org>]

commit:     972483cac6332bf7b3103ef8ce55003011c9b970
Author:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
AuthorDate: Fri Jul 21 08:41:41 2017 +0000
Commit:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
CommitDate: Fri Jul 21 08:46:40 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=972483ca

x11-themes/adwaita-qt: Package adwaita-qt themes for better integration with Gnome

Package-Manager: Portage-2.3.6, Repoman-2.3.2

 x11-themes/adwaita-qt/Manifest              |  1 +
 x11-themes/adwaita-qt/adwaita-qt-1.0.ebuild | 56 +++++++++++++++++++++++++++++
 x11-themes/adwaita-qt/metadata.xml          |  7 ++++
 3 files changed, 64 insertions(+)

diff --git a/x11-themes/adwaita-qt/Manifest b/x11-themes/adwaita-qt/Manifest
new file mode 100644
index 00000000000..1e60bdfd145
--- /dev/null
+++ b/x11-themes/adwaita-qt/Manifest
@@ -0,0 +1 @@
+DIST adwaita-qt-1.0.tar.gz 565625 SHA256 c2c0c71b131d0e3e58ee108570796cf70b35dccaa64ce17915d4486de5e91513 SHA512 35993a9f99f9d41812d448d679a9e7a8cb15e8ed9b23a2ea9a33c61c1bfc98a226f8bea2fce3ff0dab29420ff10c4e4a4a800c9b989475cc66c4042257fe154c WHIRLPOOL a45d838d2cf39237065ed8f7b650678c69ec80683b6f1e215d2252fb3e15dc16d5e1c5ed1ff2bd9c3bed2e37abf96f068a54f458336d39c4dffe049306c78993

diff --git a/x11-themes/adwaita-qt/adwaita-qt-1.0.ebuild b/x11-themes/adwaita-qt/adwaita-qt-1.0.ebuild
new file mode 100644
index 00000000000..7b1729cb1b8
--- /dev/null
+++ b/x11-themes/adwaita-qt/adwaita-qt-1.0.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit cmake-utils
+
+DESCRIPTION="A style to bend Qt applications to look like they belong into GNOME Shell"
+HOMEPAGE="https://github.com/MartinBriza/adwaita-qt"
+SRC_URI="https://github.com/MartinBriza/${PN}/archive/${PV}/${P}.tar.gz"
+
+KEYWORDS="~amd64 ~x86"
+LICENSE="GPL-2 LGPL-2"
+SLOT="0"
+
+IUSE="gnome qt4 +qt5"
+REQUIRED_USE="|| ( qt4 qt5 )"
+
+RDEPEND="
+	gnome? ( x11-themes/QGnomePlatform )
+	qt4? (
+		dev-qt/qtgui:4
+		dev-qt/qtdbus:4
+	)
+	qt5? (
+		dev-qt/qtwidgets:5
+		dev-qt/qtdbus:5
+	)
+"
+DEPEND="${RDEPEND}"
+
+src_configure() {
+	if use qt4; then
+		BUILD_DIR="${WORKDIR}/${PN}_qt4"
+		local mycmakeargs=( -DUSE_QT4=ON )
+		cmake-utils_src_configure
+	fi
+	if use qt5; then
+		BUILD_DIR="${WORKDIR}/${PN}_qt5"
+		local mycmakeargs=( -DUSE_QT4=OFF )
+		cmake-utils_src_configure
+	fi
+}
+
+src_compile() {
+	local _d
+	for _d in "${WORKDIR}"/${PN}_qt*; do
+		cmake-utils_src_compile -C "${_d}"
+	done
+}
+
+src_install() {
+	local _d
+	for _d in "${WORKDIR}"/${PN}_qt*; do
+		cmake-utils_src_install -C "${_d}"
+	done
+}

diff --git a/x11-themes/adwaita-qt/metadata.xml b/x11-themes/adwaita-qt/metadata.xml
new file mode 100644
index 00000000000..020b40648ee
--- /dev/null
+++ b/x11-themes/adwaita-qt/metadata.xml
@@ -0,0 +1,7 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>pacho@gentoo.org</email>
+	</maintainer>
+</pkgmetadata>