[gentoo-commits] repo/gentoo:master commit in: x11-misc/zim/

["Jeroen Roovers" <jer@gentoo.org>]

commit:     5d977846bd26db1525d67d0c3e2ef045846570f3
Author:     Jeroen Roovers <jer <AT> gentoo <DOT> org>
AuthorDate: Sun Apr 30 07:53:18 2017 +0000
Commit:     Jeroen Roovers <jer <AT> gentoo <DOT> org>
CommitDate: Sun Apr 30 07:53:18 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=5d977846

x11-misc/zim: Version bump.

Package-Manager: Portage-2.3.5, Repoman-2.3.2

 x11-misc/zim/Manifest        |  1 +
 x11-misc/zim/zim-0.66.ebuild | 83 ++++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 84 insertions(+)

diff --git a/x11-misc/zim/Manifest b/x11-misc/zim/Manifest
index 1f4cac90a31..70304ddd4d5 100644
--- a/x11-misc/zim/Manifest
+++ b/x11-misc/zim/Manifest
@@ -1 +1,2 @@
 DIST zim-0.65.tar.gz 1899614 SHA256 5442f3334395a2beafc5b9a2bbec2e53e38270d4bad696b5c4053dd51dc1ed96 SHA512 dee652087d3d986b80353e9087abe363392354f40db11f8819d0b3f3c6f133c08c66c651a92ed77c1656f1135998ac02622eca08ac2e28c8fb3149a724a0f7fb WHIRLPOOL 22bfeaee53214029538ba76d309f3413fa327aec125e49270f168a5d985e37672f3a8cc8043e4a35d1141ffb54f958c0a466c6edac4192028893d017401ce2a2
+DIST zim-0.66.tar.gz 2020216 SHA256 e8b53948097f211972713252f3a89b2957e3a63f55eb53587e2474dfc4cbf6c4 SHA512 9693dba8ee6ad915a85ca999674350b278043559ba4adf93c03c8815211ecab451a6e2dceaf62ea7048609eb86f19485f2dd77dbaaf6f2d81f97f6450bf25ca9 WHIRLPOOL eca653cff7581e3f8b4e43d33860e49cd0fb36dfabbdb2aefb86cb9aa804c269a32ea41823f8292969f9431725221032c91881e1a328f780e1390a3c2587ef2c

diff --git a/x11-misc/zim/zim-0.66.ebuild b/x11-misc/zim/zim-0.66.ebuild
new file mode 100644
index 00000000000..624a7703ae6
--- /dev/null
+++ b/x11-misc/zim/zim-0.66.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 )
+PYTHON_REQ_USE="sqlite"
+DISTUTILS_SINGLE_IMPL=1
+
+inherit distutils-r1 gnome2-utils fdo-mime virtualx
+
+DESCRIPTION="A desktop wiki"
+HOMEPAGE="http://zim-wiki.org/"
+SRC_URI="http://zim-wiki.org/downloads/${P}.tar.gz"
+
+LICENSE="BSD GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+
+RDEPEND="dev-python/pygtk[${PYTHON_USEDEP}]
+	dev-python/pygobject:2[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	x11-misc/xdg-utils
+	test? (
+		dev-vcs/bzr
+		dev-vcs/git
+		dev-vcs/mercurial )"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.60-remove-ubuntu-theme.patch
+)
+
+python_prepare() {
+	sed -i -e "s/'USER'/'LOGNAME'/g" zim/__init__.py zim/fs.py || die
+
+	if [[ ${LINGUAS} ]]; then
+		local lingua
+		for lingua in translations/*.po; do
+			lingua=${lingua/.po}
+			lingua=${lingua/translations\/}
+			has ${lingua} ${LINGUAS} || \
+				{ rm translations/${lingua}.po || die; }
+		done
+	fi
+
+	distutils-r1_python_prepare
+}
+
+python_test() {
+	VIRTUALX_COMMAND="${PYTHON}" virtualmake test.py
+}
+
+python_install() {
+	distutils-r1_python_install --skip-xdg-cmd
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	fdo-mime_desktop_database_update
+	gnome2_icon_cache_update
+	if ! has_version ${CATEGORY}/${PN}; then
+		einfo "Please emerge these packages for additional functionality"
+		einfo "    dev-lang/R"
+		einfo "    dev-python/gtkspell-python"
+		einfo "    dev-vcs/bzr"
+		einfo "    gnome-extra/zeitgeist"
+		einfo "    media-gfx/graphviz"
+		einfo "    media-gfx/imagemagick"
+		einfo "    media-gfx/scrot"
+		einfo "    media-sound/lilypond"
+		einfo "    sci-visualization/gnuplot"
+		einfo "    virtual/latex-base app-text/dvipng"
+	fi
+}
+
+pkg_postrm() {
+	fdo-mime_desktop_database_update
+	gnome2_icon_cache_update
+}