[gentoo-commits] repo/gentoo:master commit in: x11-wm/lwm/

["Patrice Clement" <monsieurp@gentoo.org>]

commit:     c0ec0343c4f653126f27768902f86c6492f92ec0
Author:     Patrice Clement <monsieurp <AT> gentoo <DOT> org>
AuthorDate: Mon May  8 21:37:07 2017 +0000
Commit:     Patrice Clement <monsieurp <AT> gentoo <DOT> org>
CommitDate: Tue May  9 21:52:01 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c0ec0343

x11-wm/lwm: EAPI 6 bump.

Package-Manager: Portage-2.3.3, Repoman-2.3.1

 x11-wm/lwm/lwm-1.2.3-r1.ebuild | 50 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

diff --git a/x11-wm/lwm/lwm-1.2.3-r1.ebuild b/x11-wm/lwm/lwm-1.2.3-r1.ebuild
new file mode 100644
index 00000000000..e9c2c04cd62
--- /dev/null
+++ b/x11-wm/lwm/lwm-1.2.3-r1.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit toolchain-funcs
+
+DESCRIPTION="The ultimate lightweight window manager"
+SRC_URI="http://www.jfc.org.uk/files/lwm/${P}.tar.gz"
+HOMEPAGE="http://www.jfc.org.uk/software/lwm.html"
+
+KEYWORDS="~amd64 ~ppc ~sparc ~x86 ~x86-fbsd"
+LICENSE="GPL-2"
+SLOT="0"
+
+RDEPEND="
+	x11-libs/libICE
+	x11-libs/libSM
+	x11-libs/libX11
+	x11-libs/libXext
+"
+
+DEPEND="
+	${RDEPEND}
+	x11-misc/imake
+	x11-proto/xextproto
+	x11-proto/xproto
+"
+
+DOCS=( AUTHORS BUGS ChangeLog )
+
+src_prepare() {
+	default
+	sed -i -e "s#(SMLIB)#& -lICE#g" Imakefile || die #370127
+	xmkmf || die
+}
+
+src_compile() {
+	emake \
+		EXTRA_LDOPTIONS="${CFLAGS} ${LDFLAGS}" \
+		CFLAGS="${CFLAGS}" \
+		CC="$(tc-getCC)" \
+		"${PN}"
+}
+
+src_install() {
+	dobin "${PN}"
+	newman "${PN}.man" "${PN}.1"
+	einstalldocs
+}