[gentoo-commits] repo/gentoo:master commit in: media-tv/kodi/

["Michał Górny" <mgorny@gentoo.org>]

commit:     8a96208787f8de708a61252c6efa506cc1d6b543
Author:     Craig Andrews <candrews <AT> integralblue <DOT> com>
AuthorDate: Tue Jul 11 14:01:10 2017 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Tue Jul 11 21:54:25 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=8a962087

media-tv/kodi: drop old version

Closes: https://github.com/gentoo/gentoo/pull/4966
Package-Manager: Portage-2.3.6, Repoman-2.3.2

 media-tv/kodi/Manifest         |   2 -
 media-tv/kodi/kodi-17.2.ebuild | 279 -----------------------------------------
 2 files changed, 281 deletions(-)

diff --git a/media-tv/kodi/Manifest b/media-tv/kodi/Manifest
index 99b658c0317..922f625ad12 100644
--- a/media-tv/kodi/Manifest
+++ b/media-tv/kodi/Manifest
@@ -1,6 +1,4 @@
 DIST ffmpeg-kodi-3.1.6-Krypton.tar.gz 11170735 SHA256 01f914742f6af8afd1d2eb076425975e24c4eed75f5d57f1c816086dc4625192 SHA512 060d06946ee71106196587b36eccf7fb7d0710d6ee72dae2e08f23e5bf7e223a3bac77f1730121f494ecf5f860a40635978023317a06f27a3b28752fa537f1a1 WHIRLPOOL ae6f0b3b798e92cd72aed8eb3e6dc82708c86052590b30ae93e1b8275dca89c5a4470dbc8ff51bfefd72bd40036b7bd1b7695ee77e90bab35b5e80bcb8b79826
-DIST kodi-17.2-generated-addons.tar.xz 57556 SHA256 c04c610fec8345ed383afccdb0e9eb04d6327682169dd236ca36291e866f2cab SHA512 46a41f1eb45a7d2680e0c07e71073c929881a324c91d2fea0871aa31cba00296fe0b835481411a213921c7813ac75b629ff3e9d941f5ca0ad72c0d1dcf861a21 WHIRLPOOL 45372116099402dae63a51117d93f08852416ff7cad4ecf7a969a1a70d42460e9681338bf69803291774a0e6d130166e5136f0692d086eded1d7b69e527db872
-DIST kodi-17.2.tar.gz 10507875 SHA256 8b211374dfa7b7a2a2789c4f0a2ecea2102a2a6ccef561fe314788c53bb50f64 SHA512 91bd2cf3ba2a12d51d6a11114f0fa01a777e62cf5c121df034bb981778f716aaafd3bfda6bbae526e5fdf450a368cf22957f1215f9617e5d038e7c3c93f03e13 WHIRLPOOL 40e13e6fb27732fc8fdc9bd8b5ac1d59cc96a05263b001d315e0180730db1cb2c1f5dbe76917bf0574f767da209d720f553c07f9acd1a2539ab05ae5147c897c
 DIST kodi-17.3-generated-addons.tar.xz 57548 SHA256 6175ac64dbcbe2c747cd77f876b8e2bb3e516daa4707d7ccf768d76a89b27bd1 SHA512 56d1912f5e24d3fcda3010783a5b32728ece9c81c718ac6f8db2cbbd096059fe97b8d1971b34bbde1216558a8e5db874f7b2179e1f18942774ae5486167bca9a WHIRLPOOL 1023c69687ac9958e72ab70c15a280800ea4866f8e0dc2740d9bfd50f75bef71c28f23f01a841f254022610e1388d14217ea384213161264dae721515c9dabe3
 DIST kodi-17.3.tar.gz 58466114 SHA256 1de8653a3729cefd1baaf09ecde5ace01a1e3a58fbf29d48c1363f2503d331a1 SHA512 832071c3e9f332281a767f29168f6d6d003a86b42df849e81d907c2280f81f959ae42a850eddc889ae2280bba6106de3355e701ff2d71c88ee14cb20c84e7987 WHIRLPOOL 0ed5585f891459292a1cfd4451bee1f2b19af217e462b810468b00395ee024ba346300f84c67c6dc428d27abcaef4eec9dc7b844e66e2ab83543830a106a1634
 DIST libdvdcss-2f12236bc1c92f73c21e973363f79eb300de603f.tar.gz 95395 SHA256 b6eb2d929ff56cb051152c32010afc5e7cf5fe8c5ae32dca412a2b46b6b57e34 SHA512 12ba7aa653fcb26d5336bf2a8110c924d634cec79f684bbf19dc38ea33f69fb68c22c97f4c09e5ca7c35f95f6c324a6d70ccc2c501a99122a9321cafd33b2cd9 WHIRLPOOL 8570ad8d2b6e629cc1c7e544be2853cab3bb50fd73438cea47c7a0919b251cecf906f7446ef3714c54ee3e636278dc0dabab47f772440624ff49877068b7b50a

diff --git a/media-tv/kodi/kodi-17.2.ebuild b/media-tv/kodi/kodi-17.2.ebuild
deleted file mode 100644
index 94c5a55bfa5..00000000000
--- a/media-tv/kodi/kodi-17.2.ebuild
+++ /dev/null
@@ -1,279 +0,0 @@
-# Copyright 1999-2017 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-
-# Does not work with py3 here
-PYTHON_COMPAT=( python2_7 )
-PYTHON_REQ_USE="sqlite"
-
-inherit eutils linux-info python-single-r1 cmake-utils autotools
-
-LIBDVDCSS_COMMIT="2f12236bc1c92f73c21e973363f79eb300de603f"
-LIBDVDREAD_COMMIT="17d99db97e7b8f23077b342369d3c22a6250affd"
-LIBDVDNAV_COMMIT="43b5f81f5fe30bceae3b7cecf2b0ca57fc930dac"
-FFMPEG_VERSION="3.1.6"
-CODENAME="Krypton"
-SRC_URI="https://github.com/xbmc/libdvdcss/archive/${LIBDVDCSS_COMMIT}.tar.gz -> libdvdcss-${LIBDVDCSS_COMMIT}.tar.gz
-	https://github.com/xbmc/libdvdread/archive/${LIBDVDREAD_COMMIT}.tar.gz -> libdvdread-${LIBDVDREAD_COMMIT}.tar.gz
-	https://github.com/xbmc/libdvdnav/archive/${LIBDVDNAV_COMMIT}.tar.gz -> libdvdnav-${LIBDVDNAV_COMMIT}.tar.gz
-	!system-ffmpeg? ( https://github.com/xbmc/FFmpeg/archive/${FFMPEG_VERSION}-${CODENAME}.tar.gz -> ffmpeg-${PN}-${FFMPEG_VERSION}-${CODENAME}.tar.gz )"
-
-DESCRIPTION="Kodi is a free and open source media-player and entertainment hub"
-HOMEPAGE="https://kodi.tv/ http://kodi.wiki/"
-
-LICENSE="GPL-2"
-SLOT="0"
-# use flag is called libusb so that it doesn't fool people in thinking that
-# it is _required_ for USB support. Otherwise they'll disable udev and
-# that's going to be worse.
-IUSE="airplay alsa bluetooth bluray caps cec +css dbus debug dvd gles libressl libusb lirc mysql nfs nonfree +opengl pulseaudio samba sftp systemd +system-ffmpeg test +udev udisks upnp upower vaapi vdpau webserver +X +xslt zeroconf"
-REQUIRED_USE="
-	${PYTHON_REQUIRED_USE}
-	|| ( gles opengl )
-	gles? ( X )
-	opengl? ( X )
-	udev? ( !libusb )
-	udisks? ( dbus )
-	upower? ( dbus )
-"
-
-COMMON_DEPEND="${PYTHON_DEPS}
-	airplay? (
-		app-pda/libplist
-		net-libs/shairplay
-	)
-	alsa? ( media-libs/alsa-lib )
-	bluetooth? ( net-wireless/bluez )
-	bluray? ( >=media-libs/libbluray-0.7.0 )
-	caps? ( sys-libs/libcap )
-	dbus? ( sys-apps/dbus )
-	dev-db/sqlite
-	dev-libs/expat
-	dev-libs/fribidi
-	cec? ( >=dev-libs/libcec-4.0 )
-	dev-libs/libpcre[cxx]
-	dev-libs/libxml2
-	>=dev-libs/lzo-2.04
-	dev-libs/tinyxml[stl]
-	>=dev-libs/yajl-2
-	dev-python/pillow[${PYTHON_USEDEP}]
-	dev-libs/libcdio
-	gles? ( media-libs/mesa[gles2] )
-	libusb? ( virtual/libusb:1 )
-	media-fonts/corefonts
-	>=media-fonts/noto-20160531
-	media-fonts/roboto
-	media-libs/fontconfig
-	media-libs/freetype
-	>=media-libs/libass-0.13.4
-	media-libs/mesa[egl]
-	>=media-libs/taglib-1.11.1
-	system-ffmpeg? ( >=media-video/ffmpeg-${FFMPEG_VERSION}:=[encode,postproc] )
-	mysql? ( virtual/mysql )
-	>=net-misc/curl-7.51.0
-	nfs? ( net-fs/libnfs:= )
-	opengl? ( media-libs/glu )
-	!libressl? ( >=dev-libs/openssl-1.0.2j:0= )
-	libressl? ( dev-libs/libressl:0= )
-	pulseaudio? ( media-sound/pulseaudio )
-	samba? ( >=net-fs/samba-3.4.6[smbclient(+)] )
-	sftp? ( net-libs/libssh[sftp] )
-	sys-libs/zlib
-	udev? ( virtual/udev )
-	vaapi? ( x11-libs/libva[opengl] )
-	vdpau? (
-		|| ( >=x11-libs/libvdpau-1.1 >=x11-drivers/nvidia-drivers-180.51 )
-		system-ffmpeg? ( media-video/ffmpeg[vdpau] )
-	)
-	webserver? ( >=net-libs/libmicrohttpd-0.9.50[messages] )
-	X? (
-		x11-libs/libdrm
-		x11-libs/libX11
-		x11-libs/libXrandr
-		x11-libs/libXrender
-	)
-	xslt? ( dev-libs/libxslt )
-	zeroconf? ( net-dns/avahi[dbus] )
-"
-RDEPEND="${COMMON_DEPEND}
-	lirc? (
-		|| ( app-misc/lirc app-misc/inputlircd )
-	)
-	!media-tv/xbmc
-	udisks? ( sys-fs/udisks:0 )
-	upower? (
-		systemd? ( sys-power/upower )
-		!systemd? (
-			|| ( sys-power/upower-pm-utils sys-power/upower )
-		)
-	)
-"
-DEPEND="${COMMON_DEPEND}
-	app-arch/bzip2
-	app-arch/unzip
-	app-arch/xz-utils
-	app-arch/zip
-	dev-lang/swig
-	dev-libs/crossguid
-	dev-util/cmake
-	dev-util/gperf
-	media-libs/giflib
-	>=media-libs/libjpeg-turbo-1.5.1:=
-	>=media-libs/libpng-1.6.26:0=
-	test? ( dev-cpp/gtest )
-	virtual/pkgconfig
-	x86? ( dev-lang/nasm )
-"
-case ${PV} in
-9999)
-	EGIT_REPO_URI="git://github.com/xbmc/xbmc.git"
-	inherit git-r3
-	# Force java for latest git version to avoid having to hand maintain the
-	# generated addons package.  #488118
-	DEPEND+="
-		virtual/jre
-		"
-	;;
-*)
-	MY_PV=${PV/_p/_r}
-	MY_PV=${MY_PV/_alpha/a}
-	MY_PV=${MY_PV/_beta/b}
-	MY_PV=${MY_PV/_rc/rc}
-	MY_P="${PN}-${MY_PV}"
-	SRC_URI+=" https://github.com/xbmc/xbmc/archive/${MY_PV}-${CODENAME}.tar.gz -> ${MY_P}.tar.gz
-		 !java? ( https://github.com/candrews/gentoo-kodi/raw/master/${MY_P}-generated-addons.tar.xz )"
-	KEYWORDS="amd64 x86"
-	IUSE+=" java"
-	DEPEND+="
-		java? ( virtual/jre )
-		"
-
-	S=${WORKDIR}/xbmc-${MY_PV}-${CODENAME}
-	;;
-esac
-
-CONFIG_CHECK="~IP_MULTICAST"
-ERROR_IP_MULTICAST="
-In some cases Kodi needs to access multicast addresses.
-Please consider enabling IP_MULTICAST under Networking options.
-"
-
-CMAKE_USE_DIR=${S}/project/cmake/
-
-pkg_setup() {
-	check_extra_config
-	python-single-r1_pkg_setup
-}
-
-src_prepare() {
-	if in_iuse java && use !java; then
-		eapply "${FILESDIR}"/${PN}-cmake-no-java.patch
-	fi
-	cmake-utils_src_prepare
-
-	# avoid long delays when powerkit isn't running #348580
-	sed -i \
-		-e '/dbus_connection_send_with_reply_and_block/s:-1:3000:' \
-		xbmc/linux/*.cpp || die
-
-	# Prepare tools and libs witch are configured with autotools during compile time
-	AUTOTOOLS_DIRS=(
-		"${S}"/lib/cpluff
-		"${S}"/tools/depends/native/TexturePacker/src
-		"${S}"/tools/depends/native/JsonSchemaBuilder/src
-	)
-
-	local d
-	for d in "${AUTOTOOLS_DIRS[@]}" ; do
-		pushd ${d} >/dev/null || die
-		AT_NOELIBTOOLIZE="yes" AT_TOPLEVEL_EAUTORECONF="yes" eautoreconf
-		popd >/dev/null || die
-	done
-	elibtoolize
-
-	# Prevent autoreconf rerun
-	sed -e 's/autoreconf -vif/echo "autoreconf already done in src_prepare()"/' -i \
-		"${S}"/project/cmake/modules/FindCpluff.cmake \
-		"${S}"/tools/depends/native/TexturePacker/src/autogen.sh \
-		"${S}"/tools/depends/native/JsonSchemaBuilder/src/autogen.sh
-}
-
-src_configure() {
-	local CMAKE_BUILD_TYPE=$(usex debug Debug RelWithDebInfo)
-
-	local mycmakeargs=(
-		-Ddocdir="${EPREFIX}/usr/share/doc/${PF}"
-		-DENABLE_LDGOLD=OFF # https://bugs.gentoo.org/show_bug.cgi?id=606124
-		-DENABLE_ALSA=$(usex alsa)
-		-DENABLE_AIRTUNES=$(usex airplay)
-		-DENABLE_AVAHI=$(usex zeroconf)
-		-DENABLE_BLUETOOTH=$(usex bluetooth)
-		-DENABLE_BLURAY=$(usex bluray)
-		-DENABLE_CCACHE=OFF
-		-DENABLE_CEC=$(usex cec)
-		-DENABLE_DBUS=$(usex dbus)
-		-DENABLE_DVDCSS=$(usex css)
-		-DENABLE_INTERNAL_CROSSGUID=OFF
-		-DENABLE_INTERNAL_FFMPEG="$(usex !system-ffmpeg)"
-		-DENABLE_CAP=$(usex caps)
-		-DENABLE_LIRC=$(usex lirc)
-		-DENABLE_MICROHTTPD=$(usex webserver)
-		-DENABLE_MYSQLCLIENT=$(usex mysql)
-		-DENABLE_NFS=$(usex nfs)
-		-DENABLE_NONFREE=$(usex nonfree)
-		-DENABLE_OPENGLES=$(usex gles)
-		-DENABLE_OPENGL=$(usex opengl)
-		-DENABLE_OPENSSL=ON
-		-DENABLE_OPTICAL=$(usex dvd)
-		-DENABLE_PLIST=$(usex airplay)
-		-DENABLE_PULSEAUDIO=$(usex pulseaudio)
-		-DENABLE_SMBCLIENT=$(usex samba)
-		-DENABLE_SSH=$(usex sftp)
-		-DENABLE_UDEV=$(usex udev)
-		-DENABLE_UPNP=$(usex upnp)
-		-DENABLE_VAAPI=$(usex vaapi)
-		-DENABLE_VDPAU=$(usex vdpau)
-		-DENABLE_X11=$(usex X)
-		-DENABLE_XSLT=$(usex xslt)
-		-Dlibdvdread_URL="${DISTDIR}/libdvdread-${LIBDVDREAD_COMMIT}.tar.gz"
-		-Dlibdvdnav_URL="${DISTDIR}/libdvdnav-${LIBDVDNAV_COMMIT}.tar.gz"
-		-Dlibdvdcss_URL="${DISTDIR}/libdvdcss-${LIBDVDCSS_COMMIT}.tar.gz"
-	)
-
-	use libusb && mycmakeargs+=( -DENABLE_LIBUSB=$(usex libusb) )
-
-	use !system-ffmpeg && mycmakeargs+=( -DFFMPEG_URL="${DISTDIR}/ffmpeg-${PN}-${FFMPEG_VERSION}-${CODENAME}.tar.gz" )
-
-	cmake-utils_src_configure
-}
-
-src_compile() {
-	cmake-utils_src_compile all $(usev test)
-}
-
-src_install() {
-	cmake-utils_src_install
-	rm "${ED%/}"/usr/share/doc/*/{LICENSE.GPL,copying.txt}* || die
-
-	newicon media/icon48x48.png kodi.png
-
-	# Replace bundled fonts with system ones.
-	rm "${ED%/}"/usr/share/kodi/addons/skin.estouchy/fonts/NotoSans-Regular.ttf || die
-	dosym /usr/share/fonts/noto/NotoSans-Regular.ttf \
-		usr/share/kodi/addons/skin.estouchy/fonts/NotoSans-Regular.ttf
-
-	local f
-	for f in NotoMono-Regular.ttf NotoSans-Bold.ttf NotoSans-Regular.ttf ; do
-		rm "${ED%/}"/usr/share/kodi/addons/skin.estuary/fonts/"${f}" || die
-		dosym /usr/share/fonts/noto/"${f}" \
-			usr/share/kodi/addons/skin.estuary/fonts/"${f}"
-	done
-
-	rm "${ED%/}"/usr/share/kodi/addons/skin.estuary/fonts/Roboto-Thin.ttf || die
-	dosym /usr/share/fonts/roboto/Roboto-Thin.ttf \
-		usr/share/kodi/addons/skin.estuary/fonts/Roboto-Thin.ttf
-
-	python_domodule tools/EventClients/lib/python/xbmcclient.py
-	python_newscript "tools/EventClients/Clients/Kodi Send/kodi-send.py" kodi-send
-}