From mboxrd@z Thu Jan  1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-954200-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
	(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
	(No client certificate requested)
	by finch.gentoo.org (Postfix) with ESMTPS id B4E3C139694
	for <garchives@archives.gentoo.org>; Tue,  6 Jun 2017 18:26:39 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
	by pigeon.gentoo.org (Postfix) with SMTP id 1A44421C0A3;
	Tue,  6 Jun 2017 18:26:37 +0000 (UTC)
Received: from smtp.gentoo.org (smtp.gentoo.org [140.211.166.183])
	(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
	(No client certificate requested)
	by pigeon.gentoo.org (Postfix) with ESMTPS id DABAE21C0A3
	for <gentoo-commits@lists.gentoo.org>; Tue,  6 Jun 2017 18:26:36 +0000 (UTC)
Received: from oystercatcher.gentoo.org (unknown [IPv6:2a01:4f8:202:4333:225:90ff:fed9:fc84])
	(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
	(No client certificate requested)
	by smtp.gentoo.org (Postfix) with ESMTPS id 0ED93341A29
	for <gentoo-commits@lists.gentoo.org>; Tue,  6 Jun 2017 18:26:35 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
	by oystercatcher.gentoo.org (Postfix) with ESMTP id 46F3A73E0
	for <gentoo-commits@lists.gentoo.org>; Tue,  6 Jun 2017 18:26:30 +0000 (UTC)
From: "Kristian Fiskerstrand" <k_f@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Kristian Fiskerstrand" <k_f@gentoo.org>
Message-ID: <1496773493.41ab815fe8887c360dd98fd3d8dec9cbf0ddb11d.k_f@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: net-p2p/deluge/
X-VCS-Repository: repo/gentoo
X-VCS-Files: net-p2p/deluge/Manifest net-p2p/deluge/deluge-1.3.15.ebuild
X-VCS-Directories: net-p2p/deluge/
X-VCS-Committer: k_f
X-VCS-Committer-Name: Kristian Fiskerstrand
X-VCS-Revision: 41ab815fe8887c360dd98fd3d8dec9cbf0ddb11d
X-VCS-Branch: master
Date: Tue,  6 Jun 2017 18:26:30 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Archives-Salt: efaa5cb0-fcf8-4436-b925-6aaa538db381
X-Archives-Hash: ae5cc408be4c728524cc1e1c1281447c

commit:     41ab815fe8887c360dd98fd3d8dec9cbf0ddb11d
Author:     Kristian Fiskerstrand <k_f <AT> gentoo <DOT> org>
AuthorDate: Tue Jun  6 18:24:10 2017 +0000
Commit:     Kristian Fiskerstrand <k_f <AT> gentoo <DOT> org>
CommitDate: Tue Jun  6 18:24:53 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=41ab815f

net-p2p/deluge: New version 1.3.15

Proxied commit
Thanks-To: Paolo Pedroni

Gentoo-Bug: 619812
Gentoo-Bug: 618872

Package-Manager: Portage-2.3.5, Repoman-2.3.1

 net-p2p/deluge/Manifest             |   1 +
 net-p2p/deluge/deluge-1.3.15.ebuild | 143 ++++++++++++++++++++++++++++++++++++
 2 files changed, 144 insertions(+)

diff --git a/net-p2p/deluge/Manifest b/net-p2p/deluge/Manifest
index 115a834eeab..d33634ac1e3 100644
--- a/net-p2p/deluge/Manifest
+++ b/net-p2p/deluge/Manifest
@@ -1 +1,2 @@
 DIST deluge-1.3.14.tar.bz2 1774160 SHA256 c38ab40d71bf5c1b500958b2679fdfd3c45121860f1fade69b654ebd94e1ed09 SHA512 5bf37b647a84b31c4c5fa660a7a9b1f20eaac25dfe314dbc771d3ca40259e0f994ebfc6925e81902698b04291de1cae8efb0e246f1aca631bdbcdfda51b9ba42 WHIRLPOOL 76fc95acec3366f75f26e66207bb31a51f9ac55eb8882e106ca9086170973378bd796db55b2acdb70fa38467ff0f67c5822b7f0692218b4b603a2e77bf6b7ce7
+DIST deluge-1.3.15.tar.bz2 1775913 SHA256 dcf823131be56c2180814e8def11496aaaf700710b5694867ba9f057615ac790 SHA512 1d0f93a8c5081b807a390f79101d7f26751b0dfc47efe4c3573541014f9e5969461e2d421d17646c17fb81eb4f66f25f5ddce63b9bd226989adb7d7506146bda WHIRLPOOL 93f3b2c86b983ecea7b001f0b58bd6e904ecc4c11c718286885d82b09f0068c4bf347b03be12edfe77677604d3af3ca9a68e8a2a08d696ff16f5385eb43c464f

diff --git a/net-p2p/deluge/deluge-1.3.15.ebuild b/net-p2p/deluge/deluge-1.3.15.ebuild
new file mode 100644
index 00000000000..39d19840892
--- /dev/null
+++ b/net-p2p/deluge/deluge-1.3.15.ebuild
@@ -0,0 +1,143 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+PYTHON_COMPAT=( python2_7 )
+DISTUTILS_SINGLE_IMPL=1
+PLOCALES="af ar ast be bg bn bs ca cs cy da de el en_AU en_CA en_GB eo es et eu fa fi fo fr fy ga gl he hi hr hu id is it iu ja ka kk km kn ko ku ky la lb lt lv mk ml ms nap nb nds nl nn oc pl pms pt pt_BR ro ru si sk sl sr sv ta te th tl tlh tr uk ur vi zh_CN zh_HK zh_TW"
+inherit distutils-r1 eutils systemd user l10n
+
+DESCRIPTION="BitTorrent client with a client/server model"
+HOMEPAGE="http://deluge-torrent.org/"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="git://deluge-torrent.org/${PN}.git
+		http://git.deluge-torrent.org/${PN}"
+	SRC_URI=""
+	KEYWORDS="~amd64 ~x86"
+else
+	SRC_URI="http://download.deluge-torrent.org/source/${P}.tar.bz2"
+	KEYWORDS="~amd64 ~arm ~ppc ~sparc ~x86"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="console geoip gtk libnotify sound webinterface"
+REQUIRED_USE="
+	${PYTHON_REQUIRED_USE}
+	sound? ( gtk )
+	libnotify? ( gtk )
+"
+PATCHES=(
+	"${FILESDIR}/${PN}-1.3.5-disable_libtorrent_internal_copy.patch"
+)
+
+CDEPEND="<net-libs/libtorrent-rasterbar-1.1[python,${PYTHON_USEDEP}]"
+DEPEND="${CDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	dev-util/intltool"
+RDEPEND="${CDEPEND}
+	dev-python/chardet[${PYTHON_USEDEP}]
+	dev-python/pyopenssl[${PYTHON_USEDEP}]
+	dev-python/pyxdg[${PYTHON_USEDEP}]
+	dev-python/setproctitle[${PYTHON_USEDEP}]
+	|| ( >=dev-python/twisted-16.0.0[${PYTHON_USEDEP}]
+		(
+		>=dev-python/twisted-core-13.0[${PYTHON_USEDEP}]
+		>=dev-python/twisted-web-13.0[${PYTHON_USEDEP}]
+		)
+	)
+	geoip? ( dev-libs/geoip )
+	gtk? (
+		sound? ( dev-python/pygame[${PYTHON_USEDEP}] )
+		dev-python/pygobject:2[${PYTHON_USEDEP}]
+		>=dev-python/pygtk-2.12[${PYTHON_USEDEP}]
+		gnome-base/librsvg
+		libnotify? ( dev-python/notify-python[${PYTHON_USEDEP}] )
+	)
+	webinterface? ( dev-python/mako[${PYTHON_USEDEP}] )"
+
+python_prepare_all() {
+	local args=(
+		-e "/Compiling po file/a \\\tuptoDate = False"
+	)
+	sed -i "${args[@]}" -- 'setup.py' || die
+	args=(
+		-e 's|"new_release_check": True|"new_release_check": False|'
+		-e 's|"check_new_releases": True|"check_new_releases": False|'
+		-e 's|"show_new_releases": True|"show_new_releases": False|'
+	)
+	sed -i "${args[@]}" -- 'deluge/core/preferencesmanager.py' || die
+
+	local loc_dir="${S}/deluge/i18n"
+	l10n_find_plocales_changes "${loc_dir}" "" ".po"
+	rm_loc() {
+		rm -vf "${loc_dir}/${1}.po" || die
+	}
+	l10n_for_each_disabled_locale_do rm_loc
+
+	distutils-r1_python_prepare_all
+}
+
+esetup.py() {
+	# bug 531370: deluge has its own plugin system. No need to relocate its egg info files.
+	# Override this call from the distutils-r1 eclass.
+	# This does not respect the distutils-r1 API. DONOT copy this example.
+	set -- "${PYTHON}" setup.py "$@"
+	echo "$@"
+	"$@" || die
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	if ! use console ; then
+		rm -rf "${D}/usr/$(get_libdir)/python2.7/site-packages/deluge/ui/console/" || die
+		rm -f "${D}/usr/bin/deluge-console" || die
+		rm -f "${D}/usr/share/man/man1/deluge-console.1" ||die
+	fi
+	if ! use gtk ; then
+		rm -rf "${D}/usr/$(get_libdir)/python2.7/site-packages/deluge/ui/gtkui/" || die
+		rm -rf "${D}/usr/share/icons/" || die
+		rm -f "${D}/usr/bin/deluge-gtk" || die
+		rm -f "${D}/usr/share/man/man1/deluge-gtk.1" || die
+		rm -f "${D}/usr/share/applications/deluge.desktop" || die
+	fi
+	if use webinterface; then
+		newinitd "${FILESDIR}/deluge-web.init" deluge-web
+		newconfd "${FILESDIR}/deluge-web.conf" deluge-web
+		systemd_newunit "${FILESDIR}/deluge-web.service-2" deluge-web.service
+		systemd_install_serviced "${FILESDIR}/deluge-web.service.conf"
+	else
+		rm -rf "${D}/usr/$(get_libdir)/python2.7/site-packages/deluge/ui/web/" || die
+		rm -f "${D}/usr/bin/deluge-web" || die
+		rm -f "${D}/usr/share/man/man1/deluge-web.1" || die
+	fi
+	newinitd "${FILESDIR}"/deluged.init-2 deluged
+	newconfd "${FILESDIR}"/deluged.conf-2 deluged
+	systemd_newunit "${FILESDIR}"/deluged.service-2 deluged.service
+	systemd_install_serviced "${FILESDIR}"/deluged.service.conf
+}
+
+pkg_postinst() {
+	enewgroup ${PN}
+	enewuser ${PN} -1 -1 /var/lib/${PN} ${PN}
+	elog
+	elog "If, after upgrading, deluge doesn't work, please remove the"
+	elog "'~/.config/deluge' directory and try again, but make a backup"
+	elog "first!"
+	elog
+	elog "To start the daemon either run 'deluged' as user"
+	elog "or modify /etc/conf.d/deluged and run"
+	elog "/etc/init.d/deluged start as root"
+	elog "You can still use deluge the old way"
+	elog
+	elog "Systemd unit files for deluged and deluge-web no longer source"
+	elog "/etc/conf.d/deluge* files. Environment variable customization now"
+	elog "happens in /etc/systemd/system/deluged.service.d/00gentoo.conf"
+	elog "and /etc/systemd/system/deluge-web.service.d/00gentoo.conf"
+	elog
+	elog "For more information look at http://dev.deluge-torrent.org/wiki/Faq"
+	elog
+}