[gentoo-commits] repo/gentoo:master commit in: sys-devel/gettext/

["Lars Wendler" <polynomial-c@gentoo.org>]

commit:     ff127a5fdec76a3ec3a58e0025ca381cd17d9eb0
Author:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
AuthorDate: Sat Jun 17 22:03:16 2017 +0000
Commit:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
CommitDate: Sat Jun 17 22:07:49 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ff127a5f

sys-devel/gettext: Removed old.

Package-Manager: Portage-2.3.6, Repoman-2.3.2

 sys-devel/gettext/Manifest              |   1 -
 sys-devel/gettext/gettext-0.19.7.ebuild | 139 --------------------------------
 2 files changed, 140 deletions(-)

diff --git a/sys-devel/gettext/Manifest b/sys-devel/gettext/Manifest
index 48a6b8974a2..45ba8b69fd7 100644
--- a/sys-devel/gettext/Manifest
+++ b/sys-devel/gettext/Manifest
@@ -1,2 +1 @@
-DIST gettext-0.19.7.tar.gz 19235781 SHA256 5386d2a40500295783c6a52121adcf42a25519e2d23675950619c9e69558c23f SHA512 7ba89074d3eddd0b4a5e2980e1ec74b53c49b7a04a1fa91c70c4bc11ce9c30415e4df9d79698148eaaed325fb4feb25a340a2e8e01fbe86b1a66b1376a4c9e3d WHIRLPOOL eb51c4be7c0a92c5c33c16329003e21947e0b9d1583c4a785ae6836f81273ea7ec2823a0a28ae81c3b977f2148c0f3bd524949484383ff87510e1d2bc642a786
 DIST gettext-0.19.8.1.tar.gz 19704011 SHA256 ff942af0e438ced4a8b0ea4b0b6e0d6d657157c5e2364de57baa279c1c125c43 SHA512 073042fa2dc48804c58e76f036130a669e19612c25427b0ab14d0b366b549a63751bf3af03bfd0745d7c4f72497a4b2aab26a3cc6de83189ce111679073878e1 WHIRLPOOL ef9aa9eef3067595dc725169075401dfad8ba15d6224d2b563e3421afa7c4dce9336a287147404273b772def811230b3758c005902ec90192e6ee4ac373d9a9a

diff --git a/sys-devel/gettext/gettext-0.19.7.ebuild b/sys-devel/gettext/gettext-0.19.7.ebuild
deleted file mode 100644
index 078025271d5..00000000000
--- a/sys-devel/gettext/gettext-0.19.7.ebuild
+++ /dev/null
@@ -1,139 +0,0 @@
-# Copyright 1999-2017 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-# Note: Keep version bumps in sync with dev-libs/libintl.
-
-EAPI="5"
-
-inherit epatch epunt-cxx ltprune mono-env libtool java-pkg-opt-2 multilib-minimal
-
-DESCRIPTION="GNU locale utilities"
-HOMEPAGE="https://www.gnu.org/software/gettext/"
-SRC_URI="mirror://gnu/${PN}/${P}.tar.gz"
-
-# Only libasprintf is under the LGPL (and libintl is in a sep package),
-# so put that license behind USE=cxx.
-LICENSE="GPL-3+ cxx? ( LGPL-2.1+ )"
-SLOT="0"
-KEYWORDS="alpha amd64 arm arm64 hppa ia64 m68k ~mips ppc ppc64 s390 sh sparc x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd"
-IUSE="acl -cvs +cxx doc emacs git java ncurses nls openmp static-libs"
-
-# only runtime goes multilib
-# Note: The version of libxml2 corresponds to the version bundled via gnulib.
-# If the build detects too old of a system version, it will end up falling back
-# to the bundled copy.  #596918
-# Note: expat lacks a subslot because it is dynamically loaded at runtime.  We
-# would depend on older subslots if they were available (based on the ABIs that
-# are explicitly handled), but expat doesn't currently use subslots.
-DEPEND=">=virtual/libiconv-0-r1[${MULTILIB_USEDEP}]
-	>=virtual/libintl-0-r2[${MULTILIB_USEDEP}]
-	>=dev-libs/libxml2-2.9.3:=
-	dev-libs/expat
-	acl? ( virtual/acl )
-	ncurses? ( sys-libs/ncurses:0= )
-	java? ( >=virtual/jdk-1.4 )"
-RDEPEND="${DEPEND}
-	!git? ( cvs? ( dev-vcs/cvs ) )
-	git? ( dev-vcs/git )
-	java? ( >=virtual/jre-1.4 )"
-PDEPEND="emacs? ( app-emacs/po-mode )"
-
-MULTILIB_WRAPPED_HEADERS=(
-	# only installed for native ABI
-	/usr/include/gettext-po.h
-)
-
-pkg_setup() {
-	mono-env_pkg_setup
-	java-pkg-opt-2_pkg_setup
-}
-
-src_prepare() {
-	java-pkg-opt-2_src_prepare
-
-	epatch "${FILESDIR}"/${PN}-0.19.7-disable-libintl.patch #564168
-
-	epunt_cxx
-	elibtoolize
-}
-
-multilib_src_configure() {
-	local myconf=(
-		# switches common to runtime and top-level
-		--cache-file="${BUILD_DIR}"/config.cache
-		--docdir="\$(datarootdir)/doc/${PF}"
-
-		# Emacs support is now in a separate package
-		--without-emacs
-		--without-lispdir
-		# glib depends on us so avoid circular deps
-		--with-included-glib
-		# libcroco depends on glib which ... ^^^
-		--with-included-libcroco
-		# this will _disable_ libunistring (since it is not bundled),
-		# see bug #326477
-		--with-included-libunistring
-		# Never build libintl since it's in dev-libs/libintl now.
-		--without-included-gettext
-		# Never build bundled copy of libxml2.
-		--without-included-libxml
-
-		$(use_enable acl)
-		$(use_enable cxx c++)
-		$(use_enable cxx libasprintf)
-		$(use_with git)
-		$(usex git --without-cvs $(use_with cvs))
-		$(use_enable java)
-		$(use_enable ncurses curses)
-		$(use_enable nls)
-		$(use_enable openmp)
-		$(use_enable static-libs static)
-	)
-
-	local ECONF_SOURCE=${S}
-	if ! multilib_is_native_abi ; then
-		# for non-native ABIs, we build runtime only
-		ECONF_SOURCE+=/gettext-runtime
-	fi
-
-	econf "${myconf[@]}"
-}
-
-multilib_src_install() {
-	default
-
-	if multilib_is_native_abi ; then
-		dosym msgfmt /usr/bin/gmsgfmt #43435
-		dobin gettext-tools/misc/gettextize
-	fi
-}
-
-multilib_src_install_all() {
-	use nls || rm -r "${D}"/usr/share/locale
-	use static-libs || prune_libtool_files --all
-
-	rm -f "${D}"/usr/share/locale/locale.alias "${D}"/usr/lib/charset.alias
-
-	if use java ; then
-		java-pkg_dojar "${D}"/usr/share/${PN}/*.jar
-		rm -f "${D}"/usr/share/${PN}/*.jar
-		rm -f "${D}"/usr/share/${PN}/*.class
-		if use doc ; then
-			java-pkg_dojavadoc "${D}"/usr/share/doc/${PF}/javadoc2
-			rm -rf "${D}"/usr/share/doc/${PF}/javadoc2
-		fi
-	fi
-
-	if use doc ; then
-		dohtml "${D}"/usr/share/doc/${PF}/*.html
-	else
-		rm -rf "${D}"/usr/share/doc/${PF}/{csharpdoc,examples,javadoc2,javadoc1}
-	fi
-	rm -f "${D}"/usr/share/doc/${PF}/*.html
-
-	dodoc AUTHORS ChangeLog NEWS README THANKS
-}
-
-pkg_preinst() {
-	java-pkg-opt-2_pkg_preinst
-}