[gentoo-commits] repo/gentoo:master commit in: sci-astronomy/stellarium/

["Sebastien Fabbro" <bicatali@gentoo.org>]

commit:     389e49bfcb9d439ee3cbb28da450c6e29d815653
Author:     Sébastien Fabbro <bicatali <AT> gentoo <DOT> org>
AuthorDate: Wed Jul  5 19:31:29 2017 +0000
Commit:     Sebastien Fabbro <bicatali <AT> gentoo <DOT> org>
CommitDate: Wed Jul  5 19:31:48 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=389e49bf

sci-astronomy/stellarium: version bump
* dropped ppc on 0.16.0-r1 to allow gps on other arches
* fixed linguas stuff

Package-Manager: Portage-2.3.6, Repoman-2.3.2

 sci-astronomy/stellarium/Manifest                  |   1 +
 .../stellarium/stellarium-0.16.0-r1.ebuild         | 111 +++++++++++++++++++++
 sci-astronomy/stellarium/stellarium-0.16.0.ebuild  | 110 ++++++++++++++++++++
 3 files changed, 222 insertions(+)

diff --git a/sci-astronomy/stellarium/Manifest b/sci-astronomy/stellarium/Manifest
index 4a3add15f65..e77490202a9 100644
--- a/sci-astronomy/stellarium/Manifest
+++ b/sci-astronomy/stellarium/Manifest
@@ -13,3 +13,4 @@ DIST stellarium-0.14.2.tar.gz 139069181 SHA256 aa04a5ae44ed177bc187d20e27a87cc11
 DIST stellarium-0.14.3.tar.gz 137661611 SHA256 de41c5b14fdf0c5f6e73bab2975f380554487b1817f2c5a2ebad3bb8e9e729a4 SHA512 83d9a1c53f118c143e81d31e7f87dbf73368bfa981311c8bc41a51307fe6108c9169b43ad1fdde1cec84b9b1e8a4ef51d4de3b91d7aa676be38302b2223a6675 WHIRLPOOL 441302d93778185c9743451bd04148bd4a8a599eaff4f5a7b90025df9eb9873e1a203f0a82f687b7d2fb53fcf811e16903000d7179c6508738935518a2bbe966
 DIST stellarium-0.15.0.tar.gz 147160785 SHA256 74d0e3a69fcbaf1c6278f601a44497fd3e9f2de7dfa11a60197d3afb68288746 SHA512 3e91cb565343814c96f30a75767ecd56d93ec463cb1e925d169b30a8e0fddd285217193c8a24053aa1ce22e6e842a97c7a4b59c3ee7d65ec33308fa045e905c7 WHIRLPOOL 8a5ad7c8e4755b90976ad8f659668f5cbe49ea4023c0cabf7ae75afe3b4ebbfdd677556d92bf5999b7375e15fa91530787658a338b01dd7dafe4dfb962434e12
 DIST stellarium-0.15.1.tar.gz 155860125 SHA256 0fe52fc496c11d92728742ae6d71bac116746dca7885d34d17b1a288fe8b5b11 SHA512 42b23546e4e2dde8c0fbc5cac8e11204fe63727544356979978c9a820aa28aac48c4a285b40e49a867bf469be89a424d2f6134b97cf0717be6818ce89f20d36f WHIRLPOOL cb0807a5a0a3658aaba1f894383de9e3bd84447b25c513e14c6f5fa16978132e0ca603641759f0e104ea767322c3c08b3e3e07e6fc6e89a0deea5d182cedbdae
+DIST stellarium-0.16.0.tar.gz 204675673 SHA256 2835c4aa22c1b64edbd17b174a23e4ed23654cd09e12f3573709f44843913dcf SHA512 0f75441435ff1d0fa149264116e9ae6ec3b3553f7c66e78832bdb0ffd55cbef656b820680134d95f89c73e80ef283372660ea7545db7fff205da66cf4cf8e9d6 WHIRLPOOL 45b338788313a6e4effc3e1129cbbb1396de303d233e4cc5aeab5ddaebae700f444ed3152c9d7995c59dcf6ac9f375cdee068ad78a0ee40a086d7c22f39833fe

diff --git a/sci-astronomy/stellarium/stellarium-0.16.0-r1.ebuild b/sci-astronomy/stellarium/stellarium-0.16.0-r1.ebuild
new file mode 100644
index 00000000000..82634b69b2e
--- /dev/null
+++ b/sci-astronomy/stellarium/stellarium-0.16.0-r1.ebuild
@@ -0,0 +1,111 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit cmake-utils eutils flag-o-matic gnome2-utils l10n
+
+DESCRIPTION="3D photo-realistic skies in real time"
+HOMEPAGE="http://www.stellarium.org/"
+SRC_URI="
+	mirror://sourceforge/stellarium/${P}.tar.gz
+	stars? (
+		mirror://sourceforge/stellarium/stars_4_1v0_1.cat
+		mirror://sourceforge/stellarium/stars_5_2v0_1.cat
+		mirror://sourceforge/stellarium/stars_6_2v0_1.cat
+		mirror://sourceforge/stellarium/stars_7_2v0_1.cat
+		mirror://sourceforge/stellarium/stars_8_2v0_1.cat
+	)"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="debug gps media nls stars"
+
+RESTRICT="test" # There are no tests
+
+RDEPEND="
+	media-fonts/dejavu
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtopengl:5
+	dev-qt/qtscript:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtprintsupport:5
+	dev-qt/qtserialport:5
+	dev-qt/qtwidgets:5
+	virtual/opengl
+	sys-libs/zlib
+	media? ( dev-qt/qtmultimedia:5[widgets] )
+	gps? ( dev-qt/qtpositioning:5 )
+"
+DEPEND="${RDEPEND}
+	dev-qt/qttest:5
+	dev-qt/qtconcurrent:5
+	nls? ( dev-qt/linguist-tools:5 )"
+
+LANGS=(
+	af am ar as ast az be bg bn bo br bs ca cs
+	cy da de el en en-GB en-US eo es et eu fa fi fil fr
+	ga gd gl gu he hi hr hu hy ia id is it ja ka kk kn ko ky
+	la lb lo lt lv mk ml mn mr ms nb nl nn oc pa pl pt pt-BR ro
+	ru se si sk sl sq sr sv sw ta te tg th tl tr tt uk uz vi
+	zh-CN zh-HK zh-TW zu
+	)
+
+for X in "${LANGS[@]}" ; do
+	IUSE+=" l10n_${X}"
+done
+unset X
+
+src_prepare() {
+	cmake-utils_src_prepare
+	if [[ -n ${L10N} ]] ; then
+		local d
+		for d in po/* ; do
+			[[ -e ${d}/CMakeLists.txt ]] || continue
+			local l loc=""
+			for l in ${L10N//-/_}; do
+				[[ -e ${d}/${l}.po ]] && loc="${loc} ${l}"
+			done
+			sed -e 's/STRING(REGEX REPLACE ".po" "" \([a-z]*\).*$/SET(\1 '"${loc})/" \
+				-i ${d}/CMakeLists.txt || die
+		done
+	fi
+	use debug || append-cppflags -DQT_NO_DEBUG #415769
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_GPS="$(usex gps)"
+		-DENABLE_NLS="$(usex nls)"
+		-DENABLE_MEDIA="$(usex media)"
+	)
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	# use the more up-to-date system fonts
+	rm "${ED%/}"/usr/share/stellarium/data/DejaVuSans{Mono,}.ttf || die
+	dosym ../../fonts/dejavu/DejaVuSans.ttf /usr/share/stellarium/data/DejaVuSans.ttf
+	dosym ../../fonts/dejavu/DejaVuSansMono.ttf /usr/share/stellarium/data/DejaVuSansMono.ttf
+
+	if use stars ; then
+		insinto /usr/share/${PN}/stars/default
+		doins "${DISTDIR}"/stars_{4_1,{5,6,7,8}_2}v0_1.cat
+	fi
+	newicon doc/images/stellarium-logo.png ${PN}.png
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+}

diff --git a/sci-astronomy/stellarium/stellarium-0.16.0.ebuild b/sci-astronomy/stellarium/stellarium-0.16.0.ebuild
new file mode 100644
index 00000000000..55c9473a146
--- /dev/null
+++ b/sci-astronomy/stellarium/stellarium-0.16.0.ebuild
@@ -0,0 +1,110 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit cmake-utils eutils flag-o-matic gnome2-utils l10n
+
+DESCRIPTION="3D photo-realistic skies in real time"
+HOMEPAGE="http://www.stellarium.org/"
+SRC_URI="
+	mirror://sourceforge/stellarium/${P}.tar.gz
+	stars? (
+		mirror://sourceforge/stellarium/stars_4_1v0_1.cat
+		mirror://sourceforge/stellarium/stars_5_2v0_1.cat
+		mirror://sourceforge/stellarium/stars_6_2v0_1.cat
+		mirror://sourceforge/stellarium/stars_7_2v0_1.cat
+		mirror://sourceforge/stellarium/stars_8_2v0_1.cat
+	)"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="debug media nls stars"
+
+RESTRICT="test" # There are no tests
+
+RDEPEND="
+	media-fonts/dejavu
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtopengl:5
+	dev-qt/qtscript:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtprintsupport:5
+	dev-qt/qtwidgets:5
+	virtual/opengl
+	sys-libs/zlib
+	media? ( dev-qt/qtmultimedia:5[widgets] )
+"
+DEPEND="${RDEPEND}
+	dev-qt/qttest:5
+	dev-qt/qtconcurrent:5
+	nls? ( dev-qt/linguist-tools:5 )"
+
+LANGS=(
+	af am ar as ast az be bg bn bo br bs ca cs
+	cy da de el en en-GB en-US eo es et eu fa fi fil fr
+	ga gd gl gu he hi hr hu hy ia id is it ja ka kk kn ko ky
+	la lb lo lt lv mk ml mn mr ms nb nl nn oc pa pl pt pt-BR ro
+	ru se si sk sl sq sr sv sw ta te tg th tl tr tt uk uz vi
+	zh-CN zh-HK zh-TW zu
+	)
+
+for X in "${LANGS[@]}" ; do
+	IUSE+=" l10n_${X}"
+done
+unset X
+
+src_prepare() {
+	cmake-utils_src_prepare
+	if [[ -n ${L10N} ]] ; then
+		local d
+		for d in po/* ; do
+			[[ -e ${d}/CMakeLists.txt ]] || continue
+			local l loc=""
+			for l in ${L10N//-/_}; do
+				[[ -e ${d}/${l}.po ]] && loc="${loc} ${l}"
+			done
+			sed -e 's/STRING(REGEX REPLACE ".po" "" \([a-z]*\).*$/SET(\1 '"${loc})/" \
+				-i ${d}/CMakeLists.txt || die
+		done
+	fi
+	sed -i -e '/ADD_PLUGIN(TelescopeControl 1)/s/1/0/' CMakeLists.txt || die
+	use debug || append-cppflags -DQT_NO_DEBUG #415769
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_GPS=OFF
+		-DENABLE_NLS="$(usex nls)"
+		-DENABLE_MEDIA="$(usex media)"
+	)
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	# use the more up-to-date system fonts
+	rm "${ED%/}"/usr/share/stellarium/data/DejaVuSans{Mono,}.ttf || die
+	dosym ../../fonts/dejavu/DejaVuSans.ttf /usr/share/stellarium/data/DejaVuSans.ttf
+	dosym ../../fonts/dejavu/DejaVuSansMono.ttf /usr/share/stellarium/data/DejaVuSansMono.ttf
+
+	if use stars ; then
+		insinto /usr/share/${PN}/stars/default
+		doins "${DISTDIR}"/stars_{4_1,{5,6,7,8}_2}v0_1.cat
+	fi
+	newicon doc/images/stellarium-logo.png ${PN}.png
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+}