[gentoo-commits] repo/gentoo:master commit in: mail-client/claws-mail/

["Lars Wendler" <polynomial-c@gentoo.org>]

commit:     82c4929ad32c13ef7859fbb6cd39ccf80a408942
Author:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
AuthorDate: Mon Mar 27 07:34:39 2017 +0000
Commit:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
CommitDate: Mon Mar 27 07:39:06 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=82c4929a

mail-client/claws-mail: Bump to version 3.15.0

Package-Manager: Portage-2.3.5, Repoman-2.3.2

 mail-client/claws-mail/Manifest                 |   1 +
 mail-client/claws-mail/claws-mail-3.15.0.ebuild | 202 ++++++++++++++++++++++++
 2 files changed, 203 insertions(+)

diff --git a/mail-client/claws-mail/Manifest b/mail-client/claws-mail/Manifest
index e0fd78223e1..60c7a14a709 100644
--- a/mail-client/claws-mail/Manifest
+++ b/mail-client/claws-mail/Manifest
@@ -1,2 +1,3 @@
 DIST claws-mail-3.13.2.tar.xz 5582600 SHA256 6a731052814b3284abeca1662d47817a86e018bc7123ab428f015f0cfab40ad1 SHA512 7356a4286fc76e215746de846f412e80b4d21c3be90ac8edd7719be2874569f953ce5c094e4a20b0c467db994d710135fc14bcb01f8fb4e947bf7d1666261ea3 WHIRLPOOL ec64d157fffd7be2849c92209cf3a5cc29935fa60a9061577c1b0bbcdac28b51f800c731ebf5f9598bc34f56ee9815adddfb5691f5faa81c92252bd182ab5120
 DIST claws-mail-3.14.1.tar.xz 5812444 SHA256 b79a1dc04f0b3d1f693e84d7fa7282f140fb5280179281445a8b954ce423c335 SHA512 ee1653ebd14b8aee76e97ce81ec203e0beeea7074eba0aa34c69bceb0a80135cdb16e508009cb479047d5112abd7eaa4bdb7e46722f33a88419fb24eeb75ac30 WHIRLPOOL ae5f6296f6f56c7dd8683efa68f3d688d806a5f5da576147ad4e685d16def294c6a5f2e1bca18e137995bed2dffad1e2fd2fcfb990a96d68950eb38c96640e13
+DIST claws-mail-3.15.0.tar.xz 5665648 SHA256 4e4d2d0d43f8ae3d4623408612f5979e9a697ccbc12038b80dd27802e868dc2e SHA512 667cb0ea2f7c5d8e8b6046313ed7698c378f504caeeaa54348ba228317538dfc040e4ddf80f4aaa1491858a7803954e89599b1e479febe7cf1ab4bae5a638dc8 WHIRLPOOL 18c041a770a14c9f5c87d086965b302e2ced8aee8954ed6e3d7934ce011053b7dca8ee13958dc4485172344d70fc0facbf10cc7e62ea8f8feadbd12ba4980cb4

diff --git a/mail-client/claws-mail/claws-mail-3.15.0.ebuild b/mail-client/claws-mail/claws-mail-3.15.0.ebuild
new file mode 100644
index 00000000000..caa75e6b6ea
--- /dev/null
+++ b/mail-client/claws-mail/claws-mail-3.15.0.ebuild
@@ -0,0 +1,202 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 )
+inherit autotools gnome2-utils eutils python-single-r1
+
+DESCRIPTION="An email client (and news reader) based on GTK+"
+HOMEPAGE="http://www.claws-mail.org/"
+
+SRC_URI="http://www.claws-mail.org/download.php?file=releases/${P}.tar.xz"
+
+SLOT="0"
+LICENSE="GPL-3"
+KEYWORDS="~amd64 ~x86"
+
+IUSE="archive bogofilter calendar clamav dbus debug doc gdata +gnutls gtk3 +imap ipv6 ldap +libcanberra +libindicate +libnotify networkmanager nls nntp +notification pda pdf perl +pgp python rss session sieve smime spamassassin spam-report spell startup-notification svg valgrind xface"
+REQUIRED_USE="libcanberra? ( notification )
+	libindicate? ( notification )
+	libnotify? ( notification )
+	networkmanager? ( dbus )
+	smime? ( pgp )"
+
+COMMONDEPEND="
+	net-mail/ytnef
+	archive? (
+		app-arch/libarchive
+		>=net-misc/curl-7.9.7
+	)
+	bogofilter? ( mail-filter/bogofilter )
+	calendar? (
+		>=dev-libs/libical-2.0.0
+		>=net-misc/curl-7.9.7
+	)
+	dbus? ( >=dev-libs/dbus-glib-0.60 )
+	gdata? ( >=dev-libs/libgdata-0.17.2 )
+	gnutls? ( >=net-libs/gnutls-3.0 )
+	gtk3? ( x11-libs/gtk+:3 )
+	!gtk3? ( >=x11-libs/gtk+-2.20:2 )
+	imap? ( >=net-libs/libetpan-0.57 )
+	ldap? ( >=net-nds/openldap-2.0.7 )
+	nls? ( >=sys-devel/gettext-0.18 )
+	nntp? ( >=net-libs/libetpan-0.57 )
+	notification? (
+		dev-libs/glib:2
+		libcanberra? (  media-libs/libcanberra[gtk] )
+		libindicate? ( dev-libs/libindicate:3[gtk] )
+		libnotify? ( x11-libs/libnotify )
+	)
+	pda? ( >=app-pda/jpilot-0.99 )
+	pdf? ( app-text/poppler[cairo] )
+	pgp? ( >=app-crypt/gpgme-1.0.0 )
+	session? (
+		x11-libs/libICE
+		x11-libs/libSM
+	)
+	smime? ( >=app-crypt/gpgme-1.0.0 )
+	spam-report? ( >=net-misc/curl-7.9.7 )
+	spell? ( >=app-text/enchant-1.0.0 )
+	startup-notification? ( x11-libs/startup-notification )
+	svg? ( >=gnome-base/librsvg-2.40.5 )
+	valgrind? ( dev-util/valgrind )
+"
+
+DEPEND="${COMMONDEPEND}
+	app-arch/xz-utils
+	virtual/pkgconfig
+	xface? ( >=media-libs/compface-1.4 )"
+
+RDEPEND="${COMMONDEPEND}
+	app-misc/mime-types
+	x11-misc/shared-mime-info
+	clamav? ( app-antivirus/clamav )
+	networkmanager? ( net-misc/networkmanager )
+	pdf? ( app-text/ghostscript-gpl )
+	perl? ( dev-lang/perl:= )
+	python? (
+		${PYTHON_DEPS}
+		>=dev-python/pygtk-2.10.3
+	)
+	rss? (
+		dev-libs/libxml2
+		net-misc/curl
+	)"
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	# Don't use libsoup-gnome (bug #565924)
+	export HAVE_LIBSOUP_GNOME=no
+
+	local myeconfargs=(
+		--disable-bsfilter-plugin
+		--disable-fancy-plugin
+		--disable-generic-umpc
+		--enable-acpi_notifier-plugin
+		--enable-address_keeper-plugin
+		--enable-alternate-addressbook
+		--enable-att_remover-plugin
+		--enable-attachwarner-plugin
+		--enable-fetchinfo-plugin
+		--enable-mailmbox-plugin
+		--enable-newmail-plugin
+		--enable-tnef_parse-plugin
+		--with-password-encryption=$(usex gnutls gnutls old)
+		$(use_enable archive archive-plugin)
+		$(use_enable bogofilter bogofilter-plugin)
+		$(use_enable calendar vcalendar-plugin)
+		$(use_enable clamav clamd-plugin)
+		$(use_enable dbus)
+		$(use_enable debug crash-dialog)
+		$(use_enable doc manual)
+		$(use_enable gdata gdata-plugin)
+		$(use_enable gnutls)
+		$(use_enable gtk3)
+		$(use_enable ipv6)
+		$(use_enable ldap)
+		$(use_enable networkmanager)
+		$(use_enable nls)
+		$(use_enable notification notification-plugin)
+		$(use_enable pda jpilot)
+		$(use_enable pdf pdf_viewer-plugin)
+		$(use_enable perl perl-plugin)
+		$(use_enable pgp pgpcore-plugin)
+		$(use_enable pgp pgpinline-plugin)
+		$(use_enable pgp pgpmime-plugin)
+		$(use_enable python python-plugin)
+		$(use_enable rss rssyl-plugin)
+		$(use_enable session libsm)
+		$(use_enable sieve managesieve-plugin)
+		$(use_enable smime smime-plugin)
+		$(use_enable spam-report spam_report-plugin)
+		$(use_enable spamassassin spamassassin-plugin)
+		$(use_enable spell enchant)
+		$(use_enable startup-notification)
+		$(use_enable svg)
+		$(use_enable valgrind valgrind)
+		$(use_enable xface compface)
+	)
+
+	# libetpan is needed if user wants nntp or imap functionality
+	if use imap || use nntp; then
+		myeconfargs+=( --enable-libetpan )
+	else
+		myeconfargs+=( --disable-libetpan )
+	fi
+
+	ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	local DOCS=( AUTHORS ChangeLog* INSTALL* NEWS README* TODO* )
+	default
+
+	# Makefile install claws-mail.png in /usr/share/icons/hicolor/48x48/apps
+	# => also install it in /usr/share/pixmaps for other desktop envs
+	# => also install higher resolution icons in /usr/share/icons/hicolor/...
+	insinto /usr/share/pixmaps
+	doins ${PN}.png
+	local size
+	for size in 64 128 ; do
+		newicon -s ${size} ${PN}-${size}x${size}.png ${PN}.png
+	done
+
+	docinto tools
+	dodoc tools/README*
+
+	domenu ${PN}.desktop
+
+	einfo "Installing extra tools"
+	cd "${S}"/tools
+	exeinto /usr/$(get_libdir)/${PN}/tools
+	doexe *.pl *.py *.conf *.sh
+	doexe tb2claws-mail update-po uudec uuooffice
+
+	# kill useless files
+	rm -f "${D}"/usr/lib*/claws-mail/plugins/*.{a,la}
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	ewarn "When upgrading from version 3.9.0 or below some changes have happened:"
+	ewarn "- There are no individual plugins in mail-client/claws-mail-* anymore, but they are integrated mostly controlled through USE flags"
+	ewarn "- Plugins with no special dependencies are just built and can be loaded through the interface"
+	ewarn "- The gtkhtml2, dillo and trayicon plugins have been dropped entirely"
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+}