[gentoo-commits] repo/gentoo:master commit in: sys-auth/keystone/

["Matt Thode" <prometheanfire@gentoo.org>]

commit:     ff974102eaa6576a70b7085457dde96e5549e536
Author:     Matthew Thode <prometheanfire <AT> gentoo <DOT> org>
AuthorDate: Tue May 30 19:08:30 2017 +0000
Commit:     Matt Thode <prometheanfire <AT> gentoo <DOT> org>
CommitDate: Tue May 30 19:15:38 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ff974102

sys-auth/keystone: 11.0.2 bup

Package-Manager: Portage-2.3.5, Repoman-2.3.2

 sys-auth/keystone/Manifest               |   1 +
 sys-auth/keystone/keystone-11.0.2.ebuild | 158 +++++++++++++++++++++++++++++++
 2 files changed, 159 insertions(+)

diff --git a/sys-auth/keystone/Manifest b/sys-auth/keystone/Manifest
index 972b92a0dc2..a3a1e72cc88 100644
--- a/sys-auth/keystone/Manifest
+++ b/sys-auth/keystone/Manifest
@@ -1,3 +1,4 @@
 DIST keystone-10.0.1.tar.gz 1357929 SHA256 1030e6e818db6b9d84a2ad430912b821c9309ecf600fd0753bd75a741a9e4ddc SHA512 86069e19f519dcf51079a1c3a32658fabdaf5c59b4f5010dd6d3ddc28dbdf710a271d22af22d3451b5553eff609da6252577f8329a7f3a517da148bf37207c86 WHIRLPOOL f24a8bbd3efce90e26d00e484bd5b5cac738568a4fb4948b8f3fa6d51e34bf83488247168cdf75533e80b05a28c17bd3b5bf9f3298f40e86fa5f80255992c025
 DIST keystone-11.0.0.tar.gz 1399328 SHA256 296f18beb4494b243bf78a8f6e14d0f6e402d230620f870ee76955d5b135afe2 SHA512 3e054613973dc67e54e9eb248a42685eda3b7a98236955246b02ed2a0193bbab606d8cc8b4cd6f05b15de2cc68f3a1f12f43a4d5725591cfcef4de063b834598 WHIRLPOOL d8ce1c87e68a339ecbc132d93eb657d1ff5d2f9e669020621b1e53a06313b5b907623d752e980541726528ee90a243788088642cfef322802cdf01e647946a7e
 DIST keystone-11.0.1.tar.gz 1373584 SHA256 b1117e6074c94e0d87d4ddba46f5ee3f786ebc98322cd13c206887e773770248 SHA512 c911883c575436e1696deb5522cc7715d6feaa217e9afc8dad2cbf93840ad1e29eca9e8d101385b55d660867bcf3da4d74497cb6f28e337a5fc75fff64c5a394 WHIRLPOOL bd8221c8340f9f4ea8b8dfad3c5941bd49925a6786f83abf6b9f9f7486558e60be0327f2ac0b969565f5e126ba0ce4024ae732104a1a82864043fd94b2ef133f
+DIST keystone-11.0.2.tar.gz 1370396 SHA256 cf25068272dba6c6487477e3d620ae449770d73d3e3382d37d2b88cf80fe9ef1 SHA512 d2ec2c6e01df524f5dbec12960ffb54bb2a5400fff61027d6e632b1d775223e5e7ca97962db70acfbcd61e6c13ce9f5e392fc44249836055228ba4547e4ae4e6 WHIRLPOOL 7c9eff71b588632b125ca22824477116e387d4cfbf46b724510806b24a5d1d7694e3566da43ea8f0646a2c7059b8e6eb58343d6df4abec0427a4197f2a64354d

diff --git a/sys-auth/keystone/keystone-11.0.2.ebuild b/sys-auth/keystone/keystone-11.0.2.ebuild
new file mode 100644
index 00000000000..5ffc0c9e0c8
--- /dev/null
+++ b/sys-auth/keystone/keystone-11.0.2.ebuild
@@ -0,0 +1,158 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_4 )
+
+inherit distutils-r1 user
+
+DESCRIPTION="The Openstack authentication, authorization, and service catalog"
+HOMEPAGE="https://launchpad.net/keystone"
+SRC_URI="https://tarballs.openstack.org/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="+sqlite ldap memcached mongo mysql postgres test"
+REQUIRED_USE="|| ( mysql postgres sqlite )"
+
+CDEPEND=">=dev-python/pbr-1.8[${PYTHON_USEDEP}]"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	${CDEPEND}"
+RDEPEND="
+	${CDEPEND}
+	>=dev-python/Babel-2.3.4[${PYTHON_USEDEP}]
+	>=dev-python/webob-1.6.0[${PYTHON_USEDEP}]
+	>=dev-python/pastedeploy-1.5.0[${PYTHON_USEDEP}]
+	dev-python/paste[${PYTHON_USEDEP}]
+	>=dev-python/routes-1.12.3[${PYTHON_USEDEP}]
+	!~dev-python/routes-2.0[${PYTHON_USEDEP}]
+	!~dev-python/routes-2.1[$(python_gen_usedep 'python2_7')]
+	!~dev-python/routes-2.3.0[${PYTHON_USEDEP}]
+	>=dev-python/cryptography-1.0[${PYTHON_USEDEP}]
+	!~dev-python/cryptography-1.3.0[${PYTHON_USEDEP}]
+	>=dev-python/six-1.9.0[${PYTHON_USEDEP}]
+	sqlite? (
+		>=dev-python/sqlalchemy-1.0.10[sqlite,${PYTHON_USEDEP}]
+		<dev-python/sqlalchemy-1.1.0[sqlite,${PYTHON_USEDEP}]
+	)
+	mysql? (
+		>=dev-python/pymysql-0.7.6[${PYTHON_USEDEP}]
+		!~dev-python/pymysql-0.7.7[${PYTHON_USEDEP}]
+		>=dev-python/sqlalchemy-1.0.10[${PYTHON_USEDEP}]
+		<dev-python/sqlalchemy-1.1.0[${PYTHON_USEDEP}]
+	)
+	postgres? (
+		>=dev-python/psycopg-2.5.0[${PYTHON_USEDEP}]
+		>=dev-python/sqlalchemy-1.0.10[${PYTHON_USEDEP}]
+		<dev-python/sqlalchemy-1.1.0[${PYTHON_USEDEP}]
+	)
+	>=dev-python/sqlalchemy-migrate-0.9.6[${PYTHON_USEDEP}]
+	>=dev-python/stevedore-1.17.1[${PYTHON_USEDEP}]
+	>=dev-python/passlib-1.7.0[${PYTHON_USEDEP}]
+	>=dev-python/python-keystoneclient-3.8.0[${PYTHON_USEDEP}]
+	>=dev-python/keystonemiddleware-4.12.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-cache-1.5.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-concurrency-3.8.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-config-3.14.0[${PYTHON_USEDEP}]
+	!~dev-python/oslo-config-3.18.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-context-2.9.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-messaging-5.14.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-db-4.15.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-i18n-2.1.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-log-3.11.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-middleware-3.0.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-policy-1.17.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-serialization-1.10.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-utils-3.18.0[${PYTHON_USEDEP}]
+	>=dev-python/oauthlib-0.6.0[${PYTHON_USEDEP}]
+	>=dev-python/pysaml2-2.4.0[${PYTHON_USEDEP}]
+	<dev-python/pysaml2-4.0.3[${PYTHON_USEDEP}]
+	>=dev-python/dogpile-cache-0.6.2[${PYTHON_USEDEP}]
+	>=dev-python/jsonschema-2.0.0[${PYTHON_USEDEP}]
+	!~dev-python/jsonschema-2.5.0[${PYTHON_USEDEP}]
+	<dev-python/jsonschema-3.0.0[${PYTHON_USEDEP}]
+	>=dev-python/pycadf-1.1.0[${PYTHON_USEDEP}]
+	!~dev-python/pycadf-2.0.0[${PYTHON_USEDEP}]
+	>=dev-python/msgpack-0.4.0[${PYTHON_USEDEP}]
+	>=dev-python/osprofiler-1.4.0[${PYTHON_USEDEP}]
+	memcached? (
+		>=dev-python/python-memcached-1.56[${PYTHON_USEDEP}]
+	)
+	mongo? (
+		>=dev-python/pymongo-3.0.2[${PYTHON_USEDEP}]
+		!~dev-python/pymongo-3.1[${PYTHON_USEDEP}]
+	)
+	ldap? (
+		>=dev-python/pyldap-2.4.20[${PYTHON_USEDEP}]
+		>=dev-python/ldappool-2.0.0[${PYTHON_USEDEP}]
+	)
+	|| (
+		www-servers/uwsgi[python,${PYTHON_USEDEP}]
+		www-apache/mod_wsgi[${PYTHON_USEDEP}]
+		www-servers/gunicorn[${PYTHON_USEDEP}]
+	)"
+
+PATCHES=(
+)
+
+pkg_setup() {
+	enewgroup keystone
+	enewuser keystone -1 -1 /var/lib/keystone keystone
+}
+
+python_prepare_all() {
+	# it's in git, but not in the tarball.....
+	sed -i '/^hacking/d' test-requirements.txt || die
+	mkdir -p ${PN}/tests/tmp/ || die
+	cp etc/keystone-paste.ini ${PN}/tests/tmp/ || die
+	sed -i 's|/usr/local|/usr|g' httpd/keystone-uwsgi-* || die
+	sed -i 's|python|python27|g' httpd/keystone-uwsgi-* || die
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	nosetests -I 'test_keystoneclient*' \
+		-e test_static_translated_string_is_Message \
+		-e test_get_token_id_error_handling \
+		-e test_provider_token_expiration_validation \
+		-e test_import --process-restartworker --process-timeout=60 || die "testsuite failed under python2.7"
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	diropts -m 0750
+	keepdir /etc/keystone /var/log/keystone
+	insinto /etc/keystone
+	insopts -m0640 -okeystone -gkeystone
+	doins etc/keystone.conf.sample etc/logging.conf.sample
+	doins etc/default_catalog.templates etc/policy.json
+	doins etc/policy.v3cloudsample.json etc/keystone-paste.ini
+	insinto /etc/keystone/httpd
+	doins httpd/*
+
+	fowners keystone:keystone /etc/keystone /etc/keystone/httpd /var/log/keystone
+}
+
+pkg_postinst() {
+	elog "You might want to run:"
+	elog "emerge --config =${CATEGORY}/${PF}"
+	elog "if this is a new install."
+	elog "If you have not already configured your openssl installation"
+	elog "please do it by modifying /etc/ssl/openssl.cnf"
+	elog "BEFORE issuing the configuration command."
+	elog "Otherwise default values will be used."
+}
+
+pkg_config() {
+	if [ ! -d "${ROOT}"/etc/keystone/ssl ] ; then
+		einfo "Press ENTER to configure the keystone PKI, or Control-C to abort now..."
+		read
+		"${ROOT}"/usr/bin/keystone-manage pki_setup --keystone-user keystone --keystone-group keystone
+	else
+		einfo "keystone PKI certificates directory already present, skipping configuration"
+	fi
+}