From mboxrd@z Thu Jan  1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-949608-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
	(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
	(No client certificate requested)
	by finch.gentoo.org (Postfix) with ESMTPS id EEB5A139695
	for <garchives@archives.gentoo.org>; Sat, 13 May 2017 17:50:28 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
	by pigeon.gentoo.org (Postfix) with SMTP id E473DE0C37;
	Sat, 13 May 2017 17:50:25 +0000 (UTC)
Received: from smtp.gentoo.org (smtp.gentoo.org [140.211.166.183])
	(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
	(No client certificate requested)
	by pigeon.gentoo.org (Postfix) with ESMTPS id B048DE0C37
	for <gentoo-commits@lists.gentoo.org>; Sat, 13 May 2017 17:50:25 +0000 (UTC)
Received: from oystercatcher.gentoo.org (unknown [IPv6:2a01:4f8:202:4333:225:90ff:fed9:fc84])
	(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
	(No client certificate requested)
	by smtp.gentoo.org (Postfix) with ESMTPS id 39CDC3416BB
	for <gentoo-commits@lists.gentoo.org>; Sat, 13 May 2017 17:50:24 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
	by oystercatcher.gentoo.org (Postfix) with ESMTP id 9B9344EBE
	for <gentoo-commits@lists.gentoo.org>; Sat, 13 May 2017 17:50:22 +0000 (UTC)
From: "William Hubbs" <williamh@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "William Hubbs" <williamh@gentoo.org>
Message-ID: <1494697773.3494f7e17468429f343a8239ce121d9e658e475d.williamh@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: sys-apps/openrc/
X-VCS-Repository: repo/gentoo
X-VCS-Files: sys-apps/openrc/Manifest sys-apps/openrc/openrc-0.26.1.ebuild
X-VCS-Directories: sys-apps/openrc/
X-VCS-Committer: williamh
X-VCS-Committer-Name: William Hubbs
X-VCS-Revision: 3494f7e17468429f343a8239ce121d9e658e475d
X-VCS-Branch: master
Date: Sat, 13 May 2017 17:50:22 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Archives-Salt: 499ab289-3555-4944-aa4f-b3e82e1e2619
X-Archives-Hash: f331b4046a6373d56db39a56ae8f95aa

commit:     3494f7e17468429f343a8239ce121d9e658e475d
Author:     William Hubbs <williamh <AT> gentoo <DOT> org>
AuthorDate: Fri May 12 22:37:59 2017 +0000
Commit:     William Hubbs <williamh <AT> gentoo <DOT> org>
CommitDate: Sat May 13 17:49:33 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=3494f7e1

sys-apps/openrc: 0.26.1 version bump

Package-Manager: Portage-2.3.5, Repoman-2.3.2

 sys-apps/openrc/Manifest             |   1 +
 sys-apps/openrc/openrc-0.26.1.ebuild | 329 +++++++++++++++++++++++++++++++++++
 2 files changed, 330 insertions(+)

diff --git a/sys-apps/openrc/Manifest b/sys-apps/openrc/Manifest
index 7508708c917..dcc5a091eac 100644
--- a/sys-apps/openrc/Manifest
+++ b/sys-apps/openrc/Manifest
@@ -3,4 +3,5 @@ DIST openrc-0.22.4.tar.gz 214321 SHA256 d428890c12936b502d79018667dc6094d0e801c5
 DIST openrc-0.23.2.tar.gz 209569 SHA256 244a9902a98694a7fd59ad3dec49bd9e61a6b22864795ed31ef8fc81aa474251 SHA512 6c8483d36812d21ba45bf3c386c6f1c03a9c01c10f48b7e7eb26707d105568b8017ba8a7728a794ac0ac6fedab10cea2bc9587f4d5ddb1957001e03f872e8f18 WHIRLPOOL 88f61ab81562bdcb1b616441f01cbc3b45aca45d0a55bf41e3a9d6b733b3dfec429bf3c1645811c187c21038674e56d3e32e6035062685b45765fb3b85740e3c
 DIST openrc-0.24.2.tar.gz 212605 SHA256 3d6486beb0a1b5fc696bce71b6a2d07590516699cfa3481f4852d759f7a9f8a4 SHA512 4f8557b16407148e1819986ed81976dbb0ccf24349317e3895665cfd37b9db2b549ce53774766fb5752e347b44cdabd45acdc252f5efbe272acc183be1e5476b WHIRLPOOL 17ba761f77553344fd8de919b52c61970d579b61711b275fc7161adbe31cf5e622e4abf1caf72257e9932e69474bebb02ea0fbca4f415f002cb32a7e3cf08dd6
 DIST openrc-0.25.tar.gz 216430 SHA256 e8ac607052a5c494b595b9641c66ad3ce5a1e867677066aacc33a5259868a121 SHA512 ab26df45b5856a62959796f4c9903650bb5fc87317a9d598585a6dd7b2087d96d6d2a800b6f1373e20514a6da05f873ebf0a79d325292c2ea61034fd1bbdb378 WHIRLPOOL c6e7f44e68bea8117b7aff45a3f1bcc75589f0df57388ea0cd8fef644102edae73bbee4d2e2248e9ff80aebbdaf86e55f25c506bdca4ac1f9c45da3594e421ce
+DIST openrc-0.26.1.tar.gz 218944 SHA256 02f2412d857a4c910cd1632287b6314ab0c445d3e98d2e46c4f01975beadc17c SHA512 384626a2dfcedf51e5648d88a875917f95fb1b411746f7fbf0b3fec4216d6d999c1755878b6c7f9a8838c3040daaa5982190fc95ba890ce806c5141309c1475c WHIRLPOOL 306d1674028e86ae6d3f0b3e8a57b5e6c106f4d0147a43c600ff79bfca6f7f0d8e1abe47542c2076c206d507adb485098106e8f8a750d98b2b012b6b9468a07e
 DIST openrc-0.26.tar.gz 218989 SHA256 fda4b12343abc54abe6cf75d8cb8319ae396b3de3d1d444ba49a3af623fc8f35 SHA512 f7d4da9b224f429f84dda9e6d910a374b2147c6d4236446b2fb9c38a7c6ae7f370f2c2e1261e51b5c1806a042d0a1bbf0aebefdb3c1d8116ccc313a3d5170782 WHIRLPOOL a278b12583d47aea1830dfc087215832f290d5bcdf28442a929cb5b81d3cd36f5b2709ccc8ca961d2d53c70144a325a742e7a24194aebe6b1e03df5380fb57ca

diff --git a/sys-apps/openrc/openrc-0.26.1.ebuild b/sys-apps/openrc/openrc-0.26.1.ebuild
new file mode 100644
index 00000000000..1ce8145c500
--- /dev/null
+++ b/sys-apps/openrc/openrc-0.26.1.ebuild
@@ -0,0 +1,329 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit flag-o-matic pam toolchain-funcs
+
+DESCRIPTION="OpenRC manages the services, startup and shutdown of a host"
+HOMEPAGE="https://github.com/openrc/openrc/"
+
+if [[ ${PV} == "9999" ]]; then
+	EGIT_REPO_URI="git://github.com/OpenRC/${PN}.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/${PN}/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd"
+fi
+
+LICENSE="BSD-2"
+SLOT="0"
+IUSE="audit debug ncurses pam newnet prefix +netifrc selinux static-libs
+	unicode kernel_linux kernel_FreeBSD"
+
+COMMON_DEPEND="kernel_FreeBSD? ( || ( >=sys-freebsd/freebsd-ubin-9.0_rc sys-process/fuser-bsd ) )
+	ncurses? ( sys-libs/ncurses:0= )
+	pam? (
+		sys-auth/pambase
+		virtual/pam
+	)
+	audit? ( sys-process/audit )
+	kernel_linux? (
+		sys-process/psmisc
+		!<sys-process/procps-3.3.9-r2
+	)
+	selinux? (
+		sys-apps/policycoreutils
+		sys-libs/libselinux
+	)
+	!<sys-apps/baselayout-2.1-r1
+	!<sys-fs/udev-init-scripts-27"
+DEPEND="${COMMON_DEPEND}
+	virtual/os-headers
+	ncurses? ( virtual/pkgconfig )"
+RDEPEND="${COMMON_DEPEND}
+	!prefix? (
+		kernel_linux? (
+			>=sys-apps/sysvinit-2.86-r6[selinux?]
+			virtual/tmpfiles
+		)
+		kernel_FreeBSD? ( sys-freebsd/freebsd-sbin )
+	)
+	selinux? (
+		sec-policy/selinux-base-policy
+		sec-policy/selinux-openrc
+	)
+"
+
+PDEPEND="netifrc? ( net-misc/netifrc )"
+
+src_prepare() {
+	default
+
+	sed -i 's:0444:0644:' mk/sys.mk || die
+
+	if [[ ${PV} == "9999" ]] ; then
+		local ver="git-${EGIT_VERSION:0:6}"
+		sed -i "/^GITVER[[:space:]]*=/s:=.*:=${ver}:" mk/gitver.mk || die
+	fi
+}
+
+src_compile() {
+	unset LIBDIR #266688
+
+	MAKE_ARGS="${MAKE_ARGS}
+		LIBNAME=$(get_libdir)
+		LIBEXECDIR=${EPREFIX}/$(get_libdir)/rc
+		MKNET=$(usex newnet)
+		MKSELINUX=$(usex selinux)
+		MKAUDIT=$(usex audit)
+		MKPAM=$(usev pam)
+		MKSTATICLIBS=$(usex static-libs)"
+
+	local brand="Unknown"
+	if use kernel_linux ; then
+		MAKE_ARGS="${MAKE_ARGS} OS=Linux"
+		brand="Linux"
+	elif use kernel_FreeBSD ; then
+		MAKE_ARGS="${MAKE_ARGS} OS=FreeBSD"
+		brand="FreeBSD"
+	fi
+	export BRANDING="Gentoo ${brand}"
+	use prefix && MAKE_ARGS="${MAKE_ARGS} MKPREFIX=yes PREFIX=${EPREFIX}"
+	export DEBUG=$(usev debug)
+	export MKTERMCAP=$(usev ncurses)
+
+	tc-export CC AR RANLIB
+	emake ${MAKE_ARGS}
+}
+
+# set_config <file> <option name> <yes value> <no value> test
+# a value of "#" will just comment out the option
+set_config() {
+	local file="${ED}/$1" var=$2 val com
+	eval "${@:5}" && val=$3 || val=$4
+	[[ ${val} == "#" ]] && com="#" && val='\2'
+	sed -i -r -e "/^#?${var}=/{s:=([\"'])?([^ ]*)\1?:=\1${val}\1:;s:^#?:${com}:}" "${file}"
+}
+
+set_config_yes_no() {
+	set_config "$1" "$2" YES NO "${@:3}"
+}
+
+src_install() {
+	emake ${MAKE_ARGS} DESTDIR="${D}" install
+
+	# move the shared libs back to /usr so ldscript can install
+	# more of a minimal set of files
+	# disabled for now due to #270646
+	#mv "${ED}"/$(get_libdir)/lib{einfo,rc}* "${ED}"/usr/$(get_libdir)/ || die
+	#gen_usr_ldscript -a einfo rc
+	gen_usr_ldscript libeinfo.so
+	gen_usr_ldscript librc.so
+
+	if ! use kernel_linux; then
+		keepdir /$(get_libdir)/rc/init.d
+	fi
+	keepdir /$(get_libdir)/rc/tmp
+
+	# Backup our default runlevels
+	dodir /usr/share/"${PN}"
+	cp -PR "${ED}"/etc/runlevels "${ED}"/usr/share/${PN} || die
+	rm -rf "${ED}"/etc/runlevels
+
+	# Setup unicode defaults for silly unicode users
+	set_config_yes_no /etc/rc.conf unicode use unicode
+
+	# Cater to the norm
+	set_config_yes_no /etc/conf.d/keymaps windowkeys '(' use x86 '||' use amd64 ')'
+
+	# On HPPA, do not run consolefont by default (bug #222889)
+	if use hppa; then
+		rm -f "${ED}"/usr/share/openrc/runlevels/boot/consolefont
+	fi
+
+	# Support for logfile rotation
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}"/openrc.logrotate openrc
+
+	# install gentoo pam.d files
+	newpamd "${FILESDIR}"/start-stop-daemon.pam start-stop-daemon
+	newpamd "${FILESDIR}"/start-stop-daemon.pam supervise-daemon
+
+	# install documentation
+	dodoc ChangeLog *.md
+	if use newnet; then
+		dodoc README.newnet
+	fi
+}
+
+add_boot_init() {
+	local initd=$1
+	local runlevel=${2:-boot}
+	# if the initscript is not going to be installed and is not
+	# currently installed, return
+	[[ -e "${ED}"/etc/init.d/${initd} || -e "${EROOT}"etc/init.d/${initd} ]] \
+		|| return
+	[[ -e "${EROOT}"etc/runlevels/${runlevel}/${initd} ]] && return
+
+	# if runlevels dont exist just yet, then create it but still flag
+	# to pkg_postinst that it needs real setup #277323
+	if [[ ! -d "${EROOT}"etc/runlevels/${runlevel} ]] ; then
+		mkdir -p "${EROOT}"etc/runlevels/${runlevel}
+		touch "${EROOT}"etc/runlevels/.add_boot_init.created
+	fi
+
+	elog "Auto-adding '${initd}' service to your ${runlevel} runlevel"
+	ln -snf /etc/init.d/${initd} "${EROOT}"etc/runlevels/${runlevel}/${initd}
+}
+add_boot_init_mit_config() {
+	local config=$1 initd=$2
+	if [[ -e ${EROOT}${config} ]] ; then
+		if [[ -n $(sed -e 's:#.*::' -e '/^[[:space:]]*$/d' "${EROOT}"${config}) ]] ; then
+			add_boot_init ${initd}
+		fi
+	fi
+}
+
+pkg_preinst() {
+	local f LIBDIR=$(get_libdir)
+
+	# avoid default thrashing in conf.d files when possible #295406
+	if [[ -e "${EROOT}"etc/conf.d/hostname ]] ; then
+		(
+		unset hostname HOSTNAME
+		source "${EROOT}"etc/conf.d/hostname
+		: ${hostname:=${HOSTNAME}}
+		[[ -n ${hostname} ]] && set_config /etc/conf.d/hostname hostname "${hostname}"
+		)
+	fi
+
+	# set default interactive shell to sulogin if it exists
+	set_config /etc/rc.conf rc_shell /sbin/sulogin "#" test -e /sbin/sulogin
+
+	# termencoding was added in 0.2.1 and needed in boot
+	has_version ">=sys-apps/openrc-0.2.1" || add_boot_init termencoding
+
+	# swapfiles was added in 0.9.9 and needed in boot (february 2012)
+	has_version ">=sys-apps/openrc-0.9.9" || add_boot_init swapfiles
+
+	if ! has_version ">=sys-apps/openrc-0.11"; then
+		add_boot_init sysfs sysinit
+	fi
+
+	if ! has_version ">=sys-apps/openrc-0.11.3" ; then
+		migrate_udev_mount_script
+		add_boot_init tmpfiles.setup boot
+	fi
+
+	# these were added in 0.12.
+	if ! has_version ">=sys-apps/openrc-0.12"; then
+		add_boot_init loopback
+		add_boot_init tmpfiles.dev sysinit
+
+		# ensure existing /etc/conf.d/net is not removed
+		# undoes the hack to get around CONFIG_PROTECT in openrc-0.11.8 and earlier
+		# this needs to stay in openrc ebuilds for a long time. :(
+		# Added in 0.12.
+		if [[ -f "${EROOT}"etc/conf.d/net ]]; then
+			einfo "Modifying conf.d/net to keep it from being removed"
+			cat <<-EOF >>"${EROOT}"etc/conf.d/net
+
+# The network scripts are now part of net-misc/netifrc
+# In order to avoid sys-apps/${P} from removing this file, this comment was
+# added; you can safely remove this comment.  Please see
+# /usr/share/doc/netifrc*/README* for more information.
+EOF
+		fi
+	fi
+	has_version ">=sys-apps/openrc-0.14" || add_boot_init binfmt
+
+	if ! has_version ">=sys-apps/openrc-0.18.3"; then
+		add_boot_init mtab
+		if [[ -f "${EROOT}"etc/mtab ]] && [[ ! -L "${EROOT}"etc/mtab ]]; then
+			ewarn "${EROOT}etc/mtab will be replaced with a"
+			ewarn "symbolic link to /proc/self/mounts on the next"
+			ewarn "reboot."
+			ewarn "Change the setting in ${EROOT}etc/conf.d/mtab"
+			ewarn "if you do not want this to happen."
+		fi
+	fi
+}
+
+# >=OpenRC-0.11.3 requires udev-mount to be in the sysinit runlevel with udev.
+migrate_udev_mount_script() {
+	if [ -e "${EROOT}"etc/runlevels/sysinit/udev -a \
+		! -e "${EROOT}"etc/runlevels/sysinit/udev-mount ]; then
+		add_boot_init udev-mount sysinit
+	fi
+	return 0
+}
+
+pkg_postinst() {
+	local LIBDIR=$(get_libdir)
+
+	# Make our runlevels if they don't exist
+	if [[ ! -e "${EROOT}"etc/runlevels ]] || [[ -e "${EROOT}"etc/runlevels/.add_boot_init.created ]] ; then
+		einfo "Copying across default runlevels"
+		cp -RPp "${EROOT}"usr/share/${PN}/runlevels "${EROOT}"etc
+		rm -f "${EROOT}"etc/runlevels/.add_boot_init.created
+	else
+		if [[ ! -e "${EROOT}"etc/runlevels/sysinit/devfs ]] ; then
+			mkdir -p "${EROOT}"etc/runlevels/sysinit
+			cp -RPp "${EROOT}"usr/share/${PN}/runlevels/sysinit/* \
+				"${EROOT}"etc/runlevels/sysinit
+		fi
+		if [[ ! -e "${EROOT}"etc/runlevels/shutdown/mount-ro ]] ; then
+			mkdir -p "${EROOT}"etc/runlevels/shutdown
+			cp -RPp "${EROOT}"usr/share/${PN}/runlevels/shutdown/* \
+				"${EROOT}"etc/runlevels/shutdown
+		fi
+		if [[ ! -e "${EROOT}"etc/runlevels/nonetwork/local ]]; then
+			cp -RPp "${EROOT}"usr/share/${PN}/runlevels/nonetwork \
+				"${EROOT}"etc/runlevels
+		fi
+	fi
+
+	if use hppa; then
+		elog "Setting the console font does not work on all HPPA consoles."
+		elog "You can still enable it by running:"
+		elog "# rc-update add consolefont boot"
+	fi
+
+	# Handle the conf.d/local.{start,stop} -> local.d transition
+	if path_exists -o "${EROOT}"etc/conf.d/local.{start,stop} ; then
+		elog "Moving your ${EROOT}etc/conf.d/local.{start,stop}"
+		elog "files to ${EROOT}etc/local.d"
+		mv "${EROOT}"etc/conf.d/local.start "${EROOT}"etc/local.d/baselayout1.start
+		mv "${EROOT}"etc/conf.d/local.stop "${EROOT}"etc/local.d/baselayout1.stop
+		chmod +x "${EROOT}"etc/local.d/*{start,stop}
+	fi
+
+	if use kernel_linux && [[ "${EROOT}" = "/" ]]; then
+		if ! /$(get_libdir)/rc/sh/migrate-to-run.sh; then
+			ewarn "The dependency data could not be migrated to /run/openrc."
+			ewarn "This means you need to reboot your system."
+		fi
+	fi
+
+	# update the dependency tree after touching all files #224171
+	[[ "${EROOT}" = "/" ]] && "${EROOT}/${LIBDIR}"/rc/bin/rc-depend -u
+
+	if ! use newnet && ! use netifrc; then
+		ewarn "You have emerged OpenRc without network support. This"
+		ewarn "means you need to SET UP a network manager such as"
+		ewarn "	net-misc/netifrc, net-misc/dhcpcd, net-misc/wicd,"
+		ewarn "net-misc/NetworkManager, or net-vpn/badvpn."
+		ewarn "Or, you have the option of emerging openrc with the newnet"
+		ewarn "use flag and configuring /etc/conf.d/network and"
+		ewarn "/etc/conf.d/staticroute if you only use static interfaces."
+		ewarn
+	fi
+
+	if use newnet && [ ! -e "${EROOT}"etc/runlevels/boot/network ]; then
+		ewarn "Please add the network service to your boot runlevel"
+		ewarn "as soon as possible. Not doing so could leave you with a system"
+		ewarn "without networking."
+		ewarn
+	fi
+}