[gentoo-commits] repo/gentoo:master commit in: dev-python/jaraco-packaging/

["Michał Górny" <mgorny@gentoo.org>]

commit:     6323fb2b70dee55fca165797955ff58fad3656bd
Author:     Louis Sautier <sautier.louis <AT> gmail <DOT> com>
AuthorDate: Sat May 13 15:49:22 2017 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Mon May 15 09:09:22 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=6323fb2b

dev-python/jaraco-packaging: new package, version 4.1

Tools to supplement packaging Python releases.

Closes: https://github.com/gentoo/gentoo/pull/4617
Bug: https://bugs.gentoo.org/617962
Package-Manager: Portage-2.3.5, Repoman-2.3.2

 dev-python/jaraco-packaging/Manifest               |  1 +
 .../jaraco-packaging/jaraco-packaging-4.1.ebuild   | 47 ++++++++++++++++++++++
 dev-python/jaraco-packaging/metadata.xml           | 21 ++++++++++
 3 files changed, 69 insertions(+)

diff --git a/dev-python/jaraco-packaging/Manifest b/dev-python/jaraco-packaging/Manifest
new file mode 100644
index 00000000000..7bc721c3e6c
--- /dev/null
+++ b/dev-python/jaraco-packaging/Manifest
@@ -0,0 +1 @@
+DIST jaraco.packaging-4.1.tar.gz 8820 SHA256 9980b0fb6a0d2ee754d5979c9e5e02f31853da8e9046dc99f5abfcb7ace9e189 SHA512 381ac1ba3a8eeea1235e719d98b61e38399d3fea1310732b0e2f921a3d46544efbb12c23c03bfa3ecfa07697458cb8930ca5156df7b411509c7b1da0b673d7cd WHIRLPOOL 887d743fef6d1e5b8aa97b1ae0d83500f2c68f61520978557a0a53ec7d58b6f42740e3669340e7101cf1c3afd9638da4bf27e6ab5402229b614a27267d62df9b

diff --git a/dev-python/jaraco-packaging/jaraco-packaging-4.1.ebuild b/dev-python/jaraco-packaging/jaraco-packaging-4.1.ebuild
new file mode 100644
index 00000000000..1584db69651
--- /dev/null
+++ b/dev-python/jaraco-packaging/jaraco-packaging-4.1.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( pypy{,3} python{2_7,3_{4,5,6}} )
+
+inherit distutils-r1
+
+MY_PN="${PN/-/.}"
+DESCRIPTION="Tools to supplement packaging Python releases"
+HOMEPAGE="https://github.com/jaraco/jaraco.packaging"
+SRC_URI="mirror://pypi/${PN:0:1}/${MY_PN}/${MY_PN}-${PV}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+RDEPEND=">=dev-python/six-1.4[${PYTHON_USEDEP}]"
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+	>=dev-python/setuptools_scm-1.9[${PYTHON_USEDEP}]
+	doc? (
+		dev-python/rst-linker[${PYTHON_USEDEP}]
+		dev-python/sphinx[${PYTHON_USEDEP}]
+	)
+	test? (
+		${RDEPEND}
+		>=dev-python/pytest-2.8[${PYTHON_USEDEP}]
+		dev-python/pytest-runner[${PYTHON_USEDEP}]
+	)
+"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+python_compile_all() {
+	if use doc; then
+		sphinx-build docs html || die "docs failed to build"
+		HTML_DOCS=( html/. )
+	fi
+}
+
+python_test() {
+	# Skip one test which requires network access
+	PYTHONPATH=. py.test -v -k "not test_revived_distribution" \
+		|| die "tests failed with ${EPYTHON}"
+}

diff --git a/dev-python/jaraco-packaging/metadata.xml b/dev-python/jaraco-packaging/metadata.xml
new file mode 100644
index 00000000000..7f4f59851b2
--- /dev/null
+++ b/dev-python/jaraco-packaging/metadata.xml
@@ -0,0 +1,21 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>sautier.louis@gmail.com</email>
+		<name>Louis Sautier</name>
+	</maintainer>
+	<maintainer type="project">
+		<email>proxy-maint@gentoo.org</email>
+		<name>Proxy Maintainers</name>
+	</maintainer>
+	<maintainer type="project">
+		<email>python@gentoo.org</email>
+		<name>Python</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="pypi">jaraco.packaging</remote-id>
+		<remote-id type="github">jaraco/jaraco.packaging</remote-id>
+		<bugs-to>https://github.com/jaraco/jaraco.packaging/issues</bugs-to>
+	</upstream>
+</pkgmetadata>