[gentoo-commits] repo/gentoo:master commit in: x11-plugins/wmdrawer/

["Bernard Cafarelli" <voyageur@gentoo.org>]

commit:     54dad47e478953c0eb8d892682aa39cf7039f500
Author:     Bernard Cafarelli <voyageur <AT> gentoo <DOT> org>
AuthorDate: Mon May 29 12:18:00 2017 +0000
Commit:     Bernard Cafarelli <voyageur <AT> gentoo <DOT> org>
CommitDate: Mon May 29 12:19:12 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=54dad47e

x11-plugins/wmdrawer: decompress manpage, bug #619980

Also update EAPI

Package-Manager: Portage-2.3.6, Repoman-2.3.2

 x11-plugins/wmdrawer/wmdrawer-0.10.5-r3.ebuild | 46 ++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)

diff --git a/x11-plugins/wmdrawer/wmdrawer-0.10.5-r3.ebuild b/x11-plugins/wmdrawer/wmdrawer-0.10.5-r3.ebuild
new file mode 100644
index 00000000000..b27b454cb21
--- /dev/null
+++ b/x11-plugins/wmdrawer/wmdrawer-0.10.5-r3.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit eutils
+
+DESCRIPTION="dockapp which provides a drawer (retractable button bar) to launch applications"
+HOMEPAGE="http://people.easter-eggs.org/~valos/wmdrawer/"
+SRC_URI="http://people.easter-eggs.org/~valos/wmdrawer/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86"
+IUSE=""
+
+RDEPEND="x11-libs/gtk+:2"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+DOCS=( README TODO AUTHORS ChangeLog wmdrawerrc.example )
+PATCHES=( "${FILESDIR}"/${P}-gtk+-2.patch )
+
+src_prepare() {
+	default
+
+	gunzip doc/wmdrawer.1x.gz || die
+
+	# Honour Gentoo CFLAGS
+	sed -i -e "s|-O3|${CFLAGS}|" Makefile || die
+	# Fix LDFLAGS ordering per bug #248640
+	sed -i -e 's/$(CC) $(LDFLAGS) -o $@ $(OBJS)/$(CC) -o $@ $(OBJS) $(LDFLAGS)/' Makefile || die
+	# Do not auto-strip binaries
+	sed -i -e 's/	strip $@//' Makefile || die
+	# Honour Gentoo LDFLAGS
+	sed -i -e 's/$(CC) -o/$(CC) $(REAL_LDFLAGS) -o/' Makefile || die
+}
+
+src_compile() {
+	emake REAL_LDFLAGS="${LDFLAGS}"
+}
+
+src_install() {
+	dobin wmdrawer
+	doman doc/wmdrawer.1x
+	einstalldocs
+}