[gentoo-commits] repo/gentoo:master commit in: www-misc/fcgiwrap/

["Matt Turner" <mattst88@gentoo.org>]

commit:     3bf8c027f02001a8f5ca16531f794302b9b40156
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Sun Jun 18 16:21:51 2017 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Sun Jun 18 16:22:37 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=3bf8c027

www-misc/fcgiwrap: Add 1.1.0_pre20150419 snapshot

 www-misc/fcgiwrap/Manifest                         |  1 +
 .../fcgiwrap/fcgiwrap-1.1.0_pre20150419.ebuild     | 63 ++++++++++++++++++++++
 2 files changed, 64 insertions(+)

diff --git a/www-misc/fcgiwrap/Manifest b/www-misc/fcgiwrap/Manifest
index e6596f48a85..651d5ec9d9b 100644
--- a/www-misc/fcgiwrap/Manifest
+++ b/www-misc/fcgiwrap/Manifest
@@ -1 +1,2 @@
 DIST fcgiwrap-1.1.0.tar.gz 9924 SHA256 4c7de0db2634c38297d5fcef61ab4a3e21856dd7247d49c33d9b19542bd1c61f SHA512 b8d35762d1d3c94a67602290b0092f0c38cffbbcd3dbc16597abf8b92172909b04450c238de2e430e841a17dd47fdd48d6a001f77539966980ef1af61e447ddc WHIRLPOOL 0df7ab6de6b97db0e516f2ec79185391f0cd2ca2f3ea81b88739546f41a613be3e469394baf3901708b337c8fc7145529e0afb8e884b9ca52d0fba664487e7c0
+DIST fcgiwrap-1.1.0_pre20150419.tar.gz 10834 SHA256 2aefec1bac8cb6131ff994dee7440a3e12f7761bf35152ceb38c472cb4becf9a SHA512 48df3f0b5ad15d172b7ee883d53c59ecbd78c0c401ef1452df8fc03af1a7aed153464b2515ca18881af70f6baf6c80e0b405d1dde4888a20397b9db272ea6ba4 WHIRLPOOL 83aa10235c232efc96af3ae7c37da0565d34183e965733512ec2b8c7f94b29989cc9285adf35f69ada0acf13ff27641e37fa64ff676a3890853164dcbe13c852

diff --git a/www-misc/fcgiwrap/fcgiwrap-1.1.0_pre20150419.ebuild b/www-misc/fcgiwrap/fcgiwrap-1.1.0_pre20150419.ebuild
new file mode 100644
index 00000000000..c2894ba93aa
--- /dev/null
+++ b/www-misc/fcgiwrap/fcgiwrap-1.1.0_pre20150419.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+[[ ${PV} = *9999* ]] && VCS_ECLASS="git-r3" || VCS_ECLASS=""
+inherit autotools systemd toolchain-funcs ${VCS_ECLASS}
+
+DESCRIPTION="Simple FastCGI wrapper for CGI scripts (CGI support for nginx)"
+HOMEPAGE="https://github.com/gnosek/fcgiwrap"
+
+LICENSE="BSD"
+SLOT="0"
+IUSE="systemd"
+
+if [[ ${PV} == *9999* ]]; then
+	EGIT_REPO_URI="git://github.com/gnosek/${PN}.git"
+else
+	MY_REV="99c942c90063c73734e56bacaa65f947772d9186"
+	MY_P="gnosek-fcgiwrap-${MY_REV:0:7}"
+	SRC_URI="https://github.com/gnosek/${PN}/tarball/${MY_REV} -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~x86"
+fi
+
+RDEPEND="
+	dev-libs/fcgi
+	systemd? ( sys-apps/systemd )
+"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+DOCS=( README.rst )
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+	sed -e "s/-Werror//" \
+		-i configure.ac || die "sed failed"
+
+	sed -e '/man8dir = $(DESTDIR)/s/@prefix@//' \
+		-i Makefile.in || die "sed failed"
+
+	sed -e "s/libsystemd-daemon/libsystemd/" \
+		-i configure.ac || die "sed failed"
+	tc-export CC
+
+	# Fix systemd units for Gentoo
+	sed -i -e '/User/d' systemd/fcgiwrap.service || die
+	sed -i -e '/Group/d' systemd/fcgiwrap.service || die
+
+	eapply_user
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(use_with systemd) \
+		--with-systemdsystemunitdir="$(systemd_get_systemunitdir)"
+}
+
+pkg_postinst() {
+	einfo 'You may want to install www-servers/spawn-fcgi to use with fcgiwrap.'
+}