[gentoo-commits] repo/gentoo:master commit in: dev-python/twisted/

["Brian Dolbec" <dolsen@gentoo.org>]

commit:     88eca7f31805cac0aba446d437f581700e4aa9bb
Author:     Brian Dolbec <dolsen <AT> gentoo <DOT> org>
AuthorDate: Fri Mar 31 20:56:40 2017 +0000
Commit:     Brian Dolbec <dolsen <AT> gentoo <DOT> org>
CommitDate: Fri Mar 31 21:08:52 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=88eca7f3

dev-python/twisted: Version bump

Package-Manager: Portage-2.3.5, Repoman-2.3.2_p30

 dev-python/twisted/Manifest              |   1 +
 dev-python/twisted/twisted-17.1.0.ebuild | 164 +++++++++++++++++++++++++++++++
 2 files changed, 165 insertions(+)

diff --git a/dev-python/twisted/Manifest b/dev-python/twisted/Manifest
index 34853df61ab..19a472c33ce 100644
--- a/dev-python/twisted/Manifest
+++ b/dev-python/twisted/Manifest
@@ -2,3 +2,4 @@ DIST Twisted-16.2.0.tar.bz2 2942537 SHA256 a090e8dc675e97fb20c3bb5f8114ae94169f4
 DIST Twisted-16.3.2.tar.bz2 2916410 SHA256 22c32e68feb6be7ea68bcbc8f89184f06b5693a9f1b59d052927d19597645967 SHA512 6ddca880a06087717487d8a5cc128da81f1acbc97e5c372b1ba51eaeb87390ae7f91925e8e4cc90f29df21692bc11b6e0fe3772341b8488940895e57942e5149 WHIRLPOOL ad381b36f94351c15713e35d6312bae35c78ff90eb485892131f7db8c89168ccf5ddbc9d486bfeb47db695e75280bc73401194c6b36815c5859cc945d0191a7b
 DIST Twisted-16.4.1.tar.bz2 2975697 SHA256 1d8d73f006c990744effb35588359fd44d43608649ac0b6b7edc71176e88e816 SHA512 7d841f5ef7fbcc5c215e5fb0d56934c6b37ecb0835a9e602a2b788a76960c669eb910a58c1f40f3e15121a7852a1055d377891c7ce3f2e360292a41341ab6bfe WHIRLPOOL 1c79ea538cddd2026d2aa02367e37f22dec23746f720ce3a25c8065d9db616c622faa89b0011966a27a47f3336fcca066ad85645d3316bbaa318f6143ac8f8cf
 DIST Twisted-16.6.0.tar.bz2 2979747 SHA256 d0fe115ea7ef8cf632d05103de60356c6e992b2153d6830bdc4476f8accb1fca SHA512 0b8de0ec7f64457f76c396fced64b366b8e63c6e000a5edc6c6388cd917fb2f95711918cd8edda39e0aa77e2cd32b5d775d23630a5ad10fc013c18f8316300cf WHIRLPOOL a09a8747312580e3b27d222bf0942b714ad041044a817876e1731c5fa2ae3d11e4d5a45221d2e7d126ebb664730d15c886d5ae164841c7a8f0acd6e12c4691a9
+DIST Twisted-17.1.0.tar.bz2 2997334 SHA256 dbf211d70afe5b4442e3933ff01859533eba9f13d8b3e2e1b97dc2125e2d44dc SHA512 e5eedc9a70b7e4d0ec18dddaa82aa9a784e96fd517db65c278d822d15e8bdc65a35307a5a0474eb68dcb73fcd5508086bec605580a9f2f767bcbe27d714b4966 WHIRLPOOL 828a939134df47950a285c732867b3d4172e5e86a75fbdc1cc4365b5a24699a0b3fcb573b7e3d389eea591fc9fc79456c09f2d2c8f08d7e1215dc5761e88ed8e

diff --git a/dev-python/twisted/twisted-17.1.0.ebuild b/dev-python/twisted/twisted-17.1.0.ebuild
new file mode 100644
index 00000000000..74f7447e1fb
--- /dev/null
+++ b/dev-python/twisted/twisted-17.1.0.ebuild
@@ -0,0 +1,164 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+PYTHON_COMPAT=( python2_7 python3_{4,5,6})
+PYTHON_REQ_USE="threads(+)"
+TWISTED_PN="Twisted"
+#DISTUTILS_IN_SOURCE_BUILD="yes"
+
+inherit eutils flag-o-matic twisted-r1
+
+DESCRIPTION="An asynchronous networking framework written in Python"
+SRC_URI="http://twistedmatrix.com/Releases/${TWISTED_PN}"
+SRC_URI="${SRC_URI}/${TWISTED_RELEASE}/${TWISTED_P}.tar.bz2"
+
+# Dropped keywords due to new deps not keyworded
+#KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~ppc ~ppc64 ~s390 ~sh ~x86 ~x86-fbsd ~ia64-hpux ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~mips ~ppc ~ppc64 ~x86"
+IUSE="conch crypt http2 serial +soap test"
+
+RDEPEND=">=dev-python/zope-interface-4.0.2[${PYTHON_USEDEP}]
+	conch? (
+		dev-python/pyasn1[${PYTHON_USEDEP}]
+		>=dev-python/cryptography-0.9.1[${PYTHON_USEDEP}]
+		>=dev-python/appdirs-1.4.0[${PYTHON_USEDEP}]
+	)
+	crypt? (
+		>=dev-python/pyopenssl-16.0.0[${PYTHON_USEDEP}]
+		dev-python/service_identity[${PYTHON_USEDEP}]
+		>=dev-python/idna-0.6[${PYTHON_USEDEP}]
+	)
+	serial? ( dev-python/pyserial[${PYTHON_USEDEP}] )
+	soap? ( $(python_gen_cond_dep 'dev-python/soappy[${PYTHON_USEDEP}]' python2_7) )
+	http2? (
+		>=dev-python/hyper-h2-2.5.0[${PYTHON_USEDEP}]
+		<dev-python/hyper-h2-3.0.0[${PYTHON_USEDEP}]
+		>=dev-python/priority-1.1.0[${PYTHON_USEDEP}]
+		<dev-python/priority-2.0[${PYTHON_USEDEP}]
+	)
+	>=dev-python/constantly-15.1.0[${PYTHON_USEDEP}]
+	!dev-python/twisted-core
+	!dev-python/twisted-conch
+	!dev-python/twisted-lore
+	!dev-python/twisted-mail
+	!dev-python/twisted-names
+	!dev-python/twisted-news
+	!dev-python/twisted-pair
+	!dev-python/twisted-runner
+	!dev-python/twisted-words
+	!dev-python/twisted-web
+"
+DEPEND="
+	>=dev-python/incremental-16.10.1[${PYTHON_USEDEP}]
+	test? (
+		dev-python/gmpy[${PYTHON_USEDEP}]
+		dev-python/pyasn1[${PYTHON_USEDEP}]
+		>=dev-python/cryptography-0.9.1[${PYTHON_USEDEP}]
+		>=dev-python/appdirs-1.4.0[${PYTHON_USEDEP}]
+		>=dev-python/pyopenssl-0.13[${PYTHON_USEDEP}]
+		dev-python/service_identity[${PYTHON_USEDEP}]
+		dev-python/idna[${PYTHON_USEDEP}]
+		dev-python/pyserial[${PYTHON_USEDEP}]
+		>=dev-python/constantly-15.1.0[${PYTHON_USEDEP}]
+	)
+"
+
+PATCHES=(
+	# Respect TWISTED_DISABLE_WRITING_OF_PLUGIN_CACHE variable.
+	"${FILESDIR}/${PN}-16.5.0-respect_TWISTED_DISABLE_WRITING_OF_PLUGIN_CACHE.patch"
+	"${FILESDIR}/test_main.patch"
+	"${FILESDIR}/utf8_overrides.patch"
+	"${FILESDIR}/${PN}-16.6.0-test-fixes.patch"
+)
+
+python_prepare_all() {
+	# disable tests that don't work in our sandbox
+	# and other test failures due to our conditions
+	if use test ; then
+		# Remove since this is an upstream distribution test for making releases
+		rm src/twisted/python/test/test_release.py || die "rm src/twisted/python/test/test_release.py FAILED"
+	fi
+	distutils-r1_python_prepare_all
+}
+
+python_compile() {
+	if ! python_is_python3; then
+		# Needed to make the sendmsg extension work
+		# (see http://twistedmatrix.com/trac/ticket/5701 )
+		local -x CFLAGS="${CFLAGS} -fno-strict-aliasing"
+		local -x CXXFLAGS="${CXXFLAGS} -fno-strict-aliasing"
+	fi
+
+	distutils-r1_python_compile
+}
+
+python_test() {
+	distutils_install_for_testing
+
+	export EMERGE_TEST_OVERRIDE=1
+	export UTF8_OVERRIDES=1
+	# workaround for the eclass not installing the entry points
+	# in the test environment.  copy the old 16.3.2 start script
+	# to run the tests with
+	cp "${FILESDIR}"/trial "${TEST_DIR}"
+
+	pushd "${TEST_DIR}" > /dev/null || die
+
+	if ! "${TEST_DIR}"/trial twisted; then
+		die "Tests failed with ${EPYTHON}"
+	fi
+	# due to an anomoly in the tests, python doesn't return the correct form
+	# of the escape sequence. So run those test separately with a clean python interpreter
+	export UTF8_OVERRIDES=0
+	if ! "${TEST_DIR}"/trial twisted.test.test_twistd.DaemonizeTests; then
+		die "DaemonizeTests failed with ${EPYTHON}"
+	fi
+	if ! "${TEST_DIR}"/trial twisted.test.test_reflect.SafeStrTests; then
+		die "SafeStrTests failed with ${EPYTHON}"
+	fi
+
+	popd > /dev/null || die
+}
+
+python_install() {
+	distutils-r1_python_install
+
+	cd "${D%/}$(python_get_sitedir)" || die
+
+	# create 'Twisted' egg wrt bug #299736
+	#local egg=( Twisted_Core*.egg-info )
+	#[[ -f ${egg[0]} ]] || die "Twisted_Core*.egg-info not found"
+	#ln -s "${egg[0]}" "${egg[0]/_Core/}" || die
+
+	# own the dropin.cache so we don't leave orphans
+	touch twisted/plugins/dropin.cache || die
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	newconfd "${FILESDIR}/twistd.conf" twistd
+	newinitd "${FILESDIR}/twistd.init" twistd
+}
+
+pkg_postinst() {
+	einfo "Install complete"
+	if use test ; then
+		einfo ""
+		einfo "Some tests have been disabled during testing due to"
+		einfo "known incompatibilities with the emerge sandboxes and/or"
+		einfo "not runnable as the root user."
+		einfo "For a complete test suite run on the code."
+		einfo "Run the tests as a normal user for each python it is installed to."
+		einfo "  ie:  $ python3.6 /usr/bin/trial twisted"
+		einfo "There are a few known python-2.7 errors due to some unicode issues"
+		einfo "which are different in Gentoo installed python-2.7"
+	fi
+}
+
+pkg_postrm(){
+	# pre portage-2.3.2 release workaround for bug 595028
+	cd "${HOME}"
+	_distutils-r1_run_foreach_impl twisted-r1_update_plugin_cache
+}