[gentoo-commits] repo/gentoo:master commit in: dev-libs/json-glib/

["Mart Raudsepp" <leio@gentoo.org>]

commit:     2311468d99b02025d18ba9d3f24a555443414bd9
Author:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
AuthorDate: Thu Mar 23 03:47:02 2017 +0000
Commit:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
CommitDate: Thu Mar 23 03:50:43 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=2311468d

dev-libs/json-glib: bump to 1.2.8

 dev-libs/json-glib/Manifest               |  1 +
 dev-libs/json-glib/json-glib-1.2.8.ebuild | 54 +++++++++++++++++++++++++++++++
 2 files changed, 55 insertions(+)

diff --git a/dev-libs/json-glib/Manifest b/dev-libs/json-glib/Manifest
index e14b2a85479..59bf1bc4946 100644
--- a/dev-libs/json-glib/Manifest
+++ b/dev-libs/json-glib/Manifest
@@ -1 +1,2 @@
 DIST json-glib-1.2.2.tar.xz 590376 SHA256 ea128ab52a824fcd06e5448fbb2bd8d9a13740d51c66d445828edba71321a621 SHA512 04cbb303c4c6fc6e8af8bc25353b7aff7454250e317f29e4544e850c251aa8c6c88f81cbada8aafd42db637f5521814a86720b0784bc6f202cb222140e993bcf WHIRLPOOL ad5d0d092356beb03537cd07adde488d125487484b02be6e15329eb5d14b0f80f7967b7abee843cbb153da81e440f31787742f12378e6d7c28a152485acc035c
+DIST json-glib-1.2.8.tar.xz 604336 SHA256 fd55a9037d39e7a10f0db64309f5f0265fa32ec962bf85066087b83a2807f40a SHA512 85d8ad431363b8698d71684927b8aa38749d99ea7236334ec09fd81482489f1ab9cb12dabcbe13f6b6ffd7e5d70ade47a36b511e275915d4aa858af647db90ba WHIRLPOOL 2c770d113e4b1911fe98ca127110c45443a5e992d442265c8e48a65f66d1429bff1099b4015f93d110b547734f4478febe1d27a81e7774cf3f23e0696c51fe18

diff --git a/dev-libs/json-glib/json-glib-1.2.8.ebuild b/dev-libs/json-glib/json-glib-1.2.8.ebuild
new file mode 100644
index 00000000000..ed3db1ec4ab
--- /dev/null
+++ b/dev-libs/json-glib/json-glib-1.2.8.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit gnome2 multilib-minimal
+
+DESCRIPTION="Library providing GLib serialization and deserialization for the JSON format"
+HOMEPAGE="https://wiki.gnome.org/Projects/JsonGlib"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-fbsd ~x86-fbsd"
+IUSE="debug +introspection"
+
+RDEPEND="
+	>=dev-libs/glib-2.37.6:2[${MULTILIB_USEDEP}]
+	introspection? ( >=dev-libs/gobject-introspection-0.9.5:= )
+"
+DEPEND="${RDEPEND}
+	~app-text/docbook-xml-dtd-4.1.2
+	app-text/docbook-xsl-stylesheets
+	dev-libs/libxslt
+	>=dev-util/gtk-doc-am-1.20
+	>=sys-devel/gettext-0.18
+	virtual/pkgconfig[${MULTILIB_USEDEP}]
+"
+
+src_prepare() {
+	# Do not touch CFLAGS with --enable-debug=yes
+	sed -e 's/CFLAGS -g/CFLAGS/' -i "${S}"/configure || die
+	gnome2_src_prepare
+}
+
+multilib_src_configure() {
+	# Coverage support is useless, and causes runtime problems
+	ECONF_SOURCE=${S} \
+	gnome2_src_configure \
+		--enable-man \
+		--disable-gcov \
+		$(usex debug --enable-debug=yes --enable-debug=minimum) \
+		$(multilib_native_use_enable introspection)
+
+	if multilib_is_native_abi; then
+		ln -s "${S}"/doc/html doc/html || die
+	fi
+}
+
+multilib_src_compile() {
+	gnome2_src_compile
+}
+
+multilib_src_install() {
+	gnome2_src_install
+}