[gentoo-commits] repo/gentoo:master commit in: games-fps/xonotic/

public inbox for gentoo-commits@lists.gentoo.org
 help / color / mirror / Atom feed

* [gentoo-commits] repo/gentoo:master commit in: games-fps/xonotic/
@ 2015-10-08  8:36 Michael Sterrett
  0 siblings, 0 replies; 18+ messages in thread
From: Michael Sterrett @ 2015-10-08  8:36 UTC (permalink / raw
  To: gentoo-commits

commit:     4ba854d68216a898711645a9782584dbb6fb8090
Author:     Michael Sterrett <mr_bones_ <AT> gentoo <DOT> org>
AuthorDate: Thu Oct  8 08:36:27 2015 +0000
Commit:     Michael Sterrett <mr_bones_ <AT> gentoo <DOT> org>
CommitDate: Thu Oct  8 08:36:45 2015 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=4ba854d6

version bump

Package-Manager: portage-2.2.20.1

 games-fps/xonotic/Manifest             |   1 +
 games-fps/xonotic/xonotic-0.8.1.ebuild | 117 +++++++++++++++++++++++++++++++++
 2 files changed, 118 insertions(+)

diff --git a/games-fps/xonotic/Manifest b/games-fps/xonotic/Manifest
index 6a57f89..5dcf3af 100644
--- a/games-fps/xonotic/Manifest
+++ b/games-fps/xonotic/Manifest
@@ -1 +1,2 @@
 DIST xonotic-0.8.0.zip 999151784 SHA256 0a87c808827a8b234f2324b468ecb643aa48a6fd43322a29e616610dca316370 SHA512 49ae728f9269ff642540ec8a7ab52fb9624f3d05cab2b07c5a1aa87d4103d3acffad4e2a1f266d3976cd457e742a3a7a1fd4a774cbcde934b123ae3baa747332 WHIRLPOOL 85e747bb2fb5ad5394896a08055028439a2f1a154305d7101be8cb5a44a1e50bdb9b36fac526ff12c9db93915a8b5253a40cf7dc654271f20240e1f92e0b4cb5
+DIST xonotic-0.8.1.zip 984854761 SHA256 be8bcc41e2993a2f26d4d04c65a7eab810443bd98b11b45e482ffdbbf284c46f SHA512 adfce546257bdc7cfebe94f53eaa9cc9b19eaa546c6405e31ed6af080e3948732c960a024126202e5853cb98b955daadeeb5a96c602a6d4d83e284d3540214a4 WHIRLPOOL 4359263c98352a8b5d169147d9bfecb4258628f212d9a965f0d1577d0a8b2469648ae1ce21d8dc0ff622d20e126ea52e1464363f69fcf514991aefad71c1bee7

diff --git a/games-fps/xonotic/xonotic-0.8.1.ebuild b/games-fps/xonotic/xonotic-0.8.1.ebuild
new file mode 100644
index 0000000..cea7356
--- /dev/null
+++ b/games-fps/xonotic/xonotic-0.8.1.ebuild
@@ -0,0 +1,117 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+inherit eutils check-reqs toolchain-funcs games
+
+MY_PN="${PN^}"
+DESCRIPTION="Fork of Nexuiz, Deathmatch FPS based on DarkPlaces, an advanced Quake 1 engine"
+HOMEPAGE="http://www.xonotic.org/"
+SRC_URI="http://dl.xonotic.org/${P}.zip"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="alsa debug dedicated doc ode sdl"
+
+UIRDEPEND="
+	media-libs/libogg
+	media-libs/libtheora
+	media-libs/libvorbis
+	media-libs/libmodplug
+	x11-libs/libX11
+	x11-libs/libXau
+	x11-libs/libXpm
+	x11-libs/libXext
+	x11-libs/libXdmcp
+	x11-libs/libXxf86dga
+	x11-libs/libXxf86vm
+	virtual/opengl
+	media-libs/freetype:2
+	alsa? ( media-libs/alsa-lib )
+	ode? ( dev-games/ode[double-precision] )
+	sdl? ( media-libs/libsdl[X,sound,joystick,opengl,video,alsa?] )"
+UIDEPEND="
+	x11-proto/xextproto
+	x11-proto/xf86dgaproto
+	x11-proto/xf86vidmodeproto
+	x11-proto/xproto"
+RDEPEND="
+	sys-libs/zlib
+	virtual/jpeg:62
+	media-libs/libpng:0
+	net-misc/curl
+	~dev-libs/d0_blind_id-0.5
+	!dedicated? ( ${UIRDEPEND} )"
+DEPEND="${RDEPEND}
+	!dedicated? ( ${UIDEPEND} )"
+
+CHECKREQS_DISK_BUILD="1200M"
+CHECKREQS_DISK_USR="950M"
+
+S=${WORKDIR}/${MY_PN}
+
+pkg_pretend() {
+	check-reqs_pkg_pretend
+}
+
+pkg_setup() {
+	check-reqs_pkg_setup
+	games_pkg_setup
+}
+
+src_prepare() {
+	sed -i \
+		-e "/^EXE_/s:darkplaces:${PN}:" \
+		-e "s:-O3:${CFLAGS}:" \
+		-e "/-lm/s:$: ${LDFLAGS}:" \
+		-e '/^STRIP/s/strip/true/' \
+		source/darkplaces/makefile.inc || die
+
+	if ! use alsa; then
+		sed -i \
+			-e "/DEFAULT_SNDAPI/s:ALSA:OSS:" \
+			source/darkplaces/makefile || die
+	fi
+}
+
+src_compile() {
+	local t="$(use debug && echo debug || echo release)"
+	local i
+
+	tc-export CC CXX LD AR RANLIB
+
+	# use a for-loop wrt bug 473352
+	for i in sv-${t} $(use !dedicated && echo "cl-${t} $(use sdl && echo sdl-${t})") ; do
+		emake \
+			-C source/darkplaces \
+			DP_LINK_ODE=$(usex ode shared no) \
+			DP_FS_BASEDIR="${GAMES_DATADIR}/${PN}" \
+			${i}
+	done
+}
+
+src_install() {
+	if ! use dedicated; then
+		dogamesbin source/darkplaces/${PN}-glx
+		newicon misc/logos/${PN}_icon.svg ${PN}.svg
+		make_desktop_entry ${PN}-glx "${MY_PN} (GLX)"
+
+		if use sdl; then
+			dogamesbin source/darkplaces/${PN}-sdl
+			make_desktop_entry ${PN}-sdl "${MY_PN} (SDL)"
+		fi
+	fi
+	dogamesbin source/darkplaces/${PN}-dedicated
+
+	dodoc Docs/*.txt
+	use doc && dohtml -r Docs
+
+	insinto "${GAMES_DATADIR}/${PN}"
+	doins -r key_0.d0pk server data
+	prepgamesdirs
+
+	elog "If you are using opensource drivers you should consider installing: "
+	elog "    media-libs/libtxc_dxtn"
+}


^ permalink raw reply related	[flat|nested] 18+ messages in thread

* [gentoo-commits] repo/gentoo:master commit in: games-fps/xonotic/
@ 2015-12-02 14:29 Agostino Sarubbo
  0 siblings, 0 replies; 18+ messages in thread
From: Agostino Sarubbo @ 2015-12-02 14:29 UTC (permalink / raw
  To: gentoo-commits

commit:     096f952828a4e19f62323a04b2127909d4cb0db5
Author:     Agostino Sarubbo <ago <AT> gentoo <DOT> org>
AuthorDate: Wed Dec  2 14:29:46 2015 +0000
Commit:     Agostino Sarubbo <ago <AT> gentoo <DOT> org>
CommitDate: Wed Dec  2 14:29:46 2015 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=096f9528

games-fps/xonotic: amd64 stable wrt bug #567278

Package-Manager: portage-2.2.20.1
RepoMan-Options: --include-arches="amd64"

 games-fps/xonotic/xonotic-0.8.1.ebuild | 2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)

diff --git a/games-fps/xonotic/xonotic-0.8.1.ebuild b/games-fps/xonotic/xonotic-0.8.1.ebuild
index 1cf837c..fdd8c3b 100644
--- a/games-fps/xonotic/xonotic-0.8.1.ebuild
+++ b/games-fps/xonotic/xonotic-0.8.1.ebuild
@@ -13,7 +13,7 @@ SRC_URI="http://dl.xonotic.org/${P}.zip"
 
 LICENSE="GPL-2"
 SLOT="0"
-KEYWORDS="~amd64 ~x86"
+KEYWORDS="amd64 ~x86"
 IUSE="alsa debug dedicated doc ode sdl"
 
 UIRDEPEND="


^ permalink raw reply related	[flat|nested] 18+ messages in thread

* [gentoo-commits] repo/gentoo:master commit in: games-fps/xonotic/
@ 2015-12-03 13:28 Agostino Sarubbo
  0 siblings, 0 replies; 18+ messages in thread
From: Agostino Sarubbo @ 2015-12-03 13:28 UTC (permalink / raw
  To: gentoo-commits

commit:     b673af95b549a624a4b8d3764e45dd5831a9cd38
Author:     Agostino Sarubbo <ago <AT> gentoo <DOT> org>
AuthorDate: Thu Dec  3 13:26:03 2015 +0000
Commit:     Agostino Sarubbo <ago <AT> gentoo <DOT> org>
CommitDate: Thu Dec  3 13:26:03 2015 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b673af95

games-fps/xonotic: x86 stable wrt bug #567278

Package-Manager: portage-2.2.20.1
RepoMan-Options: --include-arches="x86"
Signed-off-by: Agostino Sarubbo <ago <AT> gentoo.org>

 games-fps/xonotic/xonotic-0.8.1.ebuild | 2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)

diff --git a/games-fps/xonotic/xonotic-0.8.1.ebuild b/games-fps/xonotic/xonotic-0.8.1.ebuild
index fdd8c3b..31d816d 100644
--- a/games-fps/xonotic/xonotic-0.8.1.ebuild
+++ b/games-fps/xonotic/xonotic-0.8.1.ebuild
@@ -13,7 +13,7 @@ SRC_URI="http://dl.xonotic.org/${P}.zip"
 
 LICENSE="GPL-2"
 SLOT="0"
-KEYWORDS="amd64 ~x86"
+KEYWORDS="amd64 x86"
 IUSE="alsa debug dedicated doc ode sdl"
 
 UIRDEPEND="


^ permalink raw reply related	[flat|nested] 18+ messages in thread

* [gentoo-commits] repo/gentoo:master commit in: games-fps/xonotic/
@ 2015-12-18  0:47 Michael Sterrett
  0 siblings, 0 replies; 18+ messages in thread
From: Michael Sterrett @ 2015-12-18  0:47 UTC (permalink / raw
  To: gentoo-commits

commit:     817fa3898eff9e86c0b3c8984df297ebde78ae0c
Author:     Michael Sterrett <mr_bones_ <AT> gentoo <DOT> org>
AuthorDate: Thu Dec 17 20:09:02 2015 +0000
Commit:     Michael Sterrett <mr_bones_ <AT> gentoo <DOT> org>
CommitDate: Fri Dec 18 00:39:26 2015 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=817fa389

correct slot dep for virtual/jpeg

Package-Manager: portage-2.2.24

 games-fps/xonotic/xonotic-0.8.1.ebuild | 2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)

diff --git a/games-fps/xonotic/xonotic-0.8.1.ebuild b/games-fps/xonotic/xonotic-0.8.1.ebuild
index 31d816d..b862886 100644
--- a/games-fps/xonotic/xonotic-0.8.1.ebuild
+++ b/games-fps/xonotic/xonotic-0.8.1.ebuild
@@ -40,7 +40,7 @@ UIDEPEND="
 	x11-proto/xproto"
 RDEPEND="
 	sys-libs/zlib
-	virtual/jpeg:62
+	virtual/jpeg:0
 	media-libs/libpng:0
 	net-misc/curl
 	~dev-libs/d0_blind_id-0.5


^ permalink raw reply related	[flat|nested] 18+ messages in thread

* [gentoo-commits] repo/gentoo:master commit in: games-fps/xonotic/
@ 2015-12-18  0:47 Michael Sterrett
  0 siblings, 0 replies; 18+ messages in thread
From: Michael Sterrett @ 2015-12-18  0:47 UTC (permalink / raw
  To: gentoo-commits

commit:     430ae049c98b52999c2263c249a29caab3af193c
Author:     Michael Sterrett <mr_bones_ <AT> gentoo <DOT> org>
AuthorDate: Thu Dec 17 20:09:26 2015 +0000
Commit:     Michael Sterrett <mr_bones_ <AT> gentoo <DOT> org>
CommitDate: Fri Dec 18 00:39:26 2015 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=430ae049

clean old

Package-Manager: portage-2.2.24

 games-fps/xonotic/Manifest             |   1 -
 games-fps/xonotic/xonotic-0.8.0.ebuild | 116 ---------------------------------
 2 files changed, 117 deletions(-)

diff --git a/games-fps/xonotic/Manifest b/games-fps/xonotic/Manifest
index 5dcf3af..79b609a 100644
--- a/games-fps/xonotic/Manifest
+++ b/games-fps/xonotic/Manifest
@@ -1,2 +1 @@
-DIST xonotic-0.8.0.zip 999151784 SHA256 0a87c808827a8b234f2324b468ecb643aa48a6fd43322a29e616610dca316370 SHA512 49ae728f9269ff642540ec8a7ab52fb9624f3d05cab2b07c5a1aa87d4103d3acffad4e2a1f266d3976cd457e742a3a7a1fd4a774cbcde934b123ae3baa747332 WHIRLPOOL 85e747bb2fb5ad5394896a08055028439a2f1a154305d7101be8cb5a44a1e50bdb9b36fac526ff12c9db93915a8b5253a40cf7dc654271f20240e1f92e0b4cb5
 DIST xonotic-0.8.1.zip 984854761 SHA256 be8bcc41e2993a2f26d4d04c65a7eab810443bd98b11b45e482ffdbbf284c46f SHA512 adfce546257bdc7cfebe94f53eaa9cc9b19eaa546c6405e31ed6af080e3948732c960a024126202e5853cb98b955daadeeb5a96c602a6d4d83e284d3540214a4 WHIRLPOOL 4359263c98352a8b5d169147d9bfecb4258628f212d9a965f0d1577d0a8b2469648ae1ce21d8dc0ff622d20e126ea52e1464363f69fcf514991aefad71c1bee7

diff --git a/games-fps/xonotic/xonotic-0.8.0.ebuild b/games-fps/xonotic/xonotic-0.8.0.ebuild
deleted file mode 100644
index 4fa4fed..0000000
--- a/games-fps/xonotic/xonotic-0.8.0.ebuild
+++ /dev/null
@@ -1,116 +0,0 @@
-# Copyright 1999-2015 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Id$
-
-EAPI=5
-inherit eutils check-reqs games
-
-# Switch to ^ when we switch to EAPI=6.
-MY_PN="X${PN:1}"
-DESCRIPTION="Fork of Nexuiz, Deathmatch FPS based on DarkPlaces, an advanced Quake 1 engine"
-HOMEPAGE="http://www.xonotic.org/"
-SRC_URI="http://dl.xonotic.org/${P}.zip"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="amd64 x86"
-IUSE="alsa debug dedicated doc ode sdl"
-
-UIRDEPEND="
-	media-libs/libogg
-	media-libs/libtheora
-	media-libs/libvorbis
-	media-libs/libmodplug
-	x11-libs/libX11
-	x11-libs/libXau
-	x11-libs/libXpm
-	x11-libs/libXext
-	x11-libs/libXdmcp
-	x11-libs/libXxf86dga
-	x11-libs/libXxf86vm
-	virtual/opengl
-	media-libs/freetype:2
-	alsa? ( media-libs/alsa-lib )
-	ode? ( dev-games/ode[double-precision] )
-	sdl? ( media-libs/libsdl[X,sound,joystick,opengl,video,alsa?] )"
-UIDEPEND="
-	x11-proto/xextproto
-	x11-proto/xf86dgaproto
-	x11-proto/xf86vidmodeproto
-	x11-proto/xproto"
-RDEPEND="
-	sys-libs/zlib
-	virtual/jpeg
-	media-libs/libpng
-	net-misc/curl
-	~dev-libs/d0_blind_id-0.5
-	!dedicated? ( ${UIRDEPEND} )"
-DEPEND="${RDEPEND}
-	!dedicated? ( ${UIDEPEND} )"
-
-CHECKREQS_DISK_BUILD="1200M"
-CHECKREQS_DISK_USR="950M"
-
-S=${WORKDIR}/${MY_PN}
-
-pkg_pretend() {
-	check-reqs_pkg_pretend
-}
-
-pkg_setup() {
-	check-reqs_pkg_setup
-	games_pkg_setup
-}
-
-src_prepare() {
-	sed -i \
-		-e "/^EXE_/s:darkplaces:${PN}:" \
-		-e "s:-O3:${CFLAGS}:" \
-		-e "/-lm/s:$: ${LDFLAGS}:" \
-		-e '/^STRIP/s/strip/true/' \
-		source/darkplaces/makefile.inc || die
-
-	if ! use alsa; then
-		sed -i \
-			-e "/DEFAULT_SNDAPI/s:ALSA:OSS:" \
-			source/darkplaces/makefile || die
-	fi
-}
-
-src_compile() {
-	local t="$(use debug && echo debug || echo release)"
-	local i
-
-	# use a for-loop wrt bug 473352
-	for i in sv-${t} $(use !dedicated && echo "cl-${t} $(use sdl && echo sdl-${t})") ; do
-		emake \
-			-C source/darkplaces \
-			DP_LINK_TO_LIBJPEG=1 \
-			DP_FS_BASEDIR="${GAMES_DATADIR}/${PN}" \
-			${i}
-	done
-}
-
-src_install() {
-	if ! use dedicated; then
-		dogamesbin source/darkplaces/${PN}-glx
-		newicon misc/logos/${PN}_icon.svg ${PN}.svg
-		make_desktop_entry ${PN}-glx "${MY_PN} (GLX)"
-
-		if use sdl; then
-			dogamesbin source/darkplaces/${PN}-sdl
-			make_desktop_entry ${PN}-sdl "${MY_PN} (SDL)"
-		fi
-	fi
-	dogamesbin source/darkplaces/${PN}-dedicated
-
-	dodoc Docs/*.txt
-	use doc && dohtml -r Docs
-
-	insinto "${GAMES_DATADIR}/${PN}"
-	doins -r key_0.d0pk server data
-	prepgamesdirs
-
-	elog "If you are using opensource drivers you should consider installing: "
-	elog "    media-libs/libtxc_dxtn"
-}


^ permalink raw reply related	[flat|nested] 18+ messages in thread

* [gentoo-commits] repo/gentoo:master commit in: games-fps/xonotic/
@ 2017-05-18  9:01 Lars Wendler
  0 siblings, 0 replies; 18+ messages in thread
From: Lars Wendler @ 2017-05-18  9:01 UTC (permalink / raw
  To: gentoo-commits

commit:     7f87b19d87d4769a1dfb7392868e3f0c0732ae06
Author:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
AuthorDate: Thu May 18 09:00:32 2017 +0000
Commit:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
CommitDate: Thu May 18 09:01:01 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=7f87b19d

games-fps/xonotic: Bump to version 0.8.2

Package-Manager: Portage-2.3.5, Repoman-2.3.2

 games-fps/xonotic/Manifest             |   1 +
 games-fps/xonotic/xonotic-0.8.2.ebuild | 119 +++++++++++++++++++++++++++++++++
 2 files changed, 120 insertions(+)

diff --git a/games-fps/xonotic/Manifest b/games-fps/xonotic/Manifest
index 79b609af77e..a18db6cb7b8 100644
--- a/games-fps/xonotic/Manifest
+++ b/games-fps/xonotic/Manifest
@@ -1 +1,2 @@
 DIST xonotic-0.8.1.zip 984854761 SHA256 be8bcc41e2993a2f26d4d04c65a7eab810443bd98b11b45e482ffdbbf284c46f SHA512 adfce546257bdc7cfebe94f53eaa9cc9b19eaa546c6405e31ed6af080e3948732c960a024126202e5853cb98b955daadeeb5a96c602a6d4d83e284d3540214a4 WHIRLPOOL 4359263c98352a8b5d169147d9bfecb4258628f212d9a965f0d1577d0a8b2469648ae1ce21d8dc0ff622d20e126ea52e1464363f69fcf514991aefad71c1bee7
+DIST xonotic-0.8.2.zip 991045679 SHA256 a22f7230f486c5825b55cfdadd73399c9b0fae98c9e081dd8ac76eca08359ad5 SHA512 0787fcf326827ae0292e5917c7ff2c7fd79947209d4b62e7f83b8b828bec15b575da304e0631f9f163c9b0bd93bed13616e142398ff08cbdaaea890a939dfca5 WHIRLPOOL aff99ae1e995265c832747923afb5ee1048719d4410cc6b55ec773e51dc0920acffe627541209b5450f572e78ef7c74c8822ae2f6ebec2a8888f80dbfd34afba

diff --git a/games-fps/xonotic/xonotic-0.8.2.ebuild b/games-fps/xonotic/xonotic-0.8.2.ebuild
new file mode 100644
index 00000000000..cd06a49ba1c
--- /dev/null
+++ b/games-fps/xonotic/xonotic-0.8.2.ebuild
@@ -0,0 +1,119 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit eutils check-reqs toolchain-funcs
+
+# Switch to ^ when we switch to EAPI=6.
+MY_PN="X${PN:1}"
+DESCRIPTION="Fork of Nexuiz, Deathmatch FPS based on DarkPlaces, an advanced Quake 1 engine"
+HOMEPAGE="http://www.xonotic.org/"
+SRC_URI="http://dl.xonotic.org/${P}.zip"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="alsa debug dedicated doc ode sdl"
+
+UIRDEPEND="
+	media-libs/libogg
+	media-libs/libtheora
+	media-libs/libvorbis
+	media-libs/libmodplug
+	x11-libs/libX11
+	x11-libs/libXau
+	x11-libs/libXpm
+	x11-libs/libXext
+	x11-libs/libXdmcp
+	x11-libs/libXxf86dga
+	x11-libs/libXxf86vm
+	virtual/opengl
+	media-libs/freetype:2
+	alsa? ( media-libs/alsa-lib )
+	ode? ( dev-games/ode[double-precision] )
+	sdl? ( media-libs/libsdl[X,sound,joystick,opengl,video,alsa?] )"
+UIDEPEND="
+	x11-proto/xextproto
+	x11-proto/xf86dgaproto
+	x11-proto/xf86vidmodeproto
+	x11-proto/xproto"
+RDEPEND="
+	sys-libs/zlib
+	virtual/jpeg:0
+	media-libs/libpng:0
+	net-misc/curl
+	~dev-libs/d0_blind_id-1.0
+	!dedicated? ( ${UIRDEPEND} )"
+DEPEND="${RDEPEND}
+	!dedicated? ( ${UIDEPEND} )"
+
+CHECKREQS_DISK_BUILD="1200M"
+CHECKREQS_DISK_USR="950M"
+
+S="${WORKDIR}/${MY_PN}"
+
+pkg_pretend() {
+	check-reqs_pkg_pretend
+}
+
+pkg_setup() {
+	check-reqs_pkg_setup
+}
+
+src_prepare() {
+	default
+
+	sed -i \
+		-e "/^EXE_/s:darkplaces:${PN}:" \
+		-e "s:-O3:${CFLAGS}:" \
+		-e "/-lm/s:$: ${LDFLAGS}:" \
+		-e '/^STRIP/s/strip/true/' \
+		source/darkplaces/makefile.inc || die
+
+	if ! use alsa; then
+		sed -i \
+			-e "/DEFAULT_SNDAPI/s:ALSA:OSS:" \
+			source/darkplaces/makefile || die
+	fi
+}
+
+src_compile() {
+	local t="$(usex debug debug release)"
+	local i
+
+	tc-export CC CXX LD AR RANLIB
+
+	# use a for-loop wrt bug 473352
+	for i in sv-${t} $(usex !dedicated "cl-${t} $(usex sdl "sdl-${t}" "")" "") ; do
+		emake \
+			-C source/darkplaces \
+			DP_LINK_ODE=$(usex ode shared no) \
+			DP_FS_BASEDIR="/usr/${PN}" \
+			${i}
+	done
+}
+
+src_install() {
+	if ! use dedicated; then
+		dobin source/darkplaces/${PN}-glx
+		newicon misc/logos/${PN}_icon.svg ${PN}.svg
+		make_desktop_entry ${PN}-glx "${MY_PN} (GLX)"
+
+		if use sdl; then
+			dobin source/darkplaces/${PN}-sdl
+			make_desktop_entry ${PN}-sdl "${MY_PN} (SDL)"
+		fi
+	fi
+	dobin source/darkplaces/${PN}-dedicated
+
+	dodoc Docs/*.txt
+	use doc && dohtml -r Docs
+
+	insinto "/usr/${PN}"
+	doins -r key_0.d0pk server data
+}
+
+pkg_postinst() {
+	elog "If you are using opensource drivers you should consider installing: "
+	elog "    media-libs/libtxc_dxtn"
+}


^ permalink raw reply related	[flat|nested] 18+ messages in thread

* [gentoo-commits] repo/gentoo:master commit in: games-fps/xonotic/
@ 2017-05-18  9:02 Lars Wendler
  0 siblings, 0 replies; 18+ messages in thread
From: Lars Wendler @ 2017-05-18  9:02 UTC (permalink / raw
  To: gentoo-commits

commit:     07a326b92574bc35a4c1b859391bf04e097d19a5
Author:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
AuthorDate: Thu May 18 09:02:33 2017 +0000
Commit:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
CommitDate: Thu May 18 09:02:33 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=07a326b9

games-fps/xonotic: Fixed game basedir.

Package-Manager: Portage-2.3.5, Repoman-2.3.2

 games-fps/xonotic/xonotic-0.8.2.ebuild | 4 ++--
 1 file changed, 2 insertions(+), 2 deletions(-)

diff --git a/games-fps/xonotic/xonotic-0.8.2.ebuild b/games-fps/xonotic/xonotic-0.8.2.ebuild
index cd06a49ba1c..719fd3d2954 100644
--- a/games-fps/xonotic/xonotic-0.8.2.ebuild
+++ b/games-fps/xonotic/xonotic-0.8.2.ebuild
@@ -88,7 +88,7 @@ src_compile() {
 		emake \
 			-C source/darkplaces \
 			DP_LINK_ODE=$(usex ode shared no) \
-			DP_FS_BASEDIR="/usr/${PN}" \
+			DP_FS_BASEDIR="/usr/share/${PN}" \
 			${i}
 	done
 }
@@ -109,7 +109,7 @@ src_install() {
 	dodoc Docs/*.txt
 	use doc && dohtml -r Docs
 
-	insinto "/usr/${PN}"
+	insinto "/usr/share/${PN}"
 	doins -r key_0.d0pk server data
 }
 


^ permalink raw reply related	[flat|nested] 18+ messages in thread

* [gentoo-commits] repo/gentoo:master commit in: games-fps/xonotic/
@ 2017-05-19  6:49 Lars Wendler
  0 siblings, 0 replies; 18+ messages in thread
From: Lars Wendler @ 2017-05-19  6:49 UTC (permalink / raw
  To: gentoo-commits

commit:     5aeff14ae845860fecd310221eb78928302e00e6
Author:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
AuthorDate: Fri May 19 06:49:19 2017 +0000
Commit:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
CommitDate: Fri May 19 06:49:32 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=5aeff14a

games-fps/xonotic: Version 0.8.2 depends on SDL2 (bug #618842).

Package-Manager: Portage-2.3.5, Repoman-2.3.2

 games-fps/xonotic/xonotic-0.8.2.ebuild | 2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)

diff --git a/games-fps/xonotic/xonotic-0.8.2.ebuild b/games-fps/xonotic/xonotic-0.8.2.ebuild
index 719fd3d2954..aa2df9e9f86 100644
--- a/games-fps/xonotic/xonotic-0.8.2.ebuild
+++ b/games-fps/xonotic/xonotic-0.8.2.ebuild
@@ -31,7 +31,7 @@ UIRDEPEND="
 	media-libs/freetype:2
 	alsa? ( media-libs/alsa-lib )
 	ode? ( dev-games/ode[double-precision] )
-	sdl? ( media-libs/libsdl[X,sound,joystick,opengl,video,alsa?] )"
+	sdl? ( media-libs/libsdl2[X,sound,joystick,opengl,video,alsa?] )"
 UIDEPEND="
 	x11-proto/xextproto
 	x11-proto/xf86dgaproto


^ permalink raw reply related	[flat|nested] 18+ messages in thread

* [gentoo-commits] repo/gentoo:master commit in: games-fps/xonotic/
@ 2017-05-31  7:51 Lars Wendler
  0 siblings, 0 replies; 18+ messages in thread
From: Lars Wendler @ 2017-05-31  7:51 UTC (permalink / raw
  To: gentoo-commits

commit:     e378fe6d682330a0ee4cf83db9b9a372821ae00e
Author:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
AuthorDate: Wed May 31 07:51:25 2017 +0000
Commit:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
CommitDate: Wed May 31 07:51:38 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e378fe6d

games-fps/xonotic: Cosmetic change in ebuild.

Package-Manager: Portage-2.3.6, Repoman-2.3.2

 games-fps/xonotic/xonotic-0.8.2.ebuild | 3 +--
 1 file changed, 1 insertion(+), 2 deletions(-)

diff --git a/games-fps/xonotic/xonotic-0.8.2.ebuild b/games-fps/xonotic/xonotic-0.8.2.ebuild
index aa2df9e9f86..5041c1379a7 100644
--- a/games-fps/xonotic/xonotic-0.8.2.ebuild
+++ b/games-fps/xonotic/xonotic-0.8.2.ebuild
@@ -4,8 +4,7 @@
 EAPI=6
 inherit eutils check-reqs toolchain-funcs
 
-# Switch to ^ when we switch to EAPI=6.
-MY_PN="X${PN:1}"
+MY_PN="${PN^}"
 DESCRIPTION="Fork of Nexuiz, Deathmatch FPS based on DarkPlaces, an advanced Quake 1 engine"
 HOMEPAGE="http://www.xonotic.org/"
 SRC_URI="http://dl.xonotic.org/${P}.zip"


^ permalink raw reply related	[flat|nested] 18+ messages in thread

* [gentoo-commits] repo/gentoo:master commit in: games-fps/xonotic/
@ 2017-12-10 21:41 Michał Górny
  0 siblings, 0 replies; 18+ messages in thread
From: Michał Górny @ 2017-12-10 21:41 UTC (permalink / raw
  To: gentoo-commits

commit:     626d2dc587ef0ed267ce3bc4d3febfca591274d5
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sun Dec 10 17:00:49 2017 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sun Dec 10 21:41:20 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=626d2dc5

games-fps/xonotic: Update Manifest hashes

 games-fps/xonotic/Manifest | 4 ++--
 1 file changed, 2 insertions(+), 2 deletions(-)

diff --git a/games-fps/xonotic/Manifest b/games-fps/xonotic/Manifest
index a18db6cb7b8..6f7576a7cb1 100644
--- a/games-fps/xonotic/Manifest
+++ b/games-fps/xonotic/Manifest
@@ -1,2 +1,2 @@
-DIST xonotic-0.8.1.zip 984854761 SHA256 be8bcc41e2993a2f26d4d04c65a7eab810443bd98b11b45e482ffdbbf284c46f SHA512 adfce546257bdc7cfebe94f53eaa9cc9b19eaa546c6405e31ed6af080e3948732c960a024126202e5853cb98b955daadeeb5a96c602a6d4d83e284d3540214a4 WHIRLPOOL 4359263c98352a8b5d169147d9bfecb4258628f212d9a965f0d1577d0a8b2469648ae1ce21d8dc0ff622d20e126ea52e1464363f69fcf514991aefad71c1bee7
-DIST xonotic-0.8.2.zip 991045679 SHA256 a22f7230f486c5825b55cfdadd73399c9b0fae98c9e081dd8ac76eca08359ad5 SHA512 0787fcf326827ae0292e5917c7ff2c7fd79947209d4b62e7f83b8b828bec15b575da304e0631f9f163c9b0bd93bed13616e142398ff08cbdaaea890a939dfca5 WHIRLPOOL aff99ae1e995265c832747923afb5ee1048719d4410cc6b55ec773e51dc0920acffe627541209b5450f572e78ef7c74c8822ae2f6ebec2a8888f80dbfd34afba
+DIST xonotic-0.8.1.zip 984854761 BLAKE2B 442e4660903552c65e0dbc552013ae237ab8d0d9278a04e6e1d83f7957e7306ea95f3c0e4c7523823191a4458825ba3813bbd92e43e77448a4b351f0e041edc4 SHA512 adfce546257bdc7cfebe94f53eaa9cc9b19eaa546c6405e31ed6af080e3948732c960a024126202e5853cb98b955daadeeb5a96c602a6d4d83e284d3540214a4
+DIST xonotic-0.8.2.zip 991045679 BLAKE2B 3005473da954492bb7387f9e0e13c2415e638877fa8b83e14872f3b04ed0fc21b82e18f51aa6c68e8bf02d09d4a73f290cbcaebdfa8c0a12ceb6582309baee8a SHA512 0787fcf326827ae0292e5917c7ff2c7fd79947209d4b62e7f83b8b828bec15b575da304e0631f9f163c9b0bd93bed13616e142398ff08cbdaaea890a939dfca5


^ permalink raw reply related	[flat|nested] 18+ messages in thread

* [gentoo-commits] repo/gentoo:master commit in: games-fps/xonotic/
@ 2018-05-06 19:03 Matt Turner
  0 siblings, 0 replies; 18+ messages in thread
From: Matt Turner @ 2018-05-06 19:03 UTC (permalink / raw
  To: gentoo-commits

commit:     63ea7b89afa6c1953fcc7419d863a67c9c47732e
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Sun May  6 18:59:19 2018 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Sun May  6 19:02:45 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=63ea7b89

games-fps/xonotic: Drop mention of media-libs/libtxc_dxtn

Bug: https://bugs.gentoo.org/654468

 games-fps/xonotic/xonotic-0.8.2.ebuild | 5 -----
 1 file changed, 5 deletions(-)

diff --git a/games-fps/xonotic/xonotic-0.8.2.ebuild b/games-fps/xonotic/xonotic-0.8.2.ebuild
index 5041c1379a7..2ad7334b448 100644
--- a/games-fps/xonotic/xonotic-0.8.2.ebuild
+++ b/games-fps/xonotic/xonotic-0.8.2.ebuild
@@ -111,8 +111,3 @@ src_install() {
 	insinto "/usr/share/${PN}"
 	doins -r key_0.d0pk server data
 }
-
-pkg_postinst() {
-	elog "If you are using opensource drivers you should consider installing: "
-	elog "    media-libs/libtxc_dxtn"
-}


^ permalink raw reply related	[flat|nested] 18+ messages in thread

* [gentoo-commits] repo/gentoo:master commit in: games-fps/xonotic/
@ 2020-07-26 20:23 James Le Cuirot
  0 siblings, 0 replies; 18+ messages in thread
From: James Le Cuirot @ 2020-07-26 20:23 UTC (permalink / raw
  To: gentoo-commits

commit:     56f871d0d81ca821c66c2a7172d8386775afcc7c
Author:     Michael Mair-Keimberger <m.mairkeimberger <AT> gmail <DOT> com>
AuthorDate: Fri Jul  3 09:30:23 2020 +0000
Commit:     James Le Cuirot <chewi <AT> gentoo <DOT> org>
CommitDate: Sun Jul 26 20:23:02 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=56f871d0

games-fps/xonotic: EAPI7, fix #710894, use HTTPS, fix LICENSE

Closes: https://bugs.gentoo.org/710894
Package-Manager: Portage-2.3.103, Repoman-2.3.23
Signed-off-by: Michael Mair-Keimberger <m.mairkeimberger <AT> gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/16566
Signed-off-by: James Le Cuirot <chewi <AT> gentoo.org>

 games-fps/xonotic/xonotic-0.8.2.ebuild | 30 +++++++++++++++++-------------
 1 file changed, 17 insertions(+), 13 deletions(-)

diff --git a/games-fps/xonotic/xonotic-0.8.2.ebuild b/games-fps/xonotic/xonotic-0.8.2.ebuild
index 32b2eab5bb4..41f326a1322 100644
--- a/games-fps/xonotic/xonotic-0.8.2.ebuild
+++ b/games-fps/xonotic/xonotic-0.8.2.ebuild
@@ -1,15 +1,16 @@
-# Copyright 1999-2017 Gentoo Foundation
+# Copyright 1999-2020 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=6
-inherit eutils check-reqs toolchain-funcs
+EAPI=7
+
+inherit desktop check-reqs toolchain-funcs
 
 MY_PN="${PN^}"
 DESCRIPTION="Fork of Nexuiz, Deathmatch FPS based on DarkPlaces, an advanced Quake 1 engine"
-HOMEPAGE="http://www.xonotic.org/"
-SRC_URI="http://dl.xonotic.org/${P}.zip"
+HOMEPAGE="https://www.xonotic.org/"
+SRC_URI="https://dl.xonotic.org/${P}.zip"
 
-LICENSE="GPL-2"
+LICENSE="GPL-2+"
 SLOT="0"
 KEYWORDS="~amd64 ~x86"
 IUSE="alsa debug dedicated doc ode sdl"
@@ -42,6 +43,9 @@ RDEPEND="
 	!dedicated? ( ${UIRDEPEND} )"
 DEPEND="${RDEPEND}
 	!dedicated? ( ${UIDEPEND} )"
+BDEPEND="app-arch/unzip"
+
+DOCS="Docs/*.txt"
 
 CHECKREQS_DISK_BUILD="1200M"
 CHECKREQS_DISK_USR="950M"
@@ -60,15 +64,15 @@ src_prepare() {
 	default
 
 	sed -i \
-		-e "/^EXE_/s:darkplaces:${PN}:" \
-		-e "s:-O3:${CFLAGS}:" \
-		-e "/-lm/s:$: ${LDFLAGS}:" \
-		-e '/^STRIP/s/strip/true/' \
+		-e "/^EXE_/s|darkplaces|${PN}|" \
+		-e "s|-O3|${CFLAGS}|" \
+		-e "/-lm/s|$| ${LDFLAGS}|" \
+		-e '/^STRIP/s|strip|true|' \
 		source/darkplaces/makefile.inc || die
 
 	if ! use alsa; then
 		sed -i \
-			-e "/DEFAULT_SNDAPI/s:ALSA:OSS:" \
+			-e "/DEFAULT_SNDAPI/s|ALSA|OSS|" \
 			source/darkplaces/makefile || die
 	fi
 }
@@ -102,8 +106,8 @@ src_install() {
 	fi
 	dobin source/darkplaces/${PN}-dedicated
 
-	dodoc Docs/*.txt
-	use doc && dohtml -r Docs
+	use doc && local HTML_DOCS=( Docs/htmlfiles Docs/faq.html )
+	einstalldocs
 
 	insinto "/usr/share/${PN}"
 	doins -r key_0.d0pk server data


^ permalink raw reply related	[flat|nested] 18+ messages in thread

* [gentoo-commits] repo/gentoo:master commit in: games-fps/xonotic/
@ 2021-12-14  9:04 Sam James
  0 siblings, 0 replies; 18+ messages in thread
From: Sam James @ 2021-12-14  9:04 UTC (permalink / raw
  To: gentoo-commits

commit:     46161dc4faa675e8a4ed94fdf95aa55ac1ec265d
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Tue Dec 14 09:04:30 2021 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Tue Dec 14 09:04:30 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=46161dc4

games-fps/xonotic: Keyword 0.8.2 arm64, #821949

Signed-off-by: Sam James <sam <AT> gentoo.org>

 games-fps/xonotic/xonotic-0.8.2.ebuild | 2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)

diff --git a/games-fps/xonotic/xonotic-0.8.2.ebuild b/games-fps/xonotic/xonotic-0.8.2.ebuild
index 315c91ab3b4e..98e1317eb329 100644
--- a/games-fps/xonotic/xonotic-0.8.2.ebuild
+++ b/games-fps/xonotic/xonotic-0.8.2.ebuild
@@ -12,7 +12,7 @@ SRC_URI="https://dl.xonotic.org/${P}.zip"
 
 LICENSE="GPL-2+"
 SLOT="0"
-KEYWORDS="~amd64 ~x86"
+KEYWORDS="~amd64 ~arm64 ~x86"
 IUSE="alsa debug dedicated doc ode sdl"
 
 UIRDEPEND="


^ permalink raw reply related	[flat|nested] 18+ messages in thread

* [gentoo-commits] repo/gentoo:master commit in: games-fps/xonotic/
@ 2022-07-04 15:56 Ionen Wolkens
  0 siblings, 0 replies; 18+ messages in thread
From: Ionen Wolkens @ 2022-07-04 15:56 UTC (permalink / raw
  To: gentoo-commits

commit:     0879cdd7c0900fd821a40296e7f362ff43079b92
Author:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
AuthorDate: Mon Jul  4 15:38:27 2022 +0000
Commit:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
CommitDate: Mon Jul  4 15:56:02 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=0879cdd7

games-fps/xonotic: add 0.8.5

- add USE=X to make GLX variant optional (can build without X libs)
- enable sdl by default as it should make more sense than GLX nowadays,
  and seems to be preferred upstream wrt xonotic.desktop
- drop USE=dedicated, disable X and sdl to get server-only
- drop USE=debug, all this does I can see is add -g -ggdb to CFLAGS
- drop USE=doc, upstream has deprecated the AFT docs in favor
  of the markdown ones (install unconditionally)
- bump checkreqs
- install more icons and use upstream's .desktop files
- reduce reliance on the sed a bit and pass make args instead
- depend on dev-games/ode even if server-only wrt bug #801220
- bug #830499 and bug #830500 would only trigger when setting up
  a clang toolchain for some reason, but is fixed with current layout

This could likely use more work (darkplaces does all sort of stuff
that could use more attention), but should work as expected albeit
not tested much (hopefully not missing anything).

Closes: https://bugs.gentoo.org/801220
Closes: https://bugs.gentoo.org/830499
Closes: https://bugs.gentoo.org/830500
Signed-off-by: Ionen Wolkens <ionen <AT> gentoo.org>

 games-fps/xonotic/Manifest             |   1 +
 games-fps/xonotic/xonotic-0.8.5.ebuild | 105 +++++++++++++++++++++++++++++++++
 2 files changed, 106 insertions(+)

diff --git a/games-fps/xonotic/Manifest b/games-fps/xonotic/Manifest
index aa9efcbb4121..e854cb4d25f8 100644
--- a/games-fps/xonotic/Manifest
+++ b/games-fps/xonotic/Manifest
@@ -1 +1,2 @@
 DIST xonotic-0.8.2.zip 991045679 BLAKE2B 3005473da954492bb7387f9e0e13c2415e638877fa8b83e14872f3b04ed0fc21b82e18f51aa6c68e8bf02d09d4a73f290cbcaebdfa8c0a12ceb6582309baee8a SHA512 0787fcf326827ae0292e5917c7ff2c7fd79947209d4b62e7f83b8b828bec15b575da304e0631f9f163c9b0bd93bed13616e142398ff08cbdaaea890a939dfca5
+DIST xonotic-0.8.5.zip 1228561792 BLAKE2B 3f1391ff6522c8f6b7b4f717aecd6ffe852142d70e7cffff9cb5a602a69142c59850636cc1450aade5ae39088354170b819f696427ba8829bf7c375029f2430a SHA512 4ffc4b73eeb5f580d178a98419d5b44cbff0c56e356a62baa729b5b7a6c3d43b2b425b123428c9b1bf3f4718eaf61bcf5d62914521cc061c7563a253440c807e

diff --git a/games-fps/xonotic/xonotic-0.8.5.ebuild b/games-fps/xonotic/xonotic-0.8.5.ebuild
new file mode 100644
index 000000000000..de5cb5d5a726
--- /dev/null
+++ b/games-fps/xonotic/xonotic-0.8.5.ebuild
@@ -0,0 +1,105 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit desktop check-reqs toolchain-funcs xdg
+
+DESCRIPTION="Fork of Nexuiz, Deathmatch FPS based on DarkPlaces, an advanced Quake 1 engine"
+HOMEPAGE="https://xonotic.org/"
+SRC_URI="https://dl.xonotic.org/${P}.zip"
+S="${WORKDIR}/${PN^}"
+
+LICENSE="GPL-3+ GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="X +alsa ode +sdl"
+
+# note: many dependencies are used through dlopen()
+COMMON_UIDEPEND="
+	media-libs/libogg
+	media-libs/libtheora
+	media-libs/libvorbis"
+RDEPEND="
+	dev-libs/d0_blind_id
+	media-libs/libjpeg-turbo:=
+	media-libs/libpng
+	media-libs/freetype:2
+	net-misc/curl
+	sys-libs/zlib:=
+	X? (
+		${COMMON_UIDEPEND}
+		media-libs/libglvnd[X]
+		x11-libs/libX11
+		x11-libs/libXext
+		x11-libs/libXpm
+		x11-libs/libXxf86vm
+		alsa? ( media-libs/alsa-lib )
+	)
+	ode? ( dev-games/ode:=[double-precision] )
+	sdl? (
+		${COMMON_UIDEPEND}
+		media-libs/libsdl2[joystick,opengl,sound,video]
+	)"
+DEPEND="
+	${RDEPEND}
+	X? ( x11-base/xorg-proto )"
+BDEPEND="app-arch/unzip"
+
+CHECKREQS_DISK_BUILD="1500M"
+CHECKREQS_DISK_USR="1200M"
+
+src_prepare() {
+	default
+
+	sed -e 's|-O3 ||' \
+		-e '/^LDFLAGS_RELEASE/s/$(OPTIM_RELEASE)/$(GENTOO_LDFLAGS)/' \
+		-i source/darkplaces/makefile.inc || die
+}
+
+src_compile() {
+	tc-export CC
+
+	local emakeargs=(
+		-C source/darkplaces
+		DEFAULT_SNDAPI=$(usex alsa ALSA OSS)
+		DP_FS_BASEDIR="${EPREFIX}"/usr/share/${PN}
+		DP_LINK_ODE=$(usex ode shared no)
+		STRIP=:
+		CPUOPTIMIZATIONS="${CFLAGS}"
+		GENTOO_LDFLAGS="${LDFLAGS}"
+	)
+
+	# split for bug 473352
+	emake "${emakeargs[@]}" sv-release
+	use X && emake "${emakeargs[@]}" cl-release
+	use sdl && emake "${emakeargs[@]}" sdl-release
+}
+
+src_install() {
+	newbin {source/darkplaces/darkplaces,${PN}}-dedicated
+
+	if use X || use sdl; then
+		if use X; then
+			newbin {source/darkplaces/darkplaces,${PN}}-glx
+			domenu misc/logos/${PN}-glx.desktop
+		fi
+		if use sdl; then
+			newbin {source/darkplaces/darkplaces,${PN}}-sdl
+			domenu misc/logos/${PN}.desktop
+		fi
+
+		local size
+		for size in 16 22 24 32 48 128 256 512; do
+			newicon -s ${size} misc/logos/icons_png/${PN}_${size}.png ${PN}.png
+		done
+		newicon -s scalable misc/logos/${PN}_icon.svg ${PN}.svg
+	fi
+
+	dodoc Docs/*.{md,txt}
+
+	insinto /usr/share/${PN}
+	doins -r key_0.d0pk server data
+
+	rm "${ED}"/usr/share/${PN}/server/.gitattributes || die
+}


^ permalink raw reply related	[flat|nested] 18+ messages in thread

* [gentoo-commits] repo/gentoo:master commit in: games-fps/xonotic/
@ 2022-07-04 15:56 Ionen Wolkens
  0 siblings, 0 replies; 18+ messages in thread
From: Ionen Wolkens @ 2022-07-04 15:56 UTC (permalink / raw
  To: gentoo-commits

commit:     80bd8ff22a40f8b3c2529f6987ffdd02fff507e8
Author:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
AuthorDate: Mon Jul  4 15:09:47 2022 +0000
Commit:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
CommitDate: Mon Jul  4 15:56:01 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=80bd8ff2

games-fps/xonotic: add gitlab remote-id and indent

Signed-off-by: Ionen Wolkens <ionen <AT> gentoo.org>

 games-fps/xonotic/metadata.xml | 17 ++++++++++-------
 1 file changed, 10 insertions(+), 7 deletions(-)

diff --git a/games-fps/xonotic/metadata.xml b/games-fps/xonotic/metadata.xml
index 7e135f715fc2..6f0500eb437d 100644
--- a/games-fps/xonotic/metadata.xml
+++ b/games-fps/xonotic/metadata.xml
@@ -1,11 +1,14 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
-<maintainer type="project">
-	<email>games@gentoo.org</email>
-	<name>Gentoo Games Project</name>
-</maintainer>
-<use>
-	<flag name="ode">Enable support for physics engine from <pkg>dev-games/ode</pkg></flag>
-</use>
+	<maintainer type="project">
+		<email>games@gentoo.org</email>
+		<name>Gentoo Games Project</name>
+	</maintainer>
+	<use>
+		<flag name="ode">Enable support for physics engine from <pkg>dev-games/ode</pkg></flag>
+	</use>
+	<upstream>
+		<remote-id type="gitlab">xonotic/xonotic</remote-id>
+	</upstream>
 </pkgmetadata>


^ permalink raw reply related	[flat|nested] 18+ messages in thread

* [gentoo-commits] repo/gentoo:master commit in: games-fps/xonotic/
@ 2023-07-20 12:02 Ionen Wolkens
  0 siblings, 0 replies; 18+ messages in thread
From: Ionen Wolkens @ 2023-07-20 12:02 UTC (permalink / raw
  To: gentoo-commits

commit:     2f96f337e143e8b3f99f7aee3fe7325b81f3d2e0
Author:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
AuthorDate: Thu Jul 20 11:36:36 2023 +0000
Commit:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
CommitDate: Thu Jul 20 11:59:42 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=2f96f337

games-fps/xonotic: export CPUOPTIMIZATIONS rather than pass

Handling of this variable changed a bit, and it (now) passes
-mno-avx to avoid subtle errors in physics. There's currently no
reason to override things it adds (+=) so just export it rather
than do a `append-flags -mno-avx` ourselves for parity.

Signed-off-by: Ionen Wolkens <ionen <AT> gentoo.org>

 games-fps/xonotic/xonotic-0.8.6.ebuild | 4 +++-
 1 file changed, 3 insertions(+), 1 deletion(-)

diff --git a/games-fps/xonotic/xonotic-0.8.6.ebuild b/games-fps/xonotic/xonotic-0.8.6.ebuild
index dba043261a73..9848e246cedb 100644
--- a/games-fps/xonotic/xonotic-0.8.6.ebuild
+++ b/games-fps/xonotic/xonotic-0.8.6.ebuild
@@ -60,13 +60,15 @@ src_prepare() {
 src_compile() {
 	tc-export CC
 
+	# do not pass in array to keep the makefile.inc's += flags
+	local -x CPUOPTIMIZATIONS=${CFLAGS}
+
 	local emakeargs=(
 		-C source/darkplaces
 		DEFAULT_SNDAPI=$(usex alsa ALSA OSS)
 		DP_FS_BASEDIR="${EPREFIX}"/usr/share/${PN}
 		DP_LINK_ODE=$(usex ode shared no)
 		STRIP=:
-		CPUOPTIMIZATIONS="${CFLAGS}"
 		GENTOO_LDFLAGS="${LDFLAGS}"
 	)
 


^ permalink raw reply related	[flat|nested] 18+ messages in thread

* [gentoo-commits] repo/gentoo:master commit in: games-fps/xonotic/
@ 2023-07-20 12:02 Ionen Wolkens
  0 siblings, 0 replies; 18+ messages in thread
From: Ionen Wolkens @ 2023-07-20 12:02 UTC (permalink / raw
  To: gentoo-commits

commit:     17d8226c45d3b6810062329891b3fd08fd946599
Author:     spykyvenator <spykyvenator <AT> protonmail <DOT> com>
AuthorDate: Mon Jul 17 11:51:11 2023 +0000
Commit:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
CommitDate: Thu Jul 20 11:59:42 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=17d8226c

games-fps/xonotic: add 0.8.6

Closes: https://github.com/gentoo/gentoo/pull/31925
Signed-off-by: Ionen Wolkens <ionen <AT> gentoo.org>

 games-fps/xonotic/Manifest             |   1 +
 games-fps/xonotic/xonotic-0.8.6.ebuild | 105 +++++++++++++++++++++++++++++++++
 2 files changed, 106 insertions(+)

diff --git a/games-fps/xonotic/Manifest b/games-fps/xonotic/Manifest
index 1e1cdbcaa3e9..bb6cfce6cfc1 100644
--- a/games-fps/xonotic/Manifest
+++ b/games-fps/xonotic/Manifest
@@ -1 +1,2 @@
 DIST xonotic-0.8.5.zip 1228561792 BLAKE2B 3f1391ff6522c8f6b7b4f717aecd6ffe852142d70e7cffff9cb5a602a69142c59850636cc1450aade5ae39088354170b819f696427ba8829bf7c375029f2430a SHA512 4ffc4b73eeb5f580d178a98419d5b44cbff0c56e356a62baa729b5b7a6c3d43b2b425b123428c9b1bf3f4718eaf61bcf5d62914521cc061c7563a253440c807e
+DIST xonotic-0.8.6.zip 1238439495 BLAKE2B f9a9823a2ef8a1a8790c92fe898599938ff39fe9a32bb1f3595a4b451237f7fca29385feeaf8164216713a2cbe2db4d78cadeee91bb08093dae4a7ad1588e4d4 SHA512 cb39879e96f19abb2877588c2d50c5d3e64dd68153bec3dd1bebedf4d765e506afa419c28381d7005aed664cb1a042571c132b5b319e4308cab67745d996c2a6

diff --git a/games-fps/xonotic/xonotic-0.8.6.ebuild b/games-fps/xonotic/xonotic-0.8.6.ebuild
new file mode 100644
index 000000000000..dba043261a73
--- /dev/null
+++ b/games-fps/xonotic/xonotic-0.8.6.ebuild
@@ -0,0 +1,105 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit desktop check-reqs toolchain-funcs xdg
+
+DESCRIPTION="Fork of Nexuiz, Deathmatch FPS based on DarkPlaces, an advanced Quake 1 engine"
+HOMEPAGE="https://xonotic.org/"
+SRC_URI="https://dl.xonotic.org/${P}.zip"
+S="${WORKDIR}/${PN^}"
+
+LICENSE="GPL-3+ GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="X +alsa ode +sdl"
+
+# note: many dependencies are used through dlopen()
+COMMON_UIDEPEND="
+	media-libs/libogg
+	media-libs/libtheora
+	media-libs/libvorbis"
+RDEPEND="
+	dev-libs/d0_blind_id
+	media-libs/libjpeg-turbo:=
+	media-libs/libpng
+	media-libs/freetype:2
+	net-misc/curl
+	sys-libs/zlib:=
+	X? (
+		${COMMON_UIDEPEND}
+		media-libs/libglvnd[X]
+		x11-libs/libX11
+		x11-libs/libXext
+		x11-libs/libXpm
+		x11-libs/libXxf86vm
+		alsa? ( media-libs/alsa-lib )
+	)
+	ode? ( dev-games/ode:=[double-precision] )
+	sdl? (
+		${COMMON_UIDEPEND}
+		media-libs/libsdl2[joystick,opengl,sound,video]
+	)"
+DEPEND="
+	${RDEPEND}
+	X? ( x11-base/xorg-proto )"
+BDEPEND="app-arch/unzip"
+
+CHECKREQS_DISK_BUILD="1500M"
+CHECKREQS_DISK_USR="1200M"
+
+src_prepare() {
+	default
+
+	sed -e 's|-O3 ||' \
+		-e '/^LDFLAGS_RELEASE/s/$(OPTIM_RELEASE)/$(GENTOO_LDFLAGS)/' \
+		-i source/darkplaces/makefile.inc || die
+}
+
+src_compile() {
+	tc-export CC
+
+	local emakeargs=(
+		-C source/darkplaces
+		DEFAULT_SNDAPI=$(usex alsa ALSA OSS)
+		DP_FS_BASEDIR="${EPREFIX}"/usr/share/${PN}
+		DP_LINK_ODE=$(usex ode shared no)
+		STRIP=:
+		CPUOPTIMIZATIONS="${CFLAGS}"
+		GENTOO_LDFLAGS="${LDFLAGS}"
+	)
+
+	# split for bug 473352
+	emake "${emakeargs[@]}" sv-release
+	use X && emake "${emakeargs[@]}" cl-release
+	use sdl && emake "${emakeargs[@]}" sdl-release
+}
+
+src_install() {
+	newbin {source/darkplaces/darkplaces,${PN}}-dedicated
+
+	if use X || use sdl; then
+		if use X; then
+			newbin {source/darkplaces/darkplaces,${PN}}-glx
+			domenu misc/logos/${PN}-glx.desktop
+		fi
+		if use sdl; then
+			newbin {source/darkplaces/darkplaces,${PN}}-sdl
+			domenu misc/logos/${PN}.desktop
+		fi
+
+		local size
+		for size in 16 22 24 32 48 128 256 512; do
+			newicon -s ${size} misc/logos/icons_png/${PN}_${size}.png ${PN}.png
+		done
+		newicon -s scalable misc/logos/${PN}_icon.svg ${PN}.svg
+	fi
+
+	dodoc Docs/*.{md,txt}
+
+	insinto /usr/share/${PN}
+	doins -r key_0.d0pk server data
+
+	rm "${ED}"/usr/share/${PN}/server/.gitattributes || die
+}


^ permalink raw reply related	[flat|nested] 18+ messages in thread

* [gentoo-commits] repo/gentoo:master commit in: games-fps/xonotic/
@ 2023-08-06  4:32 Ionen Wolkens
  0 siblings, 0 replies; 18+ messages in thread
From: Ionen Wolkens @ 2023-08-06  4:32 UTC (permalink / raw
  To: gentoo-commits

commit:     4272a10243ad9922992611d5723f25710da767f4
Author:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
AuthorDate: Sun Aug  6 00:45:04 2023 +0000
Commit:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
CommitDate: Sun Aug  6 04:27:42 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=4272a102

games-fps/xonotic: drop 0.8.5

Signed-off-by: Ionen Wolkens <ionen <AT> gentoo.org>

 games-fps/xonotic/Manifest             |   1 -
 games-fps/xonotic/xonotic-0.8.5.ebuild | 105 ---------------------------------
 2 files changed, 106 deletions(-)

diff --git a/games-fps/xonotic/Manifest b/games-fps/xonotic/Manifest
index bb6cfce6cfc1..0416a5788373 100644
--- a/games-fps/xonotic/Manifest
+++ b/games-fps/xonotic/Manifest
@@ -1,2 +1 @@
-DIST xonotic-0.8.5.zip 1228561792 BLAKE2B 3f1391ff6522c8f6b7b4f717aecd6ffe852142d70e7cffff9cb5a602a69142c59850636cc1450aade5ae39088354170b819f696427ba8829bf7c375029f2430a SHA512 4ffc4b73eeb5f580d178a98419d5b44cbff0c56e356a62baa729b5b7a6c3d43b2b425b123428c9b1bf3f4718eaf61bcf5d62914521cc061c7563a253440c807e
 DIST xonotic-0.8.6.zip 1238439495 BLAKE2B f9a9823a2ef8a1a8790c92fe898599938ff39fe9a32bb1f3595a4b451237f7fca29385feeaf8164216713a2cbe2db4d78cadeee91bb08093dae4a7ad1588e4d4 SHA512 cb39879e96f19abb2877588c2d50c5d3e64dd68153bec3dd1bebedf4d765e506afa419c28381d7005aed664cb1a042571c132b5b319e4308cab67745d996c2a6

diff --git a/games-fps/xonotic/xonotic-0.8.5.ebuild b/games-fps/xonotic/xonotic-0.8.5.ebuild
deleted file mode 100644
index de5cb5d5a726..000000000000
--- a/games-fps/xonotic/xonotic-0.8.5.ebuild
+++ /dev/null
@@ -1,105 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit desktop check-reqs toolchain-funcs xdg
-
-DESCRIPTION="Fork of Nexuiz, Deathmatch FPS based on DarkPlaces, an advanced Quake 1 engine"
-HOMEPAGE="https://xonotic.org/"
-SRC_URI="https://dl.xonotic.org/${P}.zip"
-S="${WORKDIR}/${PN^}"
-
-LICENSE="GPL-3+ GPL-2+"
-SLOT="0"
-KEYWORDS="~amd64 ~arm64 ~x86"
-IUSE="X +alsa ode +sdl"
-
-# note: many dependencies are used through dlopen()
-COMMON_UIDEPEND="
-	media-libs/libogg
-	media-libs/libtheora
-	media-libs/libvorbis"
-RDEPEND="
-	dev-libs/d0_blind_id
-	media-libs/libjpeg-turbo:=
-	media-libs/libpng
-	media-libs/freetype:2
-	net-misc/curl
-	sys-libs/zlib:=
-	X? (
-		${COMMON_UIDEPEND}
-		media-libs/libglvnd[X]
-		x11-libs/libX11
-		x11-libs/libXext
-		x11-libs/libXpm
-		x11-libs/libXxf86vm
-		alsa? ( media-libs/alsa-lib )
-	)
-	ode? ( dev-games/ode:=[double-precision] )
-	sdl? (
-		${COMMON_UIDEPEND}
-		media-libs/libsdl2[joystick,opengl,sound,video]
-	)"
-DEPEND="
-	${RDEPEND}
-	X? ( x11-base/xorg-proto )"
-BDEPEND="app-arch/unzip"
-
-CHECKREQS_DISK_BUILD="1500M"
-CHECKREQS_DISK_USR="1200M"
-
-src_prepare() {
-	default
-
-	sed -e 's|-O3 ||' \
-		-e '/^LDFLAGS_RELEASE/s/$(OPTIM_RELEASE)/$(GENTOO_LDFLAGS)/' \
-		-i source/darkplaces/makefile.inc || die
-}
-
-src_compile() {
-	tc-export CC
-
-	local emakeargs=(
-		-C source/darkplaces
-		DEFAULT_SNDAPI=$(usex alsa ALSA OSS)
-		DP_FS_BASEDIR="${EPREFIX}"/usr/share/${PN}
-		DP_LINK_ODE=$(usex ode shared no)
-		STRIP=:
-		CPUOPTIMIZATIONS="${CFLAGS}"
-		GENTOO_LDFLAGS="${LDFLAGS}"
-	)
-
-	# split for bug 473352
-	emake "${emakeargs[@]}" sv-release
-	use X && emake "${emakeargs[@]}" cl-release
-	use sdl && emake "${emakeargs[@]}" sdl-release
-}
-
-src_install() {
-	newbin {source/darkplaces/darkplaces,${PN}}-dedicated
-
-	if use X || use sdl; then
-		if use X; then
-			newbin {source/darkplaces/darkplaces,${PN}}-glx
-			domenu misc/logos/${PN}-glx.desktop
-		fi
-		if use sdl; then
-			newbin {source/darkplaces/darkplaces,${PN}}-sdl
-			domenu misc/logos/${PN}.desktop
-		fi
-
-		local size
-		for size in 16 22 24 32 48 128 256 512; do
-			newicon -s ${size} misc/logos/icons_png/${PN}_${size}.png ${PN}.png
-		done
-		newicon -s scalable misc/logos/${PN}_icon.svg ${PN}.svg
-	fi
-
-	dodoc Docs/*.{md,txt}
-
-	insinto /usr/share/${PN}
-	doins -r key_0.d0pk server data
-
-	rm "${ED}"/usr/share/${PN}/server/.gitattributes || die
-}


^ permalink raw reply related	[flat|nested] 18+ messages in thread

end of thread, other threads:[~2023-08-06  4:32 UTC | newest]

Thread overview: 18+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2017-05-18  9:01 [gentoo-commits] repo/gentoo:master commit in: games-fps/xonotic/ Lars Wendler
  -- strict thread matches above, loose matches on Subject: below --
2023-08-06  4:32 Ionen Wolkens
2023-07-20 12:02 Ionen Wolkens
2023-07-20 12:02 Ionen Wolkens
2022-07-04 15:56 Ionen Wolkens
2022-07-04 15:56 Ionen Wolkens
2021-12-14  9:04 Sam James
2020-07-26 20:23 James Le Cuirot
2018-05-06 19:03 Matt Turner
2017-12-10 21:41 Michał Górny
2017-05-31  7:51 Lars Wendler
2017-05-19  6:49 Lars Wendler
2017-05-18  9:02 Lars Wendler
2015-12-18  0:47 Michael Sterrett
2015-12-18  0:47 Michael Sterrett
2015-12-03 13:28 Agostino Sarubbo
2015-12-02 14:29 Agostino Sarubbo
2015-10-08  8:36 Michael Sterrett

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox