[gentoo-commits] repo/gentoo:master commit in: dev-python/Kivy/

["Slawek Lis" <slis@gentoo.org>]

commit:     6b6029857a071b7baedffe18fce6d49bf6be181f
Author:     Slawomir Lis <slis <AT> gentoo <DOT> org>
AuthorDate: Wed Mar 29 09:30:38 2017 +0000
Commit:     Slawek Lis <slis <AT> gentoo <DOT> org>
CommitDate: Wed Mar 29 09:33:14 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=6b602985

dev-python/Kivy: fixed installing examples

Reported in #613354. In EAPI 6 using EXAMPLES var is banned. Fixed.

Reported-By: MaurizioB
Package-Manager: Portage-2.3.5, Repoman-2.3.2

 dev-python/Kivy/Kivy-1.9.1-r1.ebuild | 71 ++++++++++++++++++++++++++++++++++++
 1 file changed, 71 insertions(+)

diff --git a/dev-python/Kivy/Kivy-1.9.1-r1.ebuild b/dev-python/Kivy/Kivy-1.9.1-r1.ebuild
new file mode 100644
index 00000000000..e21b01c75f5
--- /dev/null
+++ b/dev-python/Kivy/Kivy-1.9.1-r1.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python{2_7,3_4,3_5} )
+
+inherit distutils-r1
+
+DISTUTILS_IN_SOURCE_BUILD=1
+
+DESCRIPTION="Library for rapid development of hardware-accelerated multitouch applications"
+HOMEPAGE="http://kivy.org/"
+SRC_URI="https://pypi.io/packages/source/${PN:0:1}/${PN}/${P,,}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="cairo camera doc examples garden gstreamer +sdl spell test"
+
+RDEPEND="
+	dev-python/pillow[${PYTHON_USEDEP}]
+	cairo? ( dev-python/pycairo[${PYTHON_USEDEP}] )
+	camera? ( media-libs/opencv:0/2.4[$(python_gen_usedep 'python2_7')] )
+	garden? ( dev-python/kivy-garden[${PYTHON_USEDEP}] )
+	gstreamer? ( dev-python/gst-python:1.0[${PYTHON_USEDEP}] )
+	sdl? ( media-libs/libsdl2
+		media-libs/sdl2-ttf
+		media-libs/sdl2-image
+		media-libs/sdl2-mixer )
+	!sdl? ( dev-python/pygame[${PYTHON_USEDEP}] )
+	spell? ( dev-python/pyenchant[${PYTHON_USEDEP}] )"
+DEPEND="${RDEPEND}
+	dev-python/cython[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? ( dev-python/nose[${PYTHON_USEDEP}] )"
+
+S="${WORKDIR}/${P,,}"
+
+python_prepare_all() {
+	sed -e '/data_files=/d' -i "${S}/setup.py" || die
+	sed -e 's/PYTHON = python/PYTHON ?= python/' -i Makefile || die
+
+	export USE_SDL2=$(usex sdl 1 0)
+	export USE_GSTREAMER=$(usex gstreamer 1 0)
+	export KIVY_USE_SETUPTOOLS=1
+	distutils-r1_python_prepare_all
+}
+
+python_compile() {
+	esetup.py build_ext --inplace
+	esetup.py build
+}
+
+python_compile_all() {
+	use doc && emake html
+}
+
+python_test() {
+	emake test PYTHON="${PYTHON}"
+}
+
+python_install_all() {
+	use doc && HTML_DOCS=( doc/build/html/. )
+	if use examples; then
+		insinto "/usr/share/doc/${PF}/examples/${f}/"
+		doins "${S}/examples"/* "${S}/examples"/*/*
+	fi
+	distutils-r1_python_install_all
+}