[gentoo-commits] repo/gentoo:master commit in: media-tv/kodi/

["David Seifert" <soap@gentoo.org>]

commit:     c7a30e26d52d66320cefe746710add211cb3b729
Author:     Craig Andrews <candrews <AT> integralblue <DOT> com>
AuthorDate: Fri Mar 24 14:31:38 2017 +0000
Commit:     David Seifert <soap <AT> gentoo <DOT> org>
CommitDate: Fri Mar 24 16:51:08 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c7a30e26

media-tv/kodi: Remove old version 17.1_rc1

Package-Manager: Portage-2.3.5, Repoman-2.3.2
Closes: https://github.com/gentoo/gentoo/pull/4262

 media-tv/kodi/Manifest             |   2 -
 media-tv/kodi/kodi-17.1_rc1.ebuild | 275 -------------------------------------
 2 files changed, 277 deletions(-)

diff --git a/media-tv/kodi/Manifest b/media-tv/kodi/Manifest
index 65dd2f0881e..a8ee9f26333 100644
--- a/media-tv/kodi/Manifest
+++ b/media-tv/kodi/Manifest
@@ -6,8 +6,6 @@ DIST kodi-17.0-generated-addons.tar.xz 57552 SHA256 89f7b681e920cec5974ec133e7c8
 DIST kodi-17.0.tar.gz 58449501 SHA256 4bfffa2493973ae15ab1d922632c09a2583908d6140bc4f58ec8f9314e4f6545 SHA512 ca0d812bcbcc58b74542872365244c5b937803c5618d2277e85a8cb805820ddb22886233d1417fa0e7532c9909749e632e276f8da51d86e1f5f060b2d1ad6a12 WHIRLPOOL f26cc7908c0618904586e255244c7f42814a52d65399a7bb16ba42f4c5079bb82176eb8035af9bf5c56469249dd4af53c161899d276f44634946333440313c53
 DIST kodi-17.1-generated-addons.tar.xz 57560 SHA256 a92a8222444a123e4876e835238ce5ddf9cfed967c07b7af17cfdd82421196ac SHA512 b3d313aceecad16c0dcf1cddeee459155b94aad4137cb74b405c0634b85f8a6819f90d3d9dad9d528ad4a39909ca7eb5ae73ed4c40c13aaa573494be2b990cd8 WHIRLPOOL b1193338224408f948175ad7ee100c9d27c45e8e07dc72adcb846e4ee2ea1febe6f605af4bfb22649dcfed95e4b16385276dbf8870f7da0f9c9886dc9ba5136d
 DIST kodi-17.1.tar.gz 58457875 SHA256 303f3903cbb57ccc2961f09cf3746505542bcb129a464f0687d7ca8601cebbee SHA512 5093fe7dcdf22e2604ea93696c909028c00a8b0c858e7b25f55dade6c3423b4a68f5a49a8a0dd5238b10f4a7dd5e815a82251949ce7adb8a8f8cf5d58fc7bd41 WHIRLPOOL a2f3ce757383b1e3ac40c91574a873cf23c3f10e944e5d74228a0bec287f919bcd0b1251d89c6dd33eea847a34a4149e26e8d464169538601ff9be0f817539c6
-DIST kodi-17.1rc1-generated-addons.tar.xz 57524 SHA256 401e9b133671e152d483db73b7de20dde862c2dd343948f0473566959fdcad46 SHA512 a54e19d3cde433331f17c6d4590c3ca1cdacd685bef286be48c99213c04f3d788c68023e3ee22fb6d2014ee2d215c11f43790c0818da6fbcd8b77dfb9fd9869b WHIRLPOOL 0590e3cc7d4a8f484ad9032d961d4606db6fe98275df504d7f961b8a5403382e6d8f3a53e15b4d6a1145098c9ef027b2cd91063ece06a4d35159e42c2e8fcd85
-DIST kodi-17.1rc1.tar.gz 58455944 SHA256 a614128c065d561fccd4167f25eddbad3875328f1e81f627ffe3d0b17958aa07 SHA512 80a8acb56210c466b44ac9d1420cb3e4395eaa0bed1a164f2600e73bc2bca97e73dbe90f6dd2c81619af81a565c466e9d83f3f9649c4acf45381b13dd758e002 WHIRLPOOL 5ca2c3b18be4a5eaacc458d6aedb5803ab712882221012a9e6c8ca79e2f9fa07fdf3cd4ad663ab8ddba4441f9cf53e4e56a5c51b155e4d1684abc66296c2d2bb
 DIST libdvdcss-2f12236bc1c92f73c21e973363f79eb300de603f.tar.gz 95395 SHA256 b6eb2d929ff56cb051152c32010afc5e7cf5fe8c5ae32dca412a2b46b6b57e34 SHA512 12ba7aa653fcb26d5336bf2a8110c924d634cec79f684bbf19dc38ea33f69fb68c22c97f4c09e5ca7c35f95f6c324a6d70ccc2c501a99122a9321cafd33b2cd9 WHIRLPOOL 8570ad8d2b6e629cc1c7e544be2853cab3bb50fd73438cea47c7a0919b251cecf906f7446ef3714c54ee3e636278dc0dabab47f772440624ff49877068b7b50a
 DIST libdvdnav-43b5f81f5fe30bceae3b7cecf2b0ca57fc930dac.tar.gz 130603 SHA256 8e3f0563e16df898fe115e1723e3f78dbc953f6e9cf4f04568add215371d9ed2 SHA512 901c6f24afa1d78b6ed78d1ee30daf634ca0bbc0467ef9cc3416bcab4fbc4fda6869ffa051791d85c0b510de748805328627681ef044668a7857299f0035232e WHIRLPOOL 588d060f418f18ef193061ff88260ac7929647b2babde5b78ab73141ffc7f3782ce1254bfee1234ec0da8bb28bc16ede301b4ec1e2d3073b9c6d22cb526f06ca
 DIST libdvdread-17d99db97e7b8f23077b342369d3c22a6250affd.tar.gz 124326 SHA256 e7179b2054163652596a56301c9f025515cb08c6d6310b42b897c3ad11c0199b SHA512 e59ae0bfdc62698e407e3d70503c6a7c5e308545c9dae7843e25db3b5b62d9b26256be77ef4e884263add6b4abec3438c324bfd5715f6ca2ce7fa5962d43a6c2 WHIRLPOOL b42130027d201e545fabc27677bd4238d04bcbc5a0e622ca6da396ac340ea94b5c60004557334464a31dac880603dab99e2f189e41d6cddbe9e32728c626085a

diff --git a/media-tv/kodi/kodi-17.1_rc1.ebuild b/media-tv/kodi/kodi-17.1_rc1.ebuild
deleted file mode 100644
index ba60df09df9..00000000000
--- a/media-tv/kodi/kodi-17.1_rc1.ebuild
+++ /dev/null
@@ -1,275 +0,0 @@
-# Copyright 1999-2017 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-
-# Does not work with py3 here
-PYTHON_COMPAT=( python2_7 )
-PYTHON_REQ_USE="sqlite"
-
-inherit eutils linux-info python-single-r1 cmake-utils autotools
-
-LIBDVDCSS_COMMIT="2f12236bc1c92f73c21e973363f79eb300de603f"
-LIBDVDREAD_COMMIT="17d99db97e7b8f23077b342369d3c22a6250affd"
-LIBDVDNAV_COMMIT="43b5f81f5fe30bceae3b7cecf2b0ca57fc930dac"
-CODENAME="Krypton"
-SRC_URI="https://github.com/xbmc/libdvdcss/archive/${LIBDVDCSS_COMMIT}.tar.gz -> libdvdcss-${LIBDVDCSS_COMMIT}.tar.gz
-	https://github.com/xbmc/libdvdread/archive/${LIBDVDREAD_COMMIT}.tar.gz -> libdvdread-${LIBDVDREAD_COMMIT}.tar.gz
-	https://github.com/xbmc/libdvdnav/archive/${LIBDVDNAV_COMMIT}.tar.gz -> libdvdnav-${LIBDVDNAV_COMMIT}.tar.gz"
-
-DESCRIPTION="Kodi is a free and open source media-player and entertainment hub"
-HOMEPAGE="https://kodi.tv/ http://kodi.wiki/"
-
-LICENSE="GPL-2"
-SLOT="0"
-# use flag is called libusb so that it doesn't fool people in thinking that
-# it is _required_ for USB support. Otherwise they'll disable udev and
-# that's going to be worse.
-IUSE="airplay alsa bluetooth bluray caps cec +css dbus debug dvd gles libressl libusb lirc mysql nfs nonfree +opengl +ssl pulseaudio samba sftp systemd test +udev udisks upnp upower vaapi vdpau webserver +X +xslt zeroconf"
-REQUIRED_USE="
-	${PYTHON_REQUIRED_USE}
-	|| ( gles opengl )
-	udev? ( !libusb )
-	udisks? ( dbus )
-	upower? ( dbus )
-"
-
-COMMON_DEPEND="${PYTHON_DEPS}
-	airplay? (
-		app-pda/libplist
-		net-libs/shairplay
-	)
-	alsa? ( media-libs/alsa-lib )
-	bluetooth? ( net-wireless/bluez )
-	bluray? ( >=media-libs/libbluray-0.7.0 )
-	caps? ( sys-libs/libcap )
-	dbus? ( sys-apps/dbus )
-	dev-db/sqlite
-	dev-libs/expat
-	dev-libs/fribidi
-	cec? ( >=dev-libs/libcec-4.0 )
-	dev-libs/libpcre[cxx]
-	dev-libs/libxml2
-	>=dev-libs/lzo-2.04
-	dev-libs/tinyxml[stl]
-	>=dev-libs/yajl-2
-	dev-python/pillow[${PYTHON_USEDEP}]
-	dev-libs/libcdio
-	gles? ( media-libs/mesa[gles2] )
-	libusb? ( virtual/libusb:1 )
-	media-fonts/corefonts
-	>=media-fonts/noto-20160531
-	media-fonts/roboto
-	media-libs/fontconfig
-	media-libs/freetype
-	>=media-libs/libass-0.13.4
-	media-libs/mesa[egl]
-	>=media-libs/taglib-1.11.1
-	>=media-video/ffmpeg-3.1.6:=[encode,postproc]
-	mysql? ( virtual/mysql )
-	>=net-misc/curl-7.51.0
-	nfs? ( net-fs/libnfs:= )
-	opengl? ( media-libs/glu )
-	ssl? (
-		!libressl? ( >=dev-libs/openssl-1.0.2j:0= )
-		libressl? ( dev-libs/libressl:0= )
-	)
-	pulseaudio? ( media-sound/pulseaudio )
-	samba? ( >=net-fs/samba-3.4.6[smbclient(+)] )
-	sftp? ( net-libs/libssh[sftp] )
-	sys-libs/zlib
-	udev? ( virtual/udev )
-	vaapi? ( x11-libs/libva[opengl] )
-	vdpau? (
-		|| ( >=x11-libs/libvdpau-1.1 >=x11-drivers/nvidia-drivers-180.51 )
-		media-video/ffmpeg[vdpau]
-	)
-	webserver? ( >=net-libs/libmicrohttpd-0.9.50[messages] )
-	X? (
-		x11-libs/libdrm
-		x11-libs/libX11
-		x11-libs/libXrandr
-		x11-libs/libXrender
-	)
-	xslt? ( dev-libs/libxslt )
-	zeroconf? ( net-dns/avahi[dbus] )
-"
-RDEPEND="${COMMON_DEPEND}
-	lirc? (
-		|| ( app-misc/lirc app-misc/inputlircd )
-	)
-	!media-tv/xbmc
-	udisks? ( sys-fs/udisks:0 )
-	upower? (
-		systemd? ( sys-power/upower )
-		!systemd? (
-			|| ( sys-power/upower-pm-utils sys-power/upower )
-		)
-	)
-"
-DEPEND="${COMMON_DEPEND}
-	app-arch/bzip2
-	app-arch/unzip
-	app-arch/xz-utils
-	app-arch/zip
-	dev-lang/swig
-	dev-libs/crossguid
-	dev-util/cmake
-	dev-util/gperf
-	media-libs/giflib
-	>=media-libs/libjpeg-turbo-1.5.1:=
-	>=media-libs/libpng-1.6.26:0=
-	test? ( dev-cpp/gtest )
-	virtual/pkgconfig
-	x86? ( dev-lang/nasm )
-"
-case ${PV} in
-9999)
-	EGIT_REPO_URI="git://github.com/xbmc/xbmc.git"
-	inherit git-r3
-	# Force java for latest git version to avoid having to hand maintain the
-	# generated addons package.  #488118
-	DEPEND+="
-		virtual/jre
-		"
-	;;
-*)
-	MY_PV=${PV/_p/_r}
-	MY_PV=${MY_PV/_alpha/a}
-	MY_PV=${MY_PV/_beta/b}
-	MY_PV=${MY_PV/_rc/rc}
-	MY_P="${PN}-${MY_PV}"
-	SRC_URI+=" https://github.com/xbmc/xbmc/archive/${MY_PV}-${CODENAME}.tar.gz -> ${MY_P}.tar.gz
-		 !java? ( https://github.com/candrews/gentoo-kodi/raw/master/${MY_P}-generated-addons.tar.xz )"
-	KEYWORDS="~amd64 ~x86"
-	IUSE+=" java"
-	DEPEND+="
-		java? ( virtual/jre )
-		"
-
-	S=${WORKDIR}/xbmc-${MY_PV}-${CODENAME}
-	;;
-esac
-
-CONFIG_CHECK="~IP_MULTICAST"
-ERROR_IP_MULTICAST="
-In some cases Kodi needs to access multicast addresses.
-Please consider enabling IP_MULTICAST under Networking options.
-"
-
-CMAKE_USE_DIR=${S}/project/cmake/
-
-pkg_setup() {
-	check_extra_config
-	python-single-r1_pkg_setup
-}
-
-src_prepare() {
-	if in_iuse java && use !java; then
-		eapply "${FILESDIR}"/${PN}-cmake-no-java.patch
-	fi
-	cmake-utils_src_prepare
-
-	# avoid long delays when powerkit isn't running #348580
-	sed -i \
-		-e '/dbus_connection_send_with_reply_and_block/s:-1:3000:' \
-		xbmc/linux/*.cpp || die
-
-	# Prepare tools and libs witch are configured with autotools during compile time
-	AUTOTOOLS_DIRS=(
-		"${S}"/lib/cpluff
-		"${S}"/tools/depends/native/TexturePacker/src
-		"${S}"/tools/depends/native/JsonSchemaBuilder/src
-	)
-
-	local d
-	for d in "${AUTOTOOLS_DIRS[@]}" ; do
-		pushd ${d} >/dev/null || die
-		AT_NOELIBTOOLIZE="yes" AT_TOPLEVEL_EAUTORECONF="yes" eautoreconf
-		popd >/dev/null || die
-	done
-	elibtoolize
-
-	# Prevent autoreconf rerun
-	sed -e 's/autoreconf -vif/echo "autoreconf already done in src_prepare()"/' -i \
-		"${S}"/project/cmake/modules/FindCpluff.cmake \
-		"${S}"/tools/depends/native/TexturePacker/src/autogen.sh \
-		"${S}"/tools/depends/native/JsonSchemaBuilder/src/autogen.sh
-}
-
-src_configure() {
-	local CMAKE_BUILD_TYPE=$(usex debug Debug RelWithDebInfo)
-
-	local mycmakeargs=(
-		-Ddocdir="${EPREFIX}/usr/share/doc/${PF}"
-		-DENABLE_LDGOLD=OFF # https://bugs.gentoo.org/show_bug.cgi?id=606124
-		-DENABLE_ALSA=$(usex alsa)
-		-DENABLE_AIRTUNES=$(usex airplay)
-		-DENABLE_AVAHI=$(usex zeroconf)
-		-DENABLE_BLUETOOTH=$(usex bluetooth)
-		-DENABLE_BLURAY=$(usex bluray)
-		-DENABLE_CCACHE=OFF
-		-DENABLE_CEC=$(usex cec)
-		-DENABLE_DBUS=$(usex dbus)
-		-DENABLE_DVDCSS=$(usex css)
-		-DENABLE_INTERNAL_CROSSGUID=OFF
-		-DENABLE_INTERNAL_FFMPEG=OFF
-		-DENABLE_CAP=$(usex caps)
-		-DENABLE_LIRC=$(usex lirc)
-		-DENABLE_MICROHTTPD=$(usex webserver)
-		-DENABLE_MYSQLCLIENT=$(usex mysql)
-		-DENABLE_NFS=$(usex nfs)
-		-DENABLE_NONFREE=$(usex nonfree)
-		-DENABLE_OPENGLES=$(usex gles)
-		-DENABLE_OPENGL=$(usex opengl)
-		-DENABLE_OPENSSL=$(usex ssl)
-		-DENABLE_OPTICAL=$(usex dvd)
-		-DENABLE_PLIST=$(usex airplay)
-		-DENABLE_PULSEAUDIO=$(usex pulseaudio)
-		-DENABLE_SMBCLIENT=$(usex samba)
-		-DENABLE_SSH=$(usex sftp)
-		-DENABLE_UDEV=$(usex udev)
-		-DENABLE_UPNP=$(usex upnp)
-		-DENABLE_VAAPI=$(usex vaapi)
-		-DENABLE_VDPAU=$(usex vdpau)
-		-DENABLE_X11=$(usex X)
-		-DENABLE_XSLT=$(usex xslt)
-		-Dlibdvdread_URL="${DISTDIR}/libdvdread-${LIBDVDREAD_COMMIT}.tar.gz"
-		-Dlibdvdnav_URL="${DISTDIR}/libdvdnav-${LIBDVDNAV_COMMIT}.tar.gz"
-		-Dlibdvdcss_URL="${DISTDIR}/libdvdcss-${LIBDVDCSS_COMMIT}.tar.gz"
-	)
-
-	use libusb && mycmakeargs+=( -DENABLE_LIBUSB=$(usex libusb) )
-
-	cmake-utils_src_configure
-}
-
-src_compile() {
-	cmake-utils_src_compile all $(usev test)
-}
-
-src_install() {
-	cmake-utils_src_install
-	rm "${ED%/}"/usr/share/doc/*/{LICENSE.GPL,copying.txt}* || die
-
-	newicon media/icon48x48.png kodi.png
-
-	# Replace bundled fonts with system ones.
-	rm "${ED%/}"/usr/share/kodi/addons/skin.estouchy/fonts/NotoSans-Regular.ttf || die
-	dosym /usr/share/fonts/noto/NotoSans-Regular.ttf \
-		usr/share/kodi/addons/skin.estouchy/fonts/NotoSans-Regular.ttf
-
-	local f
-	for f in NotoMono-Regular.ttf NotoSans-Bold.ttf NotoSans-Regular.ttf ; do
-		rm "${ED%/}"/usr/share/kodi/addons/skin.estuary/fonts/"${f}" || die
-		dosym /usr/share/fonts/noto/"${f}" \
-			usr/share/kodi/addons/skin.estuary/fonts/"${f}"
-	done
-
-	rm "${ED%/}"/usr/share/kodi/addons/skin.estuary/fonts/Roboto-Thin.ttf || die
-	dosym /usr/share/fonts/roboto/Roboto-Thin.ttf \
-		usr/share/kodi/addons/skin.estuary/fonts/Roboto-Thin.ttf
-
-	python_domodule tools/EventClients/lib/python/xbmcclient.py
-	python_newscript "tools/EventClients/Clients/Kodi Send/kodi-send.py" kodi-send
-}