* [gentoo-commits] repo/gentoo:master commit in: x11-wm/matwm2/
@ 2017-03-26 18:02 Michael Orlitzky
0 siblings, 0 replies; 4+ messages in thread
From: Michael Orlitzky @ 2017-03-26 18:02 UTC (permalink / raw
To: gentoo-commits
commit: eb47d9ba8395609fb929f326d1bea5e9d1db2d7a
Author: Michael Orlitzky <mjo <AT> gentoo <DOT> org>
AuthorDate: Sun Mar 26 18:02:26 2017 +0000
Commit: Michael Orlitzky <mjo <AT> gentoo <DOT> org>
CommitDate: Sun Mar 26 18:02:26 2017 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=eb47d9ba
x11-wm/matwm2: remove unused version 0.1.1.
Package-Manager: Portage-2.3.3, Repoman-2.3.1
x11-wm/matwm2/Manifest | 1 -
x11-wm/matwm2/matwm2-0.1.1.ebuild | 55 ---------------------------------------
2 files changed, 56 deletions(-)
diff --git a/x11-wm/matwm2/Manifest b/x11-wm/matwm2/Manifest
index a0f6182f7cb..c18a041cd20 100644
--- a/x11-wm/matwm2/Manifest
+++ b/x11-wm/matwm2/Manifest
@@ -1,2 +1 @@
-DIST matwm2-0.1.1.tar.gz 64552 SHA256 b85de9adc2118a7305a9015b57183117a4dbebf52b1ae4ac688e8f276319beb7 SHA512 27968759e2c58272a9594a5af738161f6b963cea8ef110cf18b4519725ad3d0402776bf715ac16cc5d98ca6498a18085d953c8c5eea23d889f003e963c97787a WHIRLPOOL 78ff6252f205d0e8cddea459d7368934a6a7d820ce90575b6acea3ea8c25e402dbe6fe6e5af92c9ce45faa2d09f527dbf5dff97d6a5d6c955ccb7c59bad931c8
DIST matwm2-0.1.2_pre3.tar.gz 860231 SHA256 c6fc2b4cbe278e5b85035a9019d27e3ad964cab3b5862c442652679ab85523d0 SHA512 30c55c6090015432bf99853f136baebb5b4c1301d5f922dc933e0141caf18d6891a982bd89e22e065c146c0c5c570d0e8aebb7e4c708dddde9b0570b7ed5f9ba WHIRLPOOL 05b651783232ca46f03c5cd018379770749b2ff93d87cd24f297f3ce55677917c1f6980e2e5be8d8e53ff1e6020f07d4bacafdbc7189a9de9133b8147048f78c
diff --git a/x11-wm/matwm2/matwm2-0.1.1.ebuild b/x11-wm/matwm2/matwm2-0.1.1.ebuild
deleted file mode 100644
index 60322a6fe4a..00000000000
--- a/x11-wm/matwm2/matwm2-0.1.1.ebuild
+++ /dev/null
@@ -1,55 +0,0 @@
-# Copyright 1999-2012 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=4
-inherit toolchain-funcs
-
-DESCRIPTION="Simple EWMH compatible window manager with titlebars and frames"
-HOMEPAGE="http://squidjam.com/matwm/"
-SRC_URI="http://squidjam.com/matwm/pub/${P}.tar.gz"
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE="debug xft xinerama"
-
-RDEPEND="
- x11-libs/libXext
- x11-libs/libX11
- debug? ( x11-proto/xproto )
- xft? ( x11-libs/libXft )
- xinerama? ( x11-libs/libXinerama )
-"
-DEPEND="
- ${RDEPEND}
- virtual/pkgconfig
- x11-proto/xextproto
- xinerama? ( x11-proto/xineramaproto )
-"
-
-src_configure() {
- # configure is not autotools based
- # --disable-shape left out because the code is broken
- ./configure \
- $( use debug && echo --enable-debug ) \
- $( use xft || echo --disable-xft ) \
- $( use xinerama || echo --disable-xinerama ) \
- || die
-}
-
-src_compile() {
- emake CC="$(tc-getCC)"
-}
-
-src_install() {
- dobin ${PN}
- doman ${PN}.1
- dodoc BUGS ChangeLog default_matwmrc README TODO
-
- insinto /usr/share/xsessions
- doins "${FILESDIR}"/${PN}.desktop
-
- echo ${PN} > "${T}"/${PN}
- exeinto /etc/X11/Sessions
- doexe "${T}"/${PN}
-}
^ permalink raw reply related [flat|nested] 4+ messages in thread* [gentoo-commits] repo/gentoo:master commit in: x11-wm/matwm2/
@ 2018-04-28 1:16 Matt Turner
0 siblings, 0 replies; 4+ messages in thread
From: Matt Turner @ 2018-04-28 1:16 UTC (permalink / raw
To: gentoo-commits
commit: ad0f12a8f148257b799f45a7e16a4f98602ca94e
Author: Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Sat Apr 28 01:14:28 2018 +0000
Commit: Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Sat Apr 28 01:14:28 2018 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ad0f12a8
x11-wm/matwm2: Drop unnecessary x11-proto dep
.../matwm2/{matwm2-0.1.2_pre3.ebuild => matwm2-0.1.2_pre3-r1.ebuild} | 3 ---
1 file changed, 3 deletions(-)
diff --git a/x11-wm/matwm2/matwm2-0.1.2_pre3.ebuild b/x11-wm/matwm2/matwm2-0.1.2_pre3-r1.ebuild
similarity index 93%
rename from x11-wm/matwm2/matwm2-0.1.2_pre3.ebuild
rename to x11-wm/matwm2/matwm2-0.1.2_pre3-r1.ebuild
index 0f564a80660..c6e017074c9 100644
--- a/x11-wm/matwm2/matwm2-0.1.2_pre3.ebuild
+++ b/x11-wm/matwm2/matwm2-0.1.2_pre3-r1.ebuild
@@ -19,15 +19,12 @@ S="${WORKDIR}/${PN}-${MY_PV}/${PN}"
RDEPEND="
x11-libs/libXext
x11-libs/libX11
- debug? ( x11-proto/xproto )
xft? ( x11-libs/libXft )
xinerama? ( x11-libs/libXinerama )
"
DEPEND="
${RDEPEND}
virtual/pkgconfig
- x11-proto/xextproto
- xinerama? ( x11-proto/xineramaproto )
"
PATCHES=( "${FILESDIR}/${P}-destdir-fix.patch" )
^ permalink raw reply related [flat|nested] 4+ messages in thread* [gentoo-commits] repo/gentoo:master commit in: x11-wm/matwm2/
@ 2022-06-29 9:07 David Seifert
0 siblings, 0 replies; 4+ messages in thread
From: David Seifert @ 2022-06-29 9:07 UTC (permalink / raw
To: gentoo-commits
commit: f1a9b2784876f4e62ac2f79f00f44821921d2dcd
Author: David Seifert <soap <AT> gentoo <DOT> org>
AuthorDate: Wed Jun 29 09:07:12 2022 +0000
Commit: David Seifert <soap <AT> gentoo <DOT> org>
CommitDate: Wed Jun 29 09:07:12 2022 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f1a9b278
x11-wm/matwm2: update EAPI 6 -> 8
Signed-off-by: David Seifert <soap <AT> gentoo.org>
..._pre3-r1.ebuild => matwm2-0.1.2_pre3-r2.ebuild} | 35 +++++++++++-----------
1 file changed, 17 insertions(+), 18 deletions(-)
diff --git a/x11-wm/matwm2/matwm2-0.1.2_pre3-r1.ebuild b/x11-wm/matwm2/matwm2-0.1.2_pre3-r2.ebuild
similarity index 65%
rename from x11-wm/matwm2/matwm2-0.1.2_pre3-r1.ebuild
rename to x11-wm/matwm2/matwm2-0.1.2_pre3-r2.ebuild
index c6e017074c9d..468d8e602220 100644
--- a/x11-wm/matwm2/matwm2-0.1.2_pre3-r1.ebuild
+++ b/x11-wm/matwm2/matwm2-0.1.2_pre3-r2.ebuild
@@ -1,33 +1,31 @@
-# Copyright 1999-2017 Gentoo Foundation
+# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
-EAPI=6
-inherit toolchain-funcs
+EAPI=8
+
+inherit edo toolchain-funcs
MY_PV="${PV//_/}"
DESCRIPTION="Simple EWMH compatible window manager with titlebars and frames"
HOMEPAGE="https://github.com/segin/matwm2"
SRC_URI="https://github.com/segin/${PN}/archive/${MY_PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${PN}-${MY_PV}/${PN}"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug xft xinerama"
-S="${WORKDIR}/${PN}-${MY_PV}/${PN}"
RDEPEND="
x11-libs/libXext
x11-libs/libX11
xft? ( x11-libs/libXft )
- xinerama? ( x11-libs/libXinerama )
-"
-DEPEND="
- ${RDEPEND}
- virtual/pkgconfig
-"
+ xinerama? ( x11-libs/libXinerama )"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
-PATCHES=( "${FILESDIR}/${P}-destdir-fix.patch" )
+PATCHES=( "${FILESDIR}"/${P}-destdir-fix.patch )
src_prepare() {
default
@@ -42,24 +40,25 @@ src_configure() {
--prefix="${EPREFIX}/usr"
--mandir="${EPREFIX}/usr/share/man"
--cc="$(tc-getCC)"
- $(usex debug "--enable-debug" "")
- $(usex xft "" "--disable-xft")
- $(usex xinerama "" "--disable-xinerama")
+ $(usev debug --enable-debug)
+ $(usev !xft --disable-xft)
+ $(usev !xinerama --disable-xinerama)
)
- ./configure "${myconfigureargs[@]}" || die
+ edo ./configure "${myconfigureargs[@]}"
}
src_install() {
default
- docompress -x "${EPREFIX}/usr/share/doc/${PF}"/default_matwmrc
+ docompress -x /usr/share/doc/${PF}/default_matwmrc
dodoc default_matwmrc
insinto /usr/share/xsessions
doins "${FILESDIR}"/${PN}.desktop
- echo ${PN} > "${T}"/${PN} || die
exeinto /etc/X11/Sessions
- doexe "${T}"/${PN}
+ newexe - matwm2 <<- _EOF_
+ matwm2
+ _EOF_
}
^ permalink raw reply related [flat|nested] 4+ messages in thread* [gentoo-commits] repo/gentoo:master commit in: x11-wm/matwm2/
@ 2023-08-05 22:29 Sam James
0 siblings, 0 replies; 4+ messages in thread
From: Sam James @ 2023-08-05 22:29 UTC (permalink / raw
To: gentoo-commits
commit: d81dc9697b969a8ae9f0dd1ff0f77a1584795eb0
Author: Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Sat Aug 5 22:27:10 2023 +0000
Commit: Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sat Aug 5 22:28:31 2023 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d81dc969
x11-wm/matwm2: fix shebang in /etc/X11/Sessions file
A file in /etc/X11/Sessions with just the path that's *not* executable is fine,
but if it's executable, it's reasonably treated as a script. Oops.
Bug: https://bugs.gentoo.org/911787
Signed-off-by: Sam James <sam <AT> gentoo.org>
x11-wm/matwm2/matwm2-0.1.2_pre3-r3.ebuild | 65 +++++++++++++++++++++++++++++++
1 file changed, 65 insertions(+)
diff --git a/x11-wm/matwm2/matwm2-0.1.2_pre3-r3.ebuild b/x11-wm/matwm2/matwm2-0.1.2_pre3-r3.ebuild
new file mode 100644
index 000000000000..2ed16e0d950a
--- /dev/null
+++ b/x11-wm/matwm2/matwm2-0.1.2_pre3-r3.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit edo toolchain-funcs
+
+MY_PV="${PV//_/}"
+
+DESCRIPTION="Simple EWMH compatible window manager with titlebars and frames"
+HOMEPAGE="https://github.com/segin/matwm2"
+SRC_URI="https://github.com/segin/${PN}/archive/${MY_PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${PN}-${MY_PV}/${PN}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="debug xft xinerama"
+
+RDEPEND="
+ x11-libs/libXext
+ x11-libs/libX11
+ xft? ( x11-libs/libXft )
+ xinerama? ( x11-libs/libXinerama )"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+PATCHES=( "${FILESDIR}"/${P}-destdir-fix.patch )
+
+src_prepare() {
+ default
+
+ # Let the package manager handle stripping
+ sed -e 's/install -s/install/g' -i Makefile.in || die
+}
+
+src_configure() {
+ # configure is not autotools based
+ local myconfigureargs=(
+ --prefix="${EPREFIX}/usr"
+ --mandir="${EPREFIX}/usr/share/man"
+ --cc="$(tc-getCC)"
+ $(usev debug --enable-debug)
+ $(usev !xft --disable-xft)
+ $(usev !xinerama --disable-xinerama)
+ )
+
+ edo ./configure "${myconfigureargs[@]}"
+}
+
+src_install() {
+ default
+
+ docompress -x /usr/share/doc/${PF}/default_matwmrc
+ dodoc default_matwmrc
+
+ insinto /usr/share/xsessions
+ doins "${FILESDIR}"/${PN}.desktop
+
+ exeinto /etc/X11/Sessions
+ newexe - ${PN} <<-EOF
+ #!/bin/sh
+ ${PN}
+ EOF
+}
^ permalink raw reply related [flat|nested] 4+ messages in thread
end of thread, other threads:[~2023-08-05 22:29 UTC | newest]
Thread overview: 4+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2017-03-26 18:02 [gentoo-commits] repo/gentoo:master commit in: x11-wm/matwm2/ Michael Orlitzky
-- strict thread matches above, loose matches on Subject: below --
2018-04-28 1:16 Matt Turner
2022-06-29 9:07 David Seifert
2023-08-05 22:29 Sam James
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox