[gentoo-commits] repo/gentoo:master commit in: media-radio/ibp/

["Thomas Beierlein" <tomjbe@gentoo.org>]

commit:     d328151585efccf332d7c5a192f0100179f8278e
Author:     Thomas Beierlein <tomjbe <AT> gentoo <DOT> org>
AuthorDate: Wed May 24 06:16:49 2017 +0000
Commit:     Thomas Beierlein <tomjbe <AT> gentoo <DOT> org>
CommitDate: Wed May 24 06:16:49 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d3281515

media-radio/ibp: Fix tinfo problem

Package-Manager: Portage-2.3.6, Repoman-2.3.2

 media-radio/ibp/ibp-0.21-r1.ebuild | 52 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)

diff --git a/media-radio/ibp/ibp-0.21-r1.ebuild b/media-radio/ibp/ibp-0.21-r1.ebuild
new file mode 100644
index 00000000000..3cdb7e826de
--- /dev/null
+++ b/media-radio/ibp/ibp-0.21-r1.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+inherit toolchain-funcs
+
+DESCRIPTION="Shows currently transmitting beacons of the International Beacon Project (IBP)"
+HOMEPAGE="http://wwwhome.cs.utwente.nl/~ptdeboer/ham/${PN}.html"
+SRC_URI="http://wwwhome.cs.utwente.nl/~ptdeboer/ham/${P}.tgz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="X"
+
+RDEPEND="sys-libs/ncurses:0
+	X? ( x11-libs/libX11  )"
+DEPEND="${RDEPEND}
+	X? ( x11-misc/imake )"
+
+src_prepare() {
+	# respect CFLAGS if built without USE=X
+	sed -i -e "s/= -D/+= -D/" Makefile || die
+	# fix compile if ncurses is built with separate libtinfo
+	if has_version "sys-libs/ncurses:0[tinfo]" ;then
+		sed -i -e "s/-lcurses/-lcurses -ltinfo/" Imakefile Makefile || die
+	fi
+
+	eapply_user
+}
+
+src_configure() {
+	if use X ;then
+		xmkmf || die
+	fi
+}
+
+src_compile() {
+	if use X ; then
+		emake \
+			CC="$(tc-getCC)" \
+			LOCAL_LDFLAGS="${LDFLAGS}" \
+			CDEBUGFLAGS="${CFLAGS}"
+	else
+		emake CC="$(tc-getCC)"
+	fi
+}
+
+src_install() {
+	dobin ${PN}
+	doman ${PN}.1
+}