[gentoo-commits] repo/gentoo:master commit in: sci-electronics/pulseview/

["Sven Wegener" <swegener@gentoo.org>]

commit:     d637efb790a717143ff83f0e2b97254ff3331564
Author:     Sven Wegener <swegener <AT> gentoo <DOT> org>
AuthorDate: Sat Jul  1 20:51:45 2017 +0000
Commit:     Sven Wegener <swegener <AT> gentoo <DOT> org>
CommitDate: Sat Jul  1 20:52:36 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d637efb7

sci-electronics/pulseview: Version bump

Package-Manager: Portage-2.3.6, Repoman-2.3.2

 sci-electronics/pulseview/Manifest               |  1 +
 sci-electronics/pulseview/pulseview-0.4.0.ebuild | 59 ++++++++++++++++++++++++
 2 files changed, 60 insertions(+)

diff --git a/sci-electronics/pulseview/Manifest b/sci-electronics/pulseview/Manifest
index 84ad65c85b5..dba427af021 100644
--- a/sci-electronics/pulseview/Manifest
+++ b/sci-electronics/pulseview/Manifest
@@ -1,2 +1,3 @@
 DIST pulseview-0.2.0.tar.gz 148799 SHA256 feb5d33a0a91c989bfc39fa758195755e78e87c3cf445bb135a8c8d4f86bc1dd SHA512 f770510ceade6382de2d09ba7819a9b39623f3ccbbb4a3a64bb0a64f774d356583f6ad2812a845978d1eaf50dcbfd4688ceec3005d0b712a087d1f686d3c0301 WHIRLPOOL 31068fcebd4286d325db37327c351e8cbd00e095901c04a3d034c127b1272e7c463400a91683cbb64a775b86f5cf61411f1f809e7b4dcd76113ceeb63990eaa2
 DIST pulseview-0.3.0.tar.gz 188602 SHA256 5ffe2cb7a602fcdc60933d400c77bcd66e6ce529bc4f6e97d6a5e5a86f2f530e SHA512 81c509ef3e548ab8ff29633a07c280cee1fba5cc94db7fc1fbc64822eccb905ab5fb4126392cabe0c089e51896a02e0fbc6c0f265bf728cee6ac6651c3ab883a WHIRLPOOL f23f420ab2d0083a234eff5d757fac0ebbfbe97670bf229292fb91d7f3ba6f3a37c7716bbece607b6593133da41ac103cfcfb4f46986ba6bc243d379fb4413dd
+DIST pulseview-0.4.0.tar.gz 226656 SHA256 78f8291045c6f65b4827b12e83c8e68cea2d5e7268b15a51aaca9726c8100eb9 SHA512 833a86681925fb4fb2118bb9d0044fc80174aef299b7e6ba2df83bff490511b91cd18f63f45e9a63f21c0df5d8aad3ec27ab35f45cd9959a42831b0b8a71da33 WHIRLPOOL bc2c97049e20ffcdc026fc0e33597be2ac1a213782a2fd9abaf7d8f0751b204d73ebbe5de16df4b4854ebfaddeabdf9e0b3d2e72ac8eb906b6397634f0efa926

diff --git a/sci-electronics/pulseview/pulseview-0.4.0.ebuild b/sci-electronics/pulseview/pulseview-0.4.0.ebuild
new file mode 100644
index 00000000000..c408727be2a
--- /dev/null
+++ b/sci-electronics/pulseview/pulseview-0.4.0.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+PYTHON_COMPAT=( python3_{4,5,6} )
+
+inherit cmake-utils python-single-r1
+
+if [[ ${PV} == "9999" ]]; then
+	EGIT_REPO_URI="git://sigrok.org/${PN}"
+	inherit git-r3
+else
+	SRC_URI="http://sigrok.org/download/source/${PN}/${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="Qt based logic analyzer GUI for sigrok"
+HOMEPAGE="http://sigrok.org/wiki/PulseView"
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="+decode qt4 qt5 static"
+REQUIRED_USE="decode? ( ${PYTHON_REQUIRED_USE} ) ^^ ( qt4 qt5 )"
+
+RDEPEND="
+	>=dev-libs/boost-1.55:=
+	>=dev-libs/glib-2.28.0:2
+	>=dev-cpp/glibmm-2.28.0:2
+	>=sci-libs/libsigrok-0.5.0[cxx]
+	qt4? (
+		>=dev-qt/qtcore-4.5:4
+		>=dev-qt/qtgui-4.5:4
+		>=dev-qt/qtsvg-4.5:4
+	)
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtwidgets:5
+		dev-qt/qtsvg:5
+	)
+	decode? (
+		>=sci-libs/libsigrokdecode-0.5.0[${PYTHON_USEDEP}]
+		${PYTHON_DEPS}
+	)"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+DOCS=( HACKING NEWS README )
+
+src_configure() {
+	local mycmakeargs=(
+		-DDISABLE_WERROR=TRUE
+		-DENABLE_DECODE=$(usex decode)
+		-DSTATIC_PKGDEPS_LIBS=$(usex static)
+		-DFORCE_QT4=$(usex qt4)
+	)
+	cmake-utils_src_configure
+}