From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-940755-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
(No client certificate requested)
by finch.gentoo.org (Postfix) with ESMTPS id EBDC4139694
for <garchives@archives.gentoo.org>; Sat, 25 Mar 2017 08:56:27 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id DFA9121C012;
Sat, 25 Mar 2017 08:56:25 +0000 (UTC)
Received: from smtp.gentoo.org (smtp.gentoo.org [140.211.166.183])
(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id AA5E321C012
for <gentoo-commits@lists.gentoo.org>; Sat, 25 Mar 2017 08:56:25 +0000 (UTC)
Received: from oystercatcher.gentoo.org (oystercatcher.gentoo.org [148.251.78.52])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id A953034108B
for <gentoo-commits@lists.gentoo.org>; Sat, 25 Mar 2017 08:56:24 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id 121E371B2
for <gentoo-commits@lists.gentoo.org>; Sat, 25 Mar 2017 08:56:23 +0000 (UTC)
From: "Amadeusz Piotr Żołnowski" <aidecoe@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Amadeusz Piotr Żołnowski" <aidecoe@gentoo.org>
Message-ID: <1490432178.d92250de2dd9a3200954370f653aaf1a3582837f.aidecoe@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: net-mail/notmuch/
X-VCS-Repository: repo/gentoo
X-VCS-Files: net-mail/notmuch/Manifest net-mail/notmuch/notmuch-0.24.ebuild
X-VCS-Directories: net-mail/notmuch/
X-VCS-Committer: aidecoe
X-VCS-Committer-Name: Amadeusz Piotr Żołnowski
X-VCS-Revision: d92250de2dd9a3200954370f653aaf1a3582837f
X-VCS-Branch: master
Date: Sat, 25 Mar 2017 08:56:23 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Archives-Salt: efd9596d-5a4d-4a7e-9489-434ad43f0ff2
X-Archives-Hash: c3b46a651c67f9176dc253c6219efb60
commit: d92250de2dd9a3200954370f653aaf1a3582837f
Author: Amadeusz Żołnowski <aidecoe <AT> gentoo <DOT> org>
AuthorDate: Sat Mar 25 08:51:35 2017 +0000
Commit: Amadeusz Piotr Żołnowski <aidecoe <AT> gentoo <DOT> org>
CommitDate: Sat Mar 25 08:56:18 2017 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d92250de
net-mail/notmuch: Bump version to 0.24
Package-Manager: Portage-2.3.4, Repoman-2.3.2
net-mail/notmuch/Manifest | 1 +
net-mail/notmuch/notmuch-0.24.ebuild | 200 +++++++++++++++++++++++++++++++++++
2 files changed, 201 insertions(+)
diff --git a/net-mail/notmuch/Manifest b/net-mail/notmuch/Manifest
index b521731e46c..cbf1d665bb9 100644
--- a/net-mail/notmuch/Manifest
+++ b/net-mail/notmuch/Manifest
@@ -4,3 +4,4 @@ DIST notmuch-0.22.2.tar.gz 683796 SHA256 6cd19c61634079981b2d8f4b7cb4eb953cba2a3
DIST notmuch-0.23.3.tar.gz 691361 SHA256 0f5da5cf0203b774e345c50d56e975a87c2fc5407ef4ea284b6e2b55a8951882 SHA512 232a4133d70d074e6d38b00471145ecec342a5e138822cce01b6915e2b3de29fc1181e116d1df30e2fea04d519f53297fd8ea0e9d0df91bc8d6fce549feed1e3 WHIRLPOOL 82c30f3137132504ed41c42619c3645b74680d01a835e6074122b6ff3ab8d1a5dfe138a583872d09ea9f70a7312021fafa1bd2c08c3b6b9a319f55e5c81f28ff
DIST notmuch-0.23.5.tar.gz 691921 SHA256 c62694b3c5f04db48ed3bbf37a801ea2a03439826c6be318e23b34de749ac267 SHA512 703b685737c779008484a1a5064a0a6b4c93d0c20c48a9c417e0a471b8807f5ee3151a67f0161eb6b376dce56ab42a285dd80532ec9ff79451e982a7c0f25fa1 WHIRLPOOL 687fa8939970124b21cb0725681f2a98c326ee803bf38f0d38d8d8ec1f0e40e99f7be1f72c3bdb721deb4ccc2fecb32bef2067a5baa7b0572a9de2c7d80c51aa
DIST notmuch-0.23.7.tar.gz 692230 SHA256 f11bb10d71945f6c3f16d23117afc70810aa485878e66bb4bf43cc3f08038913 SHA512 e71da3bd6ce1b344aae79b277b695a4668d4fe1b8838618d6970a0b27df9867bac66a3240473ef31fc30ed8af2b0a558203ed5ffb34da873c991b1ecc6c08522 WHIRLPOOL 0b14cd6fb2b584b27b7893bb9c45724725069a6bc980cfe52f80ec3f6ec95c3a8f631975875f44b46b2799d5a0c31a62ff845b2400b7389cd8aa6f55361a0851
+DIST notmuch-0.24.tar.gz 708243 SHA256 f7e44cf67630669d3537c4febd7685ca27d62a134e42f9a5db90d5a6ed4c75fc SHA512 f966b4faf96b165cc04be15a90681fabfe7ce66a0a9255183f9e4542556836adb7acfe8c02033db3ad8af6cb8962d1a64da8cdd03a0485b104a7b40b88b598d5 WHIRLPOOL a64643461bb3f4e97459b76c43700cce5f69d4e9df99c9eadd424f9d8e1fe2f3b8d33cfd19cb2945050bc5018d2a2dabe484723d68fb247084e729f0b778908b
diff --git a/net-mail/notmuch/notmuch-0.24.ebuild b/net-mail/notmuch/notmuch-0.24.ebuild
new file mode 100644
index 00000000000..a9dc94ccfb9
--- /dev/null
+++ b/net-mail/notmuch/notmuch-0.24.ebuild
@@ -0,0 +1,200 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+DISTUTILS_OPTIONAL=1
+PYTHON_COMPAT=( python{2_7,3_4} )
+
+inherit bash-completion-r1 elisp-common eutils flag-o-matic pax-utils \
+ distutils-r1 toolchain-funcs
+
+DESCRIPTION="Thread-based e-mail indexer, supporting quick search and tagging"
+HOMEPAGE="http://notmuchmail.org/"
+SRC_URI="${HOMEPAGE%/}/releases/${P}.tar.gz
+ test? ( ${HOMEPAGE%/}/releases/test-databases/database-v1.tar.xz )"
+
+LICENSE="GPL-3"
+# Sub-slot corresponds to major wersion of libnotmuch.so.X.Y. Bump of Y is
+# meant to be binary backward compatible.
+SLOT="0/4"
+KEYWORDS="~alpha ~amd64 ~x86"
+REQUIRED_USE="
+ nmbug? ( python )
+ python? ( ${PYTHON_REQUIRED_USE} )
+ test? ( crypt emacs python valgrind )
+ "
+IUSE="crypt doc emacs mutt nmbug python test valgrind"
+
+CDEPEND="
+ >=app-shells/bash-completion-1.9
+ >=dev-libs/glib-2.22:2
+ >=dev-libs/gmime-2.6.20-r2:2.6
+ >=dev-libs/xapian-1.2.7-r2:=
+ dev-python/sphinx[${PYTHON_USEDEP}]
+ >=sys-libs/zlib-1.2.5.2
+ sys-libs/talloc
+ crypt? ( >=dev-libs/gmime-2.6.20-r2:2.6[smime] )
+ emacs? ( >=virtual/emacs-23 )
+ python? ( ${PYTHON_DEPS} )
+ "
+DEPEND="${CDEPEND}
+ virtual/pkgconfig
+ doc? ( app-doc/doxygen )
+ test? ( app-misc/dtach || ( >=app-editors/emacs-23[libxml2]
+ >=app-editors/emacs-vcs-23[libxml2] ) sys-devel/gdb
+ crypt? ( app-crypt/gnupg dev-libs/openssl ) )
+ valgrind? ( dev-util/valgrind )
+ "
+RDEPEND="${CDEPEND}
+ crypt? ( app-crypt/gnupg )
+ nmbug? ( dev-vcs/git )
+ mutt? ( dev-perl/File-Which dev-perl/Mail-Box dev-perl/MailTools
+ dev-perl/String-ShellQuote dev-perl/Term-ReadLine-Gnu
+ virtual/perl-Digest-SHA virtual/perl-File-Path virtual/perl-Getopt-Long
+ virtual/perl-Pod-Parser )
+ "
+
+DOCS=( AUTHORS NEWS README )
+SITEFILE="50${PN}-gentoo.el"
+MY_LD_LIBRARY_PATH="${WORKDIR}/${P}/lib"
+
+bindings() {
+ local ret=0
+
+ if use $1; then
+ pushd bindings/$1 || die
+ shift
+ "$@"
+ ret=$?
+ popd || die
+ fi
+
+ return $ret
+}
+
+pkg_pretend() {
+ if has_version '<net-mail/notmuch-0.18'; then
+ ewarn
+ ewarn "There are few not backward compatible changes between"
+ ewarn "<notmuch-0.18 and >=notmuch-0.18. See NEWS file"
+ ewarn "(0.18 section) for details before first use!"
+ ewarn
+ fi
+}
+
+pkg_setup() {
+ if use emacs; then
+ elisp-need-emacs 23 || die "Emacs version too low"
+ fi
+}
+
+src_unpack() {
+ unpack "${P}".tar.gz
+ if use test; then
+ mkdir -p "${S}"/test/test-databases || die
+ cp "${DISTDIR}"/database-v1.tar.xz "${S}"/test/test-databases/ || die
+ fi
+}
+
+src_prepare() {
+ default
+
+ bindings python distutils-r1_src_prepare
+ bindings python mv README README-python || die
+ mv contrib/notmuch-mutt/README contrib/notmuch-mutt/README-mutt || die
+
+ # assure that new Makefile.config will be generated
+ rm -f Makefile.config || die
+
+ if use test; then
+ append-cflags -g
+ append-cxxflags -g
+ fi
+}
+
+src_configure() {
+ local myeconfargs=(
+ --bashcompletiondir="$(get_bashcompdir)"
+ --emacslispdir="${EPREFIX}/${SITELISP}/${PN}"
+ --emacsetcdir="${EPREFIX}/${SITEETC}/${PN}"
+ --without-ruby
+ --zshcompletiondir="${EPREFIX}/usr/share/zsh/site-functions"
+ $(use_with emacs)
+ $(use_with doc api-docs)
+ )
+ tc-export CC CXX
+ econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+ V=1 default
+ bindings python distutils-r1_src_compile
+
+ if use mutt; then
+ pushd contrib/notmuch-mutt || die
+ emake notmuch-mutt.1
+ popd || die
+ fi
+
+ if use doc; then
+ pydocs() {
+ pushd docs || die
+ emake html
+ rm -r html/_sources || die
+ rm html/{objects.inv,.buildinfo} || die
+ mkdir -p ../html && mv html ../html/python || die
+ popd || die
+ }
+ LD_LIBRARY_PATH="${MY_LD_LIBRARY_PATH}" bindings python pydocs
+ fi
+}
+
+src_test() {
+ pax-mark -m notmuch
+ LD_LIBRARY_PATH="${MY_LD_LIBRARY_PATH}" V=1 default
+ pax-mark -ze notmuch
+}
+
+src_install() {
+ default
+
+ if use emacs; then
+ elisp-site-file-install "${FILESDIR}/${SITEFILE}" || die
+ fi
+
+ if use nmbug; then
+ dobin devel/nmbug/nmbug
+ dobin devel/nmbug/notmuch-report
+ fi
+
+ if use mutt; then
+ pushd contrib/notmuch-mutt || die
+ dobin notmuch-mutt
+ doman notmuch-mutt.1
+ insinto /etc/mutt
+ doins notmuch-mutt.rc
+ dodoc README-mutt
+ popd || die
+ fi
+
+ DOCS="" bindings python distutils-r1_src_install
+ use doc && bindings python dodoc -r html
+}
+
+pkg_preinst() {
+ if use mutt && ! [[ -e ${ROOT}/etc/mutt/notmuch-mutt.rc ]]; then
+ elog "To enable notmuch support in mutt, add the following line into"
+ elog "your mutt config file, please:"
+ elog ""
+ elog " source /etc/mutt/notmuch-mutt.rc"
+ fi
+}
+
+pkg_postinst() {
+ use emacs && elisp-site-regen
+}
+
+pkg_postrm() {
+ use emacs && elisp-site-regen
+}